Deletes remaining traces of gyp in services/ and mojo/

mojo/common/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//testing/test.gni")
 
 group("common") {
   public_deps = [
     ":common_base",
     ":common_custom_types",
   ]
 }
 
-# GYP version: mojo/mojo_base.gyp:mojo_common_custom_types
 mojom("common_custom_types") {
   sources = [
     "common_custom_types.mojom",
   ]
 }
 
-# GYP version: mojo/mojo_base.gyp:mojo_common_lib
 component("common_base") {
   output_name = "mojo_common_lib"
 
   sources = [
     "common_type_converters.cc",
     "common_type_converters.h",
     "data_pipe_drainer.cc",
     "data_pipe_drainer.h",
     "data_pipe_file_utils.cc",
     "data_pipe_utils.cc",
     "data_pipe_utils.h",
     "user_agent.cc",
     "user_agent.h",
   ]
 
   defines = [ "MOJO_COMMON_IMPLEMENTATION" ]
 
   public_deps = [
     "//base",
     "//mojo/public/cpp/bindings",
     "//mojo/public/cpp/system",
   ]
 }
 
-# GYP version: mojo/mojo_base.gyp:mojo_test_common_custom_types
 mojom("test_common_custom_types") {
   sources = [
     "test_common_custom_types.mojom",
     "traits_test_service.mojom",
   ]
   public_deps = [
     ":common_custom_types",
   ]
 }
 
-# GYP version: mojo/mojo_base.gyp:mojo_common_unittests
 test("mojo_common_unittests") {
   deps = [
     ":common",
     ":common_custom_types",
     ":struct_traits",
     ":test_common_custom_types",
     "//base",
     "//base:message_loop_tests",
     "//base/test:test_support",
     "//mojo/edk/test:run_all_unittests",
@@ skipping 24 matching lines @@
 source_set("struct_traits") {
   sources = [
     "common_custom_types_struct_traits.cc",
     "common_custom_types_struct_traits.h",
   ]
   deps = [
     ":common_custom_types_shared_cpp_sources",
     "//base:base",
   ]
 }