GN: more optional components: jpeg, pdf, png, xml

BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 declare_args() {
+  skia_use_expat = true
   skia_use_giflib = !is_fuchsia
+  skia_use_libjpeg_turbo = true
+  skia_use_libpng = true
   skia_use_libwebp = !is_fuchsia
+  skia_use_sfntly = !is_fuchsia
+  skia_use_zlib = true
 }
 
 skia_public_includes = [
   "include/android",
   "include/c",
   "include/codec",
   "include/config",
   "include/core",
   "include/effects",
   "include/gpu",
@@ skipping 34 matching lines @@
     "src/pathops",
     "src/pdf",
     "src/ports",
     "src/sfnt",
     "src/utils",
     "src/utils/win",
     "third_party/etc1",
     "third_party/ktx",
   ]
 
-  defines = [
-    "SK_GAMMA_APPLY_TO_A8",
-
-    "SK_HAS_JPEG_LIBRARY",
-    "SK_HAS_PNG_LIBRARY",
-
-    # TODO(halcanary): make this the default; this is the value Android uses.
-    "SK_SFNTLY_SUBSETTER=\"sample/chromium/font_subsetter.h\"",
-  ]
+  defines = [ "SK_GAMMA_APPLY_TO_A8" ]
   if (is_linux) {
     defines += [ "SK_SAMPLES_FOR_X" ]
   }
 }
 
 # Any code that's linked into Skia-the-library should use this config via += skia_library_configs.
 config("skia_library") {
   visibility = [ ":*" ]
   defines = [ "SKIA_IMPLEMENTATION=1" ]
 }
@@ skipping 130 matching lines @@
 
   configs += skia_library_configs
   deps = [
     "//third_party/giflib",
   ]
   sources = [
     "src/codec/SkGifCodec.cpp",
   ]
 }
 
+optional("jpeg") {
+  enabled = skia_use_libjpeg_turbo
+  public_defines = [ "SK_HAS_JPEG_LIBRARY" ]
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/libjpeg-turbo:libjpeg",
+  ]
+  sources = [
+    "src/codec/SkJpegCodec.cpp",
+    "src/codec/SkJpegDecoderMgr.cpp",
+    "src/codec/SkJpegUtility.cpp",
+    "src/images/SkJPEGImageEncoder.cpp",
+    "src/images/SkJPEGWriteUtility.cpp",
+  ]
+}
+
+optional("pdf") {
+  enabled = skia_use_zlib
+  public_defines = []
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/zlib",
+  ]
+  sources = pdf_gypi.sources
+
+  if (skia_use_sfntly) {
+    deps += [ "//third_party/sfntly" ]
+    public_defines += [
+      # TODO(halcanary): make this the default; this is the value Android uses.
+      "SK_SFNTLY_SUBSETTER=\"sample/chromium/font_subsetter.h\"",
+    ]
+  }
+}
+
+optional("png") {
+  enabled = skia_use_libpng
+  public_defines = [ "SK_HAS_PNG_LIBRARY" ]
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/libpng",
+  ]
+  sources = [
+    "src/codec/SkIcoCodec.cpp",
+    "src/codec/SkPngCodec.cpp",
+    "src/images/SkPNGImageEncoder.cpp",
+  ]
+}
+
 optional("webp") {
   enabled = skia_use_libwebp
   public_defines = [ "SK_HAS_WEBP_LIBRARY" ]
 
   configs += skia_library_configs
   deps = [
     "//third_party/libwebp",
   ]
   sources = [
     "src/codec/SkWebpAdapterCodec.cpp",
     "src/codec/SkWebpCodec.cpp",
     "src/images/SkWEBPImageEncoder.cpp",
   ]
 }
 
+optional("xml") {
+  enabled = skia_use_expat
+  public_defines = []
+
+  configs += skia_library_configs
+  deps = [
+    "//third_party/expat",
+  ]
+  sources = [
+    "src/xml/SkDOM.cpp",
+    "src/xml/SkXMLParser.cpp",
+    "src/xml/SkXMLWriter.cpp",
+  ]
+}
+
 component("skia") {
   public_configs = [ ":skia_public" ]
   configs += skia_library_configs
 
   deps = [
     ":gif",
+    ":jpeg",
+    ":pdf",
+    ":png",
     ":webp",
-    "//third_party/expat",
-    "//third_party/libjpeg-turbo:libjpeg",
-    "//third_party/libpng",
-    "//third_party/sfntly",
-    "//third_party/zlib",
+    ":xml",
   ]
   if (is_x86) {
     deps += [
       ":opts_avx",
       ":opts_sse2",
       ":opts_sse41",
       ":opts_sse42",
       ":opts_ssse3",
     ]
   } else {
     deps += [ ":opts_none" ]
   }
 
   if (!is_win) {
     libs = [ "pthread" ]
   }
 
   sources = []
   sources += core_gypi.sources
   sources += effects_gypi.sources
   sources += gpu_gypi.skgpu_sources
-  sources += pdf_gypi.sources
   sources += utils_gypi.sources
   sources += [
     "src/android/SkBitmapRegionCodec.cpp",
     "src/android/SkBitmapRegionDecoder.cpp",
     "src/codec/SkAndroidCodec.cpp",
     "src/codec/SkBmpCodec.cpp",
     "src/codec/SkBmpMaskCodec.cpp",
     "src/codec/SkBmpRLECodec.cpp",
     "src/codec/SkBmpStandardCodec.cpp",
     "src/codec/SkCodec.cpp",
     "src/codec/SkCodecImageGenerator.cpp",
-    "src/codec/SkIcoCodec.cpp",
-    "src/codec/SkJpegCodec.cpp",
-    "src/codec/SkJpegDecoderMgr.cpp",
-    "src/codec/SkJpegUtility.cpp",
     "src/codec/SkMaskSwizzler.cpp",
     "src/codec/SkMasks.cpp",
-    "src/codec/SkPngCodec.cpp",
     "src/codec/SkSampledCodec.cpp",
     "src/codec/SkSampler.cpp",
     "src/codec/SkSwizzler.cpp",
     "src/codec/SkWbmpCodec.cpp",
     "src/gpu/gl/GrGLDefaultInterface_native.cpp",
     "src/images/SkImageEncoder.cpp",
     "src/images/SkImageEncoder_Factory.cpp",
-    "src/images/SkJPEGImageEncoder.cpp",
-    "src/images/SkJPEGWriteUtility.cpp",
     "src/images/SkKTXImageEncoder.cpp",
-    "src/images/SkPNGImageEncoder.cpp",
     "src/ports/SkDiscardableMemory_none.cpp",
     "src/ports/SkGlobalInitialization_default.cpp",
     "src/ports/SkImageGenerator_skia.cpp",
     "src/ports/SkMemory_malloc.cpp",
     "src/ports/SkOSFile_stdio.cpp",
     "src/sfnt/SkOTTable_name.cpp",
     "src/sfnt/SkOTUtils.cpp",
     "src/svg/SkSVGCanvas.cpp",
     "src/svg/SkSVGDevice.cpp",
     "src/utils/mac/SkStream_mac.cpp",
-    "src/xml/SkDOM.cpp",
-    "src/xml/SkXMLParser.cpp",
-    "src/xml/SkXMLWriter.cpp",
     "third_party/etc1/etc1.cpp",
     "third_party/ktx/ktx.cpp",
   ]
   sources -= [
     "src/gpu/gl/GrGLCreateNativeInterface_none.cpp",
     "src/gpu/gl/GrGLDefaultInterface_none.cpp",
   ]
 
   if (is_win) {
     sources += [
@@ skipping 338 matching lines @@
       "tools/SkShaper_harfbuzz.cpp",
       "tools/using_skia_and_harfbuzz.cpp",
     ]
     deps = [
       ":skia",
       "//third_party/harfbuzz",
     ]
     testonly = true
   }
 }