Create a Delayed Response Provider for GCDWebServer.

ios/web/public/test/response_providers/delayed_response_provider.mm

+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ios/web/public/test/response_providers/delayed_response_provider.h"
+
+#import <Foundation/Foundation.h>
+
+#import "base/mac/scoped_nsobject.h"
+#import "ios/third_party/gcdwebserver/src/GCDWebServer/Responses/GCDWebServerDataResponse.h"
+
+@interface DelayedGCDWebServerResponse : NSProxy

[stkhapugin, 2016/08/26 13:06:48]

Class comment here. 

[Olivier, 2016/08/26 14:10:04]

Done.

+
++ (instancetype)responseWithServerResponse:(GCDWebServerResponse*)response
+                                     delay:(NSTimeInterval)delay;
+- (instancetype)initWithServerResponse:(GCDWebServerResponse*)response
+                                 delay:(NSTimeInterval)delay;
+@end
+
+@implementation DelayedGCDWebServerResponse {
+  base::scoped_nsobject<GCDWebServerResponse> _response;
+  NSTimeInterval _delay;
+}
+
++ (instancetype)responseWithServerResponse:(GCDWebServerResponse*)response
+                                     delay:(NSTimeInterval)delay {
+  return [[[DelayedGCDWebServerResponse alloc] initWithServerResponse:response
+                                                                delay:delay]
+      autorelease];
+}
+
+- (instancetype)initWithServerResponse:(GCDWebServerResponse*)response
+                                 delay:(NSTimeInterval)delay {
+  _response.reset([response retain]);
+  _delay = delay;
+  return self;
+}
+
+#pragma mark - GCDWebServerResponse
+
+- (void)performReadDataWithCompletion:
+    (GCDWebServerBodyReaderCompletionBlock)block {
+  [self asyncReadDataWithCompletion:block];
+}
+
+- (void)asyncReadDataWithCompletion:
+    (GCDWebServerBodyReaderCompletionBlock)block {
+  if ([_response respondsToSelector:@selector(asyncReadDataWithCompletion:)]) {
+    dispatch_after(dispatch_time(DISPATCH_TIME_NOW,
+                                 static_cast<int64_t>(_delay * NSEC_PER_SEC)),
+                   dispatch_get_main_queue(), ^{
+                     [_response asyncReadDataWithCompletion:block];
+                   });
+  } else {
+    dispatch_after(dispatch_time(DISPATCH_TIME_NOW,
+                                 static_cast<int64_t>(_delay * NSEC_PER_SEC)),
+                   dispatch_get_main_queue(), ^{
+                     NSError* error = nil;
+                     NSData* data = [_response readData:&error];
+                     block(data, error);
+                   });
+  }
+}
+
+#pragma mark - NSProxy
+
+- (BOOL)conformsToProtocol:(Protocol*)protocol {
+  return [[_response class] conformsToProtocol:protocol];
+}
+
+- (BOOL)respondsToSelector:(SEL)selector {
+  return [[_response class] instancesRespondToSelector:selector];
+}
+
+- (NSMethodSignature*)methodSignatureForSelector:(SEL)selector {
+  return [[_response class] instanceMethodSignatureForSelector:selector];
+}
+
+- (void)forwardInvocation:(NSInvocation*)invocation {
+  SEL selector = [invocation selector];
+  if ([_response respondsToSelector:selector])
+    [invocation invokeWithTarget:_response];
+}
+
+@end
+
+namespace web {
+
+DelayedResponseProvider::DelayedResponseProvider(
+    std::unique_ptr<web::ResponseProvider> delayed_provider,
+    double delay)
+    : web::ResponseProvider(),
+      delayed_provider_(std::move(delayed_provider)),
+      delay_(delay) {}
+
+DelayedResponseProvider::~DelayedResponseProvider() {}
+
+bool DelayedResponseProvider::CanHandleRequest(const Request& request) {
+  return delayed_provider_->CanHandleRequest(request);
+}
+
+GCDWebServerResponse* DelayedResponseProvider::GetGCDWebServerResponse(
+    const Request& request) {
+  return static_cast<id>([DelayedGCDWebServerResponse

[stkhapugin, 2016/08/26 13:06:48]

ObjCCastStrict or ObjCCast instead of static_cast; cast to GCDWebServerResponse
instead of id.

[Olivier, 2016/08/26 14:10:03]

Done.

+      responseWithServerResponse:delayed_provider_->GetGCDWebServerResponse(
+                                     request)
+                           delay:delay_]);
+}
+
+}  // namespace web