Replace animated tab audio indicator with static tab audio indicator.

chrome/browser/ui/cocoa/tabs/tab_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/tabs/tab_controller.h"
 
 #include <cmath>
 
 #include "base/mac/bundle_locations.h"
 #include "base/mac/mac_util.h"
@@ skipping 255 matching lines @@
   [self updateVisibility];
 
   if (iconView_)
     [[self view] addSubview:iconView_];
 }
 
 - (NSTextField*)titleView {
   return titleView_;
 }
 
+- (NSView*)audioIndicatorView {
+  return audioIndicatorView_;
+}
+
+- (void)setAudioIndicatorView:(NSView*)audioIndicatorView {
+  [audioIndicatorView_ removeFromSuperview];
+  audioIndicatorView_.reset([audioIndicatorView retain]);
+  [self updateVisibility];
+  if (audioIndicatorView_)
+    [[self view] addSubview:audioIndicatorView_];
+}
+
 - (HoverCloseButton*)closeButton {
   return closeButton_;
 }
 
 - (NSString*)toolTip {
   return [[self tabView] toolTipText];
 }
 
 // Return a rough approximation of the number of icons we could fit in the
 // tab. We never actually do this, but it's a helpful guide for determining
 // how much space we have available.
 - (int)iconCapacity {
   CGFloat width = NSMaxX([closeButton_ frame]) - NSMinX(originalIconFrame_);
-  CGFloat iconWidth = NSWidth(originalIconFrame_);
+  const int kPaddingBetweenIcons = 2;
+  CGFloat iconWidth = NSWidth(originalIconFrame_) + kPaddingBetweenIcons;
 
   return width / iconWidth;
 }
 
 // Returns YES if we should show the icon. When tabs get too small, we clip
 // the favicon before the close button for selected tabs, and prefer the
-// favicon for unselected tabs.  The icon can also be suppressed more directly
+// favicon for unselected tabs. Exception: We clip the favicon before the audio
+// indicator in all cases. The icon can also be suppressed more directly
 // by clearing iconView_.
 - (BOOL)shouldShowIcon {
   if (!iconView_)
     return NO;
+  const BOOL should_show_audio_indicator = [self shouldShowAudioIndicator];

[sail, 2013/09/11 19:18:37]

should use camel case

[miu, 2013/09/11 21:35:06]

Whoops; missed that one.  Done.

+  if ([self mini])
+    return !should_show_audio_indicator;
+  int required_capacity = should_show_audio_indicator ? 2 : 1;
+  if ([self selected]) {
+    // Active tabs give priority to the close button, then the audio indicator,
+    // then the favicon.
+    ++required_capacity;
+  } else {
+    // Non-selected tabs give priority to the audio indicator, then the favicon,
+    // and finally the close button.
+  }
+  return [self iconCapacity] >= required_capacity;
+}
 
+// Returns YES if we should show the audio indicator. When tabs get too small,
+// we clip the audio indicator before the close button for selected tabs, and
+// prefer the audio indicator for unselected tabs.
+- (BOOL)shouldShowAudioIndicator {
+  if (!audioIndicatorView_)
+    return NO;
   if ([self mini])
     return YES;
-
-  int iconCapacity = [self iconCapacity];
-  if ([self selected])
-    return iconCapacity >= 2;
-  return iconCapacity >= 1;
+  if ([self selected]) {
+    // The active tab clips the audio indicator before the close button.
+    return [self iconCapacity] >= 2;
+  }
+  // Non-selected tabs clip close button before the audio indicator.
+  return [self iconCapacity] >= 1;
 }
 
 // Returns YES if we should be showing the close button. The selected tab
 // always shows the close button.
 - (BOOL)shouldShowCloseButton {
   if ([self mini])
     return NO;
   return ([self selected] || [self iconCapacity] >= 3);
 }
 
 - (void)updateVisibility {
   // iconView_ may have been replaced or it may be nil, so [iconView_ isHidden]
   // won't work.  Instead, the state of the icon is tracked separately in
   // isIconShowing_.
   BOOL newShowIcon = [self shouldShowIcon];
 
   [iconView_ setHidden:!newShowIcon];
   isIconShowing_ = newShowIcon;
 
   // If the tab is a mini-tab, hide the title.
   [titleView_ setHidden:[self mini]];
 
   BOOL newShowCloseButton = [self shouldShowCloseButton];
 
   [closeButton_ setHidden:!newShowCloseButton];
 
+  BOOL newShowAudioIndicator = [self shouldShowAudioIndicator];
+
+  if (audioIndicatorView_) {
+    [audioIndicatorView_ setHidden:!newShowAudioIndicator];
+
+    NSRect newFrame = [audioIndicatorView_ frame];
+    if ([self app] || [self mini]) {
+      // Tab is pinned: Position the audio indicator in the center.
+      const CGFloat tabWidth = [self app] ?
+          [TabController appTabWidth] : [TabController miniTabWidth];
+      newFrame.origin.x = (tabWidth - NSWidth(newFrame)) / 2;
+      newFrame.origin.y = NSMinY(originalIconFrame_) -
+          (NSHeight(newFrame) - NSHeight(originalIconFrame_)) / 2;
+    } else {
+      // The Frame for the audioIndicatorView_ depends on whether iconView_
+      // and/or closeButton_ are visible, and where they have been positioned.
+      const NSRect closeButtonFrame = [closeButton_ frame];
+      newFrame.origin.x = NSMinX(closeButtonFrame);
+      // Position to the left of the close button when it is showing.
+      if (newShowCloseButton)
+        newFrame.origin.x -= NSWidth(newFrame);
+      // Audio indicator is centered vertically, with respect to closeButton_.
+      newFrame.origin.y = NSMinY(closeButtonFrame) -
+          (NSHeight(newFrame) - NSHeight(closeButtonFrame)) / 2;
+    }
+    [audioIndicatorView_ setFrame:newFrame];

[sail, 2013/09/11 19:18:37]

The frame should have integral values. You can either do roundf() above or call
NSIntegralRect() here.

[miu, 2013/09/11 21:35:06]

Done.

+  }
+
   // Adjust the title view based on changes to the icon's and close button's
   // visibility.
   NSRect oldTitleFrame = [titleView_ frame];
   NSRect newTitleFrame;
   newTitleFrame.size.height = oldTitleFrame.size.height;
   newTitleFrame.origin.y = oldTitleFrame.origin.y;
 
   if (newShowIcon) {
     newTitleFrame.origin.x = originalIconFrame_.origin.x + iconTitleXOffset_;
   } else {
     newTitleFrame.origin.x = originalIconFrame_.origin.x;
   }
 
-  if (newShowCloseButton) {
+  if (newShowAudioIndicator) {
+    newTitleFrame.size.width = NSMinX([audioIndicatorView_ frame]) -
+                               newTitleFrame.origin.x;
+  } else if (newShowCloseButton) {
     newTitleFrame.size.width = NSMinX([closeButton_ frame]) -
                                newTitleFrame.origin.x;
   } else {
     newTitleFrame.size.width = NSMaxX([closeButton_ frame]) -
                                newTitleFrame.origin.x;
   }
 
   [titleView_ setFrame:newTitleFrame];
 }
 
@@ skipping 25 matching lines @@
 // TabStripDragController.
 - (BOOL)tabCanBeDragged:(TabController*)controller {
   return [[target_ dragController] tabCanBeDragged:controller];
 }
 
 - (void)maybeStartDrag:(NSEvent*)event forTab:(TabController*)tab {
   [[target_ dragController] maybeStartDrag:event forTab:tab];
 }
 
 @end