Split parts of //chrome/utility's BUILD.gn into //chrome/utility/safe_browsing/mac.

chrome/utility/safe_browsing/mac/BUILD.gn

Index: chrome/utility/safe_browsing/mac/BUILD.gn
diff --git a/chrome/utility/safe_browsing/mac/BUILD.gn b/chrome/utility/safe_browsing/mac/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..a8a0599f4df35bde867b212769ba4fbadaaa0de7
--- /dev/null
+++ b/chrome/utility/safe_browsing/mac/BUILD.gn
@@ -0,0 +1,77 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//testing/libfuzzer/fuzzer_test.gni")
+
+source_set("mac") {
+  sources = [
+    "dmg_analyzer.cc",
+    "dmg_analyzer.h",
+    "dmg_iterator.cc",
+    "dmg_iterator.h",
+  ]
+
+  deps = [
+    ":dmg_common",
+    "//base",
+    "//chrome/common",
+    "//chrome/common/safe_browsing:proto",
+  ]
+}
+
+config("dmg_public_config") {
+  libs = [
+    "bz2",
+    "CoreFoundation.framework",
+  ]
+}
+
+source_set("dmg_common") {
+  visibility = [ ":*" ]
+
+  sources = [
+    "convert_big_endian.h",
+    "hfs.cc",
+    "hfs.h",
+    "read_stream.cc",
+    "read_stream.h",
+    "udif.cc",
+    "udif.h",
+  ]
+
+  deps = [
+    "//base",
+    "//third_party/zlib",
+  ]
+
+  public_configs = [ ":dmg_public_config" ]
+}
+
+config("crdmg_private_config") {
+  visibility = [ ":crdmg" ]
+  cflags = [ "-Wno-partial-availability" ]

[Nico, 2016/09/08 22:29:12]

Fix the warnings instead?

[Robert Sesek, 2016/09/08 22:43:05]

It's from openat() and mkdirat() which are 10.10+. We can't really express a
different deployment target for one-off executables. I could #pragma them in the
file.

[Nico, 2016/09/09 20:31:59]

The warning just wants you to redeclare them, so that it knows you're aware
they're not on all platforms.

[Robert Sesek, 2016/09/09 20:44:01]

Do'h, done.

+}
+
+executable("crdmg") {

[Nico, 2016/09/08 22:29:12]

Isn't that a new target? Advertise it in the cl description?

[Robert Sesek, 2016/09/08 22:43:05]

It's one I didn't port in the GN transition, since I knew I wanted to split this
out after the GYP files were axed.

[Nico, 2016/09/09 20:31:58]

I'm just saying you should mention that in the CL description since else this'll
look like it's just moving stuff around in `git log`

[Robert Sesek, 2016/09/09 20:44:01]

Done.

+  sources = [
+    "crdmg.cc",
+  ]
+
+  deps = [
+    ":dmg_common",
+    "//base",
+  ]
+
+  configs += [ ":crdmg_private_config" ]
+}
+
+fuzzer_test("safe_browsing_dmg_fuzzer") {
+  sources = [
+    "fuzzer.cc",
+  ]
+
+  deps = [
+    ":dmg_common",
+  ]
+}