Swap main menu with app-specific menu when app window focused.

chrome/browser/ui/cocoa/apps/app_menu_controller_mac_browsertest.mm

+// Copyright (c) 2013 The Chromium Authors. All rights reserved.

[tapted, 2013/08/15 04:39:23]

nit: no (c)

[jackhou1, 2013/08/16 02:50:41]

Done.

+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/apps/app_menu_controller_mac.h"
+
+#import <Cocoa/Cocoa.h>
+
+#include "apps/shell_window_registry.h"
+#include "base/command_line.h"
+#include "base/mac/scoped_nsobject.h"
+#include "base/strings/sys_string_conversions.h"
+#include "chrome/browser/extensions/extension_test_message_listener.h"
+#include "chrome/browser/extensions/platform_app_browsertest_util.h"
+#import "chrome/common/chrome_switches.h"

[tapted, 2013/08/15 04:39:23]

nit: #include

[jackhou1, 2013/08/16 02:50:41]

Done.

+#include "chrome/common/extensions/extension.h"
+
+namespace {
+
+class AppMenuControllerBrowserTest
+    : public extensions::PlatformAppBrowserTest {
+ protected:
+  AppMenuControllerBrowserTest() {}

[tapted, 2013/08/15 04:39:23]

Since we're C++, you need to initialize data members

[jackhou1, 2013/08/16 02:50:41]

Done.

+
+  void SetUpApps() {
+    // Start two apps and wait for them to be launched.

[tapted, 2013/08/15 04:39:23]

nit: comment before declaration?

[jackhou1, 2013/08/16 02:50:41]

Done.

+    ExtensionTestMessageListener listener_1("Launched", false);
+    app_1_ = InstallAndLaunchPlatformApp("minimal_id");
+    ASSERT_TRUE(listener_1.WaitUntilSatisfied());
+    ExtensionTestMessageListener listener_2("Launched", false);
+    app_2_ = InstallAndLaunchPlatformApp("minimal");
+    ASSERT_TRUE(listener_2.WaitUntilSatisfied());
+
+    main_menu_ = [NSApp mainMenu];
+    initial_menu_item_count_ = [[main_menu_ itemArray] count];
+  }
+
+  void CheckAppMenu(const extensions::Extension* app) {

[tapted, 2013/08/15 04:39:23]

nit: CheckHasAppMenu? You could declare these functions `const` too I think

[jackhou1, 2013/08/16 02:50:41]

Done.

+    NSArray* item_array = [main_menu_ itemArray];
+    EXPECT_EQ(initial_menu_item_count_ + 1, [item_array count]);
+    for (NSUInteger i = 0; i < initial_menu_item_count_; ++i)
+      EXPECT_TRUE([[item_array objectAtIndex:i] isHidden]);
+    NSMenuItem* last_item = [item_array lastObject];
+    EXPECT_EQ(app->id(), base::SysNSStringToUTF8([last_item title]));
+    EXPECT_EQ(app->name(),
+              base::SysNSStringToUTF8([[last_item submenu] title]));
+    EXPECT_FALSE([last_item isHidden]);
+  }
+
+  void CheckNoAppMenu() {
+    NSArray* item_array = [main_menu_ itemArray];
+    EXPECT_EQ(initial_menu_item_count_, [item_array count]);
+    for (NSUInteger i = 0; i < initial_menu_item_count_; ++i)
+      EXPECT_FALSE([[item_array objectAtIndex:i] isHidden]);
+  }
+
+  const extensions::Extension* app_1_;
+  const extensions::Extension* app_2_;
+  NSMenu* main_menu_;

[tapted, 2013/08/15 04:39:23]

Maybe better without this data member, since it raises ownership questions.

[jackhou1, 2013/08/16 02:50:41]

Done.

+  NSUInteger initial_menu_item_count_;
+};

[tapted, 2013/08/15 04:39:23]

nit: private: DISALLOW_COPY_AND_ASSIGN(..)  (+ destructor that I think it will
force you to have)

[jackhou1, 2013/08/16 02:50:41]

Done.

+
+// Test that focusing an app window changes the menu bar.
+IN_PROC_BROWSER_TEST_F(AppMenuControllerBrowserTest,
+                       PlatformAppFocusUpdatesMenuBar) {
+  SetUpApps();
+
+  // When an app is focused, all Chrome menu items should be hidden, and a menu
+  // item for the app should be added.
+  apps::ShellWindow* app_1_shell_window =
+      apps::ShellWindowRegistry::Get(profile())->
+          GetShellWindowsForApp(app_1_->id()).front();
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidBecomeMainNotification
+                    object:app_1_shell_window->GetNativeWindow()];
+  CheckAppMenu(app_1_);
+
+  // When another app is focused, the menu item for the app should change.
+  apps::ShellWindow* app_2_shell_window =
+      apps::ShellWindowRegistry::Get(profile())->
+          GetShellWindowsForApp(app_2_->id()).front();
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidBecomeMainNotification
+                    object:app_2_shell_window->GetNativeWindow()];
+  CheckAppMenu(app_2_);
+
+  // When the app window loses focus, the menu items for the app should be
+  // removed.
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidResignMainNotification
+                    object:app_2_shell_window->GetNativeWindow()];
+  CheckNoAppMenu();
+
+  // When an app window is closed, the menu items for the app should be removed.
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidBecomeMainNotification
+                    object:app_2_shell_window->GetNativeWindow()];
+  CheckAppMenu(app_2_);
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowWillCloseNotification
+                    object:app_2_shell_window->GetNativeWindow()];
+  CheckNoAppMenu();
+}

[tapted, 2013/08/15 04:39:23]

Maybe a test for unloading/uninstalling an extension with windows open?

[jackhou1, 2013/08/16 02:50:41]

Done.

+
+}  // namespace