Adding performance tests for HQP that represent importance of optimising HistoryItemsForTerms method

chrome/test/BUILD.gn

Index: chrome/test/BUILD.gn
diff --git a/chrome/test/BUILD.gn b/chrome/test/BUILD.gn
index 203104dce957241f165e7572272a417fbd057c36..c2a739fe72635c9d1e65651721e2e74e5c54c373 100644
--- a/chrome/test/BUILD.gn
+++ b/chrome/test/BUILD.gn
@@ -648,6 +648,68 @@ if (!is_android) {
     }
   }
 
+  test("performance_interactive_ui_tests") {
+    sources = [
+      "//chrome/browser/omnibox_performance_browsertest.cc",
+      "//chrome/test/base/interactive_test_utils.cc",
+      "//chrome/test/base/interactive_test_utils.h",
+      "//chrome/test/base/interactive_test_utils_aura.cc",
+      "//chrome/test/base/interactive_test_utils_aura.h",
+      "//chrome/test/base/interactive_test_utils_common_views.cc",
+      "//chrome/test/base/interactive_test_utils_mac.mm",
+      "//chrome/test/base/interactive_test_utils_win.cc",
+      "//chrome/test/base/performance_interactive_ui_tests_main.cc",
+    ]
+    if (!use_aura) {
+      sources -= [
+        "//chrome/test/base/interactive_test_utils_aura.cc",
+        "//chrome/test/base/interactive_test_utils_aura.h",
+      ]
+    }
+
+    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
+    ldflags = []
+    data_deps = []
+
+    deps = [
+      ":test_support",
+      ":test_support_ui",
+      "//chrome:strings",
+      "//chrome/browser",
+      "//testing/gtest",
+      "//testing/perf",
+      "//ui/base:test_support",
+    ]
+
+    if (toolkit_views) {
+      deps += [ "//ui/views:test_support" ]
+    }
+
+    if (is_win) {
+      deps += [ "//third_party/wtl" ]
+    }
+
+    if (is_mac) {
+      # TODO(mark): We really want this for all non-static library targets, but
+      # when we tried to pull it up to the common.gypi level, it broke other
+      # things like the ui and startup tests. *shrug*
+      ldflags += [ "-Wl,-ObjC" ]
+
+      if (mac_views_browser) {
+        sources += [ "//chrome/test/base/interactive_test_utils_views.cc" ]
+      } else {
+        sources += [ "//chrome/test/base/interactive_test_utils_cocoa.mm" ]
+      }
+    } else {  # Non-Mac.
+      sources += [ "//chrome/test/base/interactive_test_utils_views.cc" ]
+    }
+
+    if (use_x11) {
+      configs += [ "//build/config/linux:xtst" ]
+      data_deps += [ "//tools/xdisplaycheck" ]
+    }
+  }
+
   if (enable_app_list && use_ash) {
     static_library("test_support_applist_ash") {
       defines = []
@@ -1810,6 +1872,7 @@ test("unit_tests") {
     "//courgette:courgette_lib",
     "//google_apis",
     "//skia",
+    "//testing/perf:perf",
     "//third_party/cacheinvalidation",
     "//third_party/icu",
     "//third_party/libxml",