Add signal strength indicator icon to WebBluetooth chooser on Mac

chrome/browser/ui/cocoa/chooser_content_view_cocoa.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/chooser_content_view_cocoa.h"
 
 #include <algorithm>
 
 #include "base/macros.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/chooser_controller/chooser_controller.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_button.h"
 #include "chrome/browser/ui/cocoa/spinner_view.h"
 #include "chrome/grit/generated_resources.h"
+#include "grit/ui_resources.h"
 #import "third_party/google_toolbox_for_mac/src/AppKit/GTMUILocalizerAndLayoutTweaker.h"
 #import "ui/base/cocoa/controls/hyperlink_button_cell.h"
 #include "ui/base/l10n/l10n_util_mac.h"
+#include "ui/base/resource/resource_bundle.h"
 
 namespace {
 
 // Chooser width.
 const CGFloat kChooserWidth = 350.0f;
 
 // Chooser height.
 const CGFloat kChooserHeight = 300.0f;
 
+// Signal strength level image size.
+const CGFloat kSignalStrengthLevelImageSize = 20.0f;
+
+// Table row view height.
+const CGFloat kTableRowViewHeight = 23.0f;
+
 // Spinner size.
 const CGFloat kSpinnerSize = 24.0f;
 
 // Distance between the chooser border and the view that is closest to the
 // border.
 const CGFloat kMarginX = 20.0f;
 const CGFloat kMarginY = 20.0f;
 
 // Distance between two views inside the chooser.
 const CGFloat kHorizontalPadding = 10.0f;
 const CGFloat kVerticalPadding = 10.0f;
 
 // Separator alpha value.
 const CGFloat kSeparatorAlphaValue = 0.6f;
 
 // Separator height.
 const CGFloat kSeparatorHeight = 1.0f;
 
+// The lookup table for signal strength level image.
+const int signalStrengthLevelImageIds[5] = {IDR_SIGNAL_0_BAR, IDR_SIGNAL_1_BAR,

[Jeffrey Yasskin, 2016/08/19 18:30:05]

Use kConstant naming:
https://google.github.io/styleguide/cppguide.html#Constant_Names

[juncai, 2016/08/22 19:18:20]

Done.

+                                            IDR_SIGNAL_2_BAR, IDR_SIGNAL_3_BAR,
+                                            IDR_SIGNAL_4_BAR};
+
 }  // namespace
 
+// A table row view that contains one line of text, and optionally contains an
+// image in front of the text.
+@interface TableRowView : NSView {
+ @private
+  base::scoped_nsobject<NSImageView> image_;
+  base::scoped_nsobject<NSTextField> text_;
+}
+
+// Designated initializer.
+- (instancetype)initWithText:(NSString*)text
+         signalStrengthLevel:(NSInteger)level;
+
+// Gets the image in front of the text.
+- (NSImageView*)image;
+
+// Gets the text.
+- (NSTextField*)text;
+
+@end
+
+@implementation TableRowView
+
+- (instancetype)initWithText:(NSString*)text
+         signalStrengthLevel:(NSInteger)level {
+  if ((self = [super initWithFrame:NSZeroRect])) {
+    if (level != -1) {
+      DCHECK_GE(level, 0);
+      DCHECK_LT(level, base::checked_cast<NSInteger>(
+                           arraysize(signalStrengthLevelImageIds)));
+      ui::ResourceBundle& rb = ui::ResourceBundle::GetSharedInstance();
+      NSImage* signalStrengthLevelImage =
+          rb.GetNativeImageNamed(signalStrengthLevelImageIds[level])
+              .ToNSImage();
+
+      image_.reset([[NSImageView alloc]
+          initWithFrame:NSMakeRect(0, (kTableRowViewHeight -
+                                       kSignalStrengthLevelImageSize) /
+                                          2,
+                                   kSignalStrengthLevelImageSize,
+                                   kSignalStrengthLevelImageSize)]);
+      [image_ setImage:signalStrengthLevelImage];
+      [self addSubview:image_];
+    }
+
+    text_.reset([[NSTextField alloc] initWithFrame:NSZeroRect]);
+    [text_ setDrawsBackground:NO];
+    [text_ setBezeled:NO];
+    [text_ setEditable:NO];
+    [text_ setSelectable:NO];
+    [text_ setStringValue:text];
+    [text_ setFont:[NSFont systemFontOfSize:[NSFont systemFontSize]]];
+    [text_ sizeToFit];
+    CGFloat textHeight = NSHeight([text_ frame]);
+    [text_ setFrameOrigin:NSMakePoint(
+                              level == -1 ? 0 : kSignalStrengthLevelImageSize +
+                                                    kVerticalPadding,

[Jeffrey Yasskin, 2016/08/19 18:30:05]

Shouldn't this be kHorizontalPadding?

[juncai, 2016/08/22 19:18:20]

Done.

+                              (kTableRowViewHeight - textHeight) / 2)];
+    [self addSubview:text_];
+  }
+
+  return self;
+}
+
+- (NSImageView*)image {
+  return image_.get();
+}
+
+- (NSTextField*)text {
+  return text_.get();
+}
+
+@end
+
 class ChooserContentViewController : public ChooserController::View {
  public:
   ChooserContentViewController(ChooserContentViewCocoa* chooser_content_view,
                                ChooserController* chooser_controller,
                                NSTableView* table_view,
                                SpinnerView* spinner,
                                NSTextField* status,
                                NSButton* rescan_button);
   ~ChooserContentViewController() override;
 
@@ skipping 111 matching lines @@
   // When refreshing, show |status_| and hide |rescan_button_|.
   // When complete, show |rescan_button_| and hide |status_|.
   [status_ setHidden:refreshing ? NO : YES];
   [rescan_button_ setHidden:refreshing ? YES : NO];
 
   [chooser_content_view_ updateView];
 }
 
 void ChooserContentViewController::UpdateTableView() {
   [table_view_ setEnabled:chooser_controller_->NumOptions() > 0];
+  // For NSView-based table views, calling reloadData will deselect the
+  // currently selected row, so |selected_row| stores the currently selected
+  // row in order to select it again.
+  NSInteger selected_row = [table_view_ selectedRow];
   [table_view_ reloadData];
+  if (selected_row != -1) {
+    [table_view_ selectRowIndexes:[NSIndexSet indexSetWithIndex:selected_row]
+             byExtendingSelection:NO];
+  }
 }
 
 @implementation ChooserContentViewCocoa
 
 // TODO(juncai): restructure this function to be some smaller methods to
 // create the pieces for the view. By doing so, the methods that calculate
 // the frame and origins can be moved into those methods, rather than as
 // helper functions.
 - (instancetype)initWithChooserTitle:(NSString*)chooserTitle
                    chooserController:
@@ skipping 199 matching lines @@
   [titleView setEditable:NO];
   [titleView setSelectable:NO];
   [titleView setStringValue:title];
   [titleView setFont:[NSFont systemFontOfSize:[NSFont systemFontSize]]];
   // The height is arbitrary as it will be adjusted later.
   [titleView setFrameSize:NSMakeSize(kChooserWidth - 2 * kMarginX, 0.0f)];
   [GTMUILocalizerAndLayoutTweaker sizeToFitFixedWidthTextField:titleView];
   return titleView;
 }
 
+- (NSView*)createTableRowView:(NSInteger)rowIndex {
+  NSInteger level = -1;
+  size_t numOptions = chooserController_->NumOptions();
+  if (chooserController_->ShouldShowIconBeforeText() && numOptions > 0) {

[Jeffrey Yasskin, 2016/08/19 18:30:05]

Dumb question: why is createTableRowView called with a particular rowIndex if
there are no options?

[juncai, 2016/08/22 19:18:20]

If numOptions == 0, the actual number rows is 1 since it needs to display
"Bluetooth devices not found" or "Devices not found" in the table view, so still
need to call createTableRowView to create a row, and a DCHECK checks the
rowIndex is always 0 in this case:
https://cs.chromium.org/chromium/src/chrome/browser/ui/cocoa/chooser_content_...

[Jeffrey Yasskin, 2016/08/22 21:59:24]

Ah, I see. Could you comment that here? Like "This function is called with
numOptions==0 to show the "not found" message."

[juncai, 2016/08/23 00:30:40]

Done.

+    DCHECK_GE(rowIndex, 0);
+    DCHECK_LT(rowIndex, base::checked_cast<NSInteger>(numOptions));
+    level = base::checked_cast<NSInteger>(
+        chooserController_->GetSignalStrengthLevel(
+            base::checked_cast<size_t>(rowIndex)));
+  }
+
+  base::scoped_nsobject<TableRowView> tableRowView([[TableRowView alloc]
+             initWithText:[self optionAtIndex:rowIndex]

[Jeffrey Yasskin, 2016/08/19 18:30:05]

This indentation looks kinda weird.

[juncai, 2016/08/22 19:18:20]

I used "git cl format" to format it. I guess here the two ":" need to be
aligned, and "signalStrengthLevel:level]);" has longer string length before the
":" than "initWithText:[self optionAtIndex:rowIndex]", so
signalStrengthLevel:level]); is indented 4 characters.

[Jeffrey Yasskin, 2016/08/22 21:59:24]

If `git cl format` did it, it's fine with me. :)

[juncai, 2016/08/23 00:30:40]

Acknowledged.

+      signalStrengthLevel:level]);
+  return tableRowView.autorelease();
+}
+
+- (CGFloat)tableRowViewHeight:(NSInteger)row {
+  return kTableRowViewHeight;
+}
+
 - (base::scoped_nsobject<NSButton>)createButtonWithTitle:(NSString*)title {
   base::scoped_nsobject<NSButton> button(
       [[ConstrainedWindowButton alloc] initWithFrame:NSZeroRect]);
   [button setButtonType:NSMomentaryPushInButton];
   [button setTitle:title];
   [button sizeToFit];
   return button;
 }
 
 - (base::scoped_nsobject<NSButton>)createConnectButton {
@@ skipping 160 matching lines @@
 }
 
 - (void)onRescan:(id)sender {
   chooserController_->RefreshOptions();
 }
 
 - (void)onHelpPressed:(id)sender {
   chooserController_->OpenHelpCenterUrl();
 }
 
+- (NSImageView*)tableRowViewImage:(NSInteger)row {
+  TableRowView* tableRowView =
+      [tableView_ viewAtColumn:0 row:row makeIfNecessary:YES];
+  return [tableRowView image];
+}
+
+- (NSTextField*)tableRowViewText:(NSInteger)row {
+  TableRowView* tableRowView =
+      [tableView_ viewAtColumn:0 row:row makeIfNecessary:YES];
+  return [tableRowView text];
+}
+
 @end