DevTools: patch browser's Chrome version into Chrome user agents for emulation

third_party/WebKit/Source/devtools/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//third_party/WebKit/Source/core/core.gni")
+import("//chrome/version.gni")

[dgozman, 2016/09/07 22:06:28]

This looks like a layering violation. Ain't any presubmit complaining?

[luoe, 2016/09/07 22:46:32]

Ninja and presubmit are fine with it, no complaints.

//chrome/version and //third_party/WebKit/Source/core/core.gni both depend on
//build/config/chrome_build.gni.  What's the right way to do this?

 
 devtools_embedder_scripts = [
   "front_end/devtools.js",
   "front_end/Tests.js",
 ]
 devtools_core_base_files = [
   "front_end/inspector.js",
   "front_end/inspector.json",
   "front_end/formatter_worker.js",
   "front_end/formatter_worker.json",
@@ skipping 836 matching lines @@
                      devtools_core_files + devtools_module_json_files +
                      devtools_modules_js_files + devtools_acorn_files
 
 resources_out_dir = "$root_out_dir/resources/inspector"
 
 generated_scripts = [
   "$resources_out_dir/InspectorBackendCommands.js",
   "$resources_out_dir/SupportedCSSProperties.js",
 ]
 
+generated_version_info_script =
+    [ "$resources_out_dir/CurrentBrowserVersion.js" ]
+
 generated_entry_files = [
   "$resources_out_dir/inspector.html",
   "$resources_out_dir/inspector.js",
   "$resources_out_dir/toolbox.html",
   "$resources_out_dir/toolbox.js",
 ]
 
 generated_workers = [
   "$resources_out_dir/formatter_worker.js",
   "$resources_out_dir/heap_snapshot_worker.js",
@@ skipping 38 matching lines @@
 visibility = [ "//third_party/WebKit/*" ]
 
 group("devtools_frontend_resources") {
   public_deps = [
     ":build_release_devtools",
     ":copy_embedder_scripts",
     ":copy_emulated_devices_images",
     ":copy_inspector_images",
     ":devtools_extension_api",
     ":frontend_protocol_sources",
+    ":generate_version_info",
     ":supported_css_properties",
   ]
   if (debug_devtools) {
     public_deps += [ ":build_debug_devtools" ]
   }
 }
 
 copy("copy_embedder_scripts") {
   sources = devtools_embedder_scripts
   outputs = [
@@ skipping 93 matching lines @@
   outputs = [
     "$resources_out_dir/InspectorBackendCommands.js",
   ]
 
   args = rebase_path(inputs, root_build_dir) + [
            "--output_js_dir",
            rebase_path(resources_out_dir, root_build_dir),
          ]
 }
 
+process_version("generate_version_info") {
+  template_file = "scripts/CurrentBrowserVersion.js"
+  output = "$resources_out_dir/CurrentBrowserVersion.js"
+  process_only = true
+}
+
 action("build_release_devtools") {
   script = "scripts/build_applications.py"
 
   deps = [
     ":frontend_protocol_sources",
+    ":generate_version_info",
     ":supported_css_properties",
   ]
 
   helper_scripts = [
     "scripts/modular_build.py",
     "scripts/concatenate_application_code.py",
     "scripts/rjsmin.py",
   ]
 
-  inputs = helper_scripts + all_devtools_files + generated_scripts + [
+  inputs = helper_scripts + all_devtools_files + generated_scripts +
+           generated_version_info_script +
+           [
              "front_end/inspector.html",
              "front_end/toolbox.html",
            ]
 
   outputs = generated_entry_files + generated_workers +
             generated_bundled_modules + generated_remote_modules
 
   debug_mode = "0"
 
   args = [
@@ skipping 49 matching lines @@
   }
 
   group("copy_debug_files") {
     public_deps = [
       ":copy_acorn_js_files",
       ":copy_codemirror_files",
       ":copy_emulated_devices_images_debug",
       ":copy_generated_scripts",
       ":copy_inspector_images_debug",
       ":copy_runtime_core",
+      ":generate_version_info_debug",
     ]
   }
 
   copy("copy_runtime_core") {
     sources = devtools_core_base_files
     outputs = [
       "$resources_out_debug_dir/{{source_file_part}}",
     ]
   }
 
@@ skipping 14 matching lines @@
   copy("copy_generated_scripts") {
     deps = [
       ":frontend_protocol_sources",
       ":supported_css_properties",
     ]
     sources = generated_scripts
     outputs = [
       "$resources_out_debug_dir/{{source_file_part}}",
     ]
   }
+
   copy("copy_inspector_images_debug") {
     sources = devtools_image_files
     outputs = [
       "$resources_out_debug_dir/Images/{{source_file_part}}",
     ]
   }
 
   copy("copy_emulated_devices_images_debug") {
     sources = devtools_emulated_devices_images
     outputs = [
       "$resources_out_debug_dir/emulated_devices/{{source_file_part}}",
     ]
   }
+
+  process_version("generate_version_info_debug") {
+    template_file = "scripts/CurrentBrowserVersion.js"
+    output = "$resources_out_debug_dir/CurrentBrowserVersion.js"
+    process_only = true
+  }
 }