GN: add sources_when_disabled to optional

BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 declare_args() {
   skia_enable_tools = !is_fuchsia && !is_component_build
 
   skia_use_expat = true
   skia_use_fontconfig = is_linux
@@ skipping 221 matching lines @@
 opts("dsp") {
   enabled = current_cpu == "mipsel"
   sources = opts_gypi.mips_dsp_sources
   cflags = []
 }
 
 # Any feature of Skia that requires third-party code should be optional and use this template.
 template("optional") {
   if (invoker.enabled) {
     config(target_name + "_public") {
-      defines = invoker.public_defines
+      if (defined(invoker.public_defines)) {
+        defines = invoker.public_defines
+      }
     }
     source_set(target_name) {
-      forward_variables_from(invoker, "*", [ "public_defines" ])
+      forward_variables_from(invoker,
+                             "*",
+                             [
+                               "public_defines",
+                               "sources_when_disabled",
+                             ])
       all_dependent_configs = [ ":" + target_name + "_public" ]
       configs += skia_library_configs
     }
   } else {
-    # If not enabled, a phony empty target that swallows all otherwise unused variables.
     source_set(target_name) {
       forward_variables_from(invoker,
                              "*",
                              [
                                "public_defines",
                                "deps",
                                "sources",
+                               "sources_when_disabled",
                              ])
+      if (defined(invoker.sources_when_disabled)) {
+        sources = invoker.sources_when_disabled
+      }
+      configs += skia_library_configs
     }
   }
 }
 
 optional("fontmgr_android") {
   enabled = fontmgr_android_enabled
-  public_defines = []
 
   deps = [
     "//third_party/expat",
     "//third_party/freetype2",
   ]
   sources = [
     "src/ports/SkFontMgr_android.cpp",
     "src/ports/SkFontMgr_android_factory.cpp",
     "src/ports/SkFontMgr_android_parser.cpp",
   ]
 }
 
 optional("fontmgr_fontconfig") {
   enabled = skia_use_freetype && skia_use_fontconfig
-  public_defines = []
 
   deps = [
     "//third_party:fontconfig",
     "//third_party/freetype2",
   ]
   sources = [
     "src/ports/SkFontConfigInterface_direct.cpp",
     "src/ports/SkFontConfigInterface_direct_factory.cpp",
     "src/ports/SkFontMgr_FontConfigInterface.cpp",
     "src/ports/SkFontMgr_fontconfig.cpp",
@@ skipping 24 matching lines @@
     "src/codec/SkJpegCodec.cpp",
     "src/codec/SkJpegDecoderMgr.cpp",
     "src/codec/SkJpegUtility.cpp",
     "src/images/SkJPEGImageEncoder.cpp",
     "src/images/SkJPEGWriteUtility.cpp",
   ]
 }
 
 optional("pdf") {
   enabled = skia_use_zlib
-  public_defines = []
 
   deps = [
     "//third_party/zlib",
   ]
   sources = pdf_gypi.sources
+  sources_when_disabled = [ "src/pdf/SkDocument_PDF_None.cpp" ]
 
   if (skia_use_sfntly) {
     deps += [ "//third_party/sfntly" ]
-    public_defines += [ "SK_PDF_USE_SFNTLY" ]
+    public_defines = [ "SK_PDF_USE_SFNTLY" ]
   }
 }
 
 optional("png") {
   enabled = skia_use_libpng
   public_defines = [ "SK_HAS_PNG_LIBRARY" ]
 
   deps = [
     "//third_party/libpng",
   ]
   sources = [
     "src/codec/SkIcoCodec.cpp",
     "src/codec/SkPngCodec.cpp",
     "src/images/SkPNGImageEncoder.cpp",
   ]
 }
 
 optional("typeface_freetype") {
   enabled = skia_use_freetype
-  public_defines = []
 
   deps = [
     "//third_party/freetype2",
   ]
   sources = [
     "src/ports/SkFontHost_FreeType.cpp",
     "src/ports/SkFontHost_FreeType_common.cpp",
   ]
 }
 
 optional("webp") {
   enabled = skia_use_libwebp
   public_defines = [ "SK_HAS_WEBP_LIBRARY" ]
 
   deps = [
     "//third_party/libwebp",
   ]
   sources = [
     "src/codec/SkWebpAdapterCodec.cpp",
     "src/codec/SkWebpCodec.cpp",
     "src/images/SkWEBPImageEncoder.cpp",
   ]
 }
 
 optional("xml") {
   enabled = skia_use_expat
-  public_defines = []
 
   deps = [
     "//third_party/expat",
   ]
   sources = [
     "src/xml/SkDOM.cpp",
     "src/xml/SkXMLParser.cpp",
     "src/xml/SkXMLWriter.cpp",
   ]
 }
@@ skipping 428 matching lines @@
         "tools/using_skia_and_harfbuzz.cpp",
       ]
       deps = [
         ":skia",
         "//third_party/harfbuzz",
       ]
       testonly = true
     }
   }
 }