GN: add sanitize arg

gn/BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 declare_args() {
   ar = "ar"
   cc = "cc"
   cxx = "c++"
 
   if (is_android) {
     ar = "$ndk/toolchains/$ndk_gccdir-4.9/prebuilt/$ndk_host/$ndk_target/bin/ar"
     cc = "$ndk/toolchains/llvm/prebuilt/$ndk_host/bin/clang"
     cxx = "$ndk/toolchains/llvm/prebuilt/$ndk_host/bin/clang++"
   }
 
   extra_cflags = ""
   extra_cflags_c = ""
   extra_cflags_cc = ""
   extra_ldflags = ""
 
   compiler_prefix = ""
 }
 
 config("no_rtti") {
-  cflags_cc = [ "-fno-rtti" ]
+  if (sanitize != "ASAN") {  # -fsanitize=vptr requires RTTI
+    cflags_cc = [ "-fno-rtti" ]
+  }
 }
 
 config("default") {
   cflags = [
     "-O1",
     "-g",
     "-fstrict-aliasing",
     "-fPIC",
     "-fvisibility=hidden",
 
     "-Werror",
     "-Wall",
     "-Wextra",
     "-Winit-self",
     "-Wpointer-arith",
     "-Wsign-compare",
     "-Wvla",
 
     "-Wno-deprecated-declarations",
     "-Wno-unused-parameter",
   ]
   cflags_cc = [
     "-std=c++11",
     "-fno-exceptions",
     "-fno-threadsafe-statics",
     "-fvisibility-inlines-hidden",
 
     "-Wnon-virtual-dtor",
   ]
+  ldflags = []
+
   if (current_cpu == "arm") {
     cflags += [
       "-march=armv7-a",
       "-mfpu=neon",
       "-mthumb",
     ]
   } else if (current_cpu == "mipsel") {
     cflags += [
       "-march=mips32r2",
       "-mdspr2",
     ]
   }
 
   if (is_android) {
     asmflags = [
       "--target=$ndk_target",
       "-B$ndk/toolchains/$ndk_gccdir-4.9/prebuilt/$ndk_host/$ndk_target/bin",
     ]
     cflags += [
       "--sysroot=$ndk/platforms/$ndk_platform",
       "--target=$ndk_target",
       "-B$ndk/toolchains/$ndk_gccdir-4.9/prebuilt/$ndk_host/$ndk_target/bin",
     ]
     cflags_cc += [
       "-isystem$ndk/sources/android/support/include",
       "-isystem$ndk/sources/cxx-stl/llvm-libc++/libcxx/include",
     ]
-    ldflags = [
+    ldflags += [
       "--sysroot=$ndk/platforms/$ndk_platform",
       "--target=$ndk_target",
       "-B$ndk/toolchains/$ndk_gccdir-4.9/prebuilt/$ndk_host/$ndk_target/bin",
       "-pie",
     ]
     lib_dirs = [
       "$ndk/sources/cxx-stl/llvm-libc++/libs/$ndk_stdlib",
       "$ndk/toolchains/$ndk_gccdir-4.9/prebuilt/$ndk_host/lib/gcc/$ndk_target/4.9.x",
     ]
     libs = [
       # Order matters here!  Keep these three in exactly this order.
       "c++_static",
       "c++abi",
       "android_support",
     ]
     if (target_cpu == "arm") {
       libs += [ "unwind" ]
     }
   }
 
   if (is_linux) {
     libs = [ "pthread" ]
   }
+
+  if (sanitize != "") {
+    # You can either pass the sanitizers directly, e.g. "address,undefined",
+    # or pass one of the couple common aliases used by the bots.
+    sanitizers = sanitize
+    if (sanitize == "ASAN") {
+      sanitizers = "address,bool,function,integer-divide-by-zero,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,signed-integer-overflow,unreachable,vla-bound,vptr"
+    } else if (sanitize == "TSAN") {
+      sanitizers = "thread"
+    } else if (sanitize == "MSAN") {
+      sanitizers = "memory"
+    }
+
+    cflags += [
+      "-fsanitize=$sanitizers",
+      "-fno-sanitize-recover=$sanitizers",
+      "-fsanitize-blacklist=" + rebase_path("../tools/xsan.blacklist"),
+    ]
+    ldflags += [ "-fsanitize=$sanitizers" ]
+    if (sanitizers == "memory") {
+      cflags += [ "-fsanitize-memory-track-origins" ]
+      cflags_cc += [ "-stdlib=libc++" ]
+      ldflags += [ "-stdlib=libc++" ]
+    }
+  }
 }
 
 config("release") {
   cflags = [ "-O3" ]
   defines = [ "NDEBUG" ]
 }
 
 config("executable") {
   if (is_mac) {
     ldflags = [ "-Wl,-rpath,@loader_path/." ]
@@ skipping 75 matching lines @@
   }
 
   tool("stamp") {
     command = "touch {{output}}"
   }
 
   tool("copy") {
     command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
   }
 }