Split parts of //chrome/utility's BUILD.gn into //chrome/utility/safe_browsing/mac.

chrome/utility/safe_browsing/mac/BUILD.gn

Index: chrome/utility/safe_browsing/mac/BUILD.gn
diff --git a/chrome/utility/safe_browsing/mac/BUILD.gn b/chrome/utility/safe_browsing/mac/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..e37d4f6d91226ff59b51353b7766d0818d7c3f15
--- /dev/null
+++ b/chrome/utility/safe_browsing/mac/BUILD.gn
@@ -0,0 +1,71 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//testing/libfuzzer/fuzzer_test.gni")
+
+source_set("mac") {
+  sources = [
+    "dmg_analyzer.cc",
+    "dmg_analyzer.h",
+    "dmg_iterator.cc",
+    "dmg_iterator.h",
+  ]
+
+  deps = [
+    ":dmg_common",
+    "//base",
+    "//chrome/common",
+    "//chrome/common/safe_browsing:proto",
+  ]
+}
+
+config("dmg_public_config") {
+  libs = [
+    "bz2",
+    "CoreFoundation.framework",
+  ]
+}
+
+source_set("dmg_common") {
+  visibility = [ ":*" ]
+
+  sources = [
+    "convert_big_endian.h",
+    "hfs.cc",
+    "hfs.h",
+    "read_stream.cc",
+    "read_stream.h",
+    "udif.cc",
+    "udif.h",
+  ]
+
+  deps = [
+    "//base",
+    "//third_party/zlib",
+  ]
+
+  public_configs = [ ":dmg_public_config" ]
+}
+
+executable("crdmg") {
+  sources = [
+    "crdmg.cc",
+  ]
+
+  deps = [
+    ":dmg_common",
+    "//base",
+  ]
+}
+
+fuzzer_test("safe_browsing_dmg_fuzzer") {
+  sources = [
+    "fuzzer.cc",
+  ]
+
+  deps = [
+    ":dmg_common",
+    "//base",
+  ]
+}