GN: extract optional() as a template and use for giflib-dependent code

BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 declare_args() {
+  skia_use_giflib = !is_fuchsia
   skia_use_libwebp = !is_fuchsia
 }
 
 skia_public_includes = [
   "include/android",
   "include/c",
   "include/codec",
   "include/config",
   "include/core",
   "include/effects",
@@ skipping 38 matching lines @@
     "src/sfnt",
     "src/utils",
     "src/utils/win",
     "third_party/etc1",
     "third_party/ktx",
   ]
 
   defines = [
     "SK_GAMMA_APPLY_TO_A8",
 
-    "SK_HAS_GIF_LIBRARY",
     "SK_HAS_JPEG_LIBRARY",
     "SK_HAS_PNG_LIBRARY",
 
     # TODO(halcanary): make this the default; this is the value Android uses.
     "SK_SFNTLY_SUBSETTER=\"sample/chromium/font_subsetter.h\"",
   ]
   if (is_linux) {
     defines += [ "SK_SAMPLES_FOR_X" ]
   }
 }
@@ skipping 96 matching lines @@
     cflags = [ "-msse4.2" ]
   }
 
   source_set("opts_avx") {
     configs += skia_library_configs
     sources = opts_gypi.avx_sources
     cflags = [ "-mavx" ]
   }
 }
 
-if (skia_use_libwebp) {
-  config("webp_config") {
-    defines = [ "SK_HAS_WEBP_LIBRARY" ]
+template("optional") {
+  if (invoker.enabled) {
+    config(target_name + "_public") {
+      defines = invoker.public_defines
+    }
+    source_set(target_name) {
+      forward_variables_from(invoker, "*", [ "public_defines" ])
+      all_dependent_configs = [ ":" + target_name + "_public" ]
+    }
+  } else {
+    # If not enabled, a phony empty target that swallows all otherwise unused variables.
+    source_set(target_name) {
+      forward_variables_from(invoker,
+                             "*",
+                             [
+                               "public_defines",
+                               "configs",
+                               "deps",
+                               "sources",
+                             ])
+    }
   }
-  source_set("webp") {
-    configs += skia_library_configs
-    all_dependent_configs = [ ":webp_config" ]
-    deps = [
-      "//third_party/libwebp",
-    ]
-    sources = [
-      "src/codec/SkWebpAdapterCodec.cpp",
-      "src/codec/SkWebpCodec.cpp",
-      "src/images/SkWEBPImageEncoder.cpp",
-    ]
-  }
-} else {
-  source_set("webp") {
-  }
+}
+set_defaults("optional") {
+  configs = default_configs
+}
+
+optional("gif") {
+  enabled = skia_use_giflib
+  public_defines = [ "SK_HAS_GIF_LIBRARY" ]
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/giflib",
+  ]
+  sources = [
+    "src/codec/SkGifCodec.cpp",
+  ]
+}
+
+optional("webp") {
+  enabled = skia_use_libwebp
+  public_defines = [ "SK_HAS_WEBP_LIBRARY" ]
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/libwebp",
+  ]
+  sources = [
+    "src/codec/SkWebpAdapterCodec.cpp",
+    "src/codec/SkWebpCodec.cpp",
+    "src/images/SkWEBPImageEncoder.cpp",
+  ]
 }
 
 component("skia") {
   public_configs = [ ":skia_public" ]
   configs += skia_library_configs
 
   deps = [
+    ":gif",
     ":webp",
     "//third_party/expat",
-    "//third_party/giflib",
     "//third_party/libjpeg-turbo:libjpeg",
     "//third_party/libpng",
     "//third_party/sfntly",
     "//third_party/zlib",
   ]
   if (is_x86) {
     deps += [
       ":opts_avx",
       ":opts_sse2",
       ":opts_sse41",
@@ skipping 17 matching lines @@
   sources += [
     "src/android/SkBitmapRegionCodec.cpp",
     "src/android/SkBitmapRegionDecoder.cpp",
     "src/codec/SkAndroidCodec.cpp",
     "src/codec/SkBmpCodec.cpp",
     "src/codec/SkBmpMaskCodec.cpp",
     "src/codec/SkBmpRLECodec.cpp",
     "src/codec/SkBmpStandardCodec.cpp",
     "src/codec/SkCodec.cpp",
     "src/codec/SkCodecImageGenerator.cpp",
-    "src/codec/SkGifCodec.cpp",
     "src/codec/SkIcoCodec.cpp",
     "src/codec/SkJpegCodec.cpp",
     "src/codec/SkJpegDecoderMgr.cpp",
     "src/codec/SkJpegUtility.cpp",
     "src/codec/SkMaskSwizzler.cpp",
     "src/codec/SkMasks.cpp",
     "src/codec/SkPngCodec.cpp",
     "src/codec/SkSampledCodec.cpp",
     "src/codec/SkSampler.cpp",
     "src/codec/SkSwizzler.cpp",
@@ skipping 366 matching lines @@
       "tools/SkShaper_harfbuzz.cpp",
       "tools/using_skia_and_harfbuzz.cpp",
     ]
     deps = [
       ":skia",
       "//third_party/harfbuzz",
     ]
     testonly = true
   }
 }