blimp: Move compositing, input and render widget feature to client/core.

blimp/client/core/render_widget/BUILD.gn

Index: blimp/client/core/render_widget/BUILD.gn
diff --git a/blimp/client/core/render_widget/BUILD.gn b/blimp/client/core/render_widget/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..7a215045fc6f643da900ff21f5ed7c216f424ff1
--- /dev/null
+++ b/blimp/client/core/render_widget/BUILD.gn
@@ -0,0 +1,85 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+if (is_android) {
+  import("//build/config/android/config.gni")
+  import("//build/config/android/rules.gni")
+}
+
+source_set("render_widget") {
+  visibility = [
+    "//blimp/client/*",
+    "//blimp/engine:browser_tests",
+  ]
+
+  sources = [
+    "blimp_render_widget.cc",
+    "blimp_render_widget.h",
+    "blimp_render_widget_delegate.h",
+    "render_widget_feature.cc",
+    "render_widget_feature.h",
+  ]
+
+  deps = [
+    "//base:base",
+    "//blimp/client/core/compositor:compositor_support",
+    "//blimp/client/core/input",
+    "//blimp/common",
+    "//blimp/net",
+    "//cc",
+    "//cc/proto",
+    "//net:net",
+  ]
+
+  public_deps = [
+    "//blimp/client/core/compositor",
+    "//blimp/common/proto",
+  ]
+}
+
+source_set("test_support") {
+  testonly = true
+
+  sources = [
+    "mock_render_widget_feature_delegate.cc",
+    "mock_render_widget_feature_delegate.h",
+  ]
+
+  deps = [
+    ":render_widget",
+    "//testing/gmock",
+  ]
+}
+
+source_set("unit_tests") {
+  visibility = [ "//blimp/client/core:unit_tests" ]
+
+  testonly = true
+
+  sources = [
+    "render_widget_feature_unittest.cc",
+  ]
+
+  if (is_linux) {
+    #TODO(khushalsagar): Run these tests for android.
+    sources += [ "blimp_render_widget_unittest.cc" ]
+  }
+
+  deps = [
+    ":render_widget",
+    ":test_support",
+    "//base",
+    "//base/test:test_support",
+    "//blimp/client/core/compositor:compositor_support",
+    "//blimp/common",
+    "//blimp/common/proto",
+    "//blimp/net",
+    "//blimp/net:test_support",
+    "//cc/proto",
+    "//net",
+    "//net:test_support",
+    "//testing/gmock",
+    "//testing/gtest",
+  ]
+}