Clean up GN template code.

build/toolchain/nacl/BUILD.gn

 # Copyright (c) 2014 The Native Client Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 import("//build/config/nacl/config.gni")
 import("//build/toolchain/nacl_toolchain.gni")
 
 # Add the toolchain revision as a preprocessor define so that sources are
 # rebuilt when a toolchain is updated.
 # Idea we could use the toolchain deps feature, but currently that feature is
 # bugged and does not trigger a rebuild.
 # https://code.google.com/p/chromium/issues/detail?id=431880
 # Calls to get the toolchain revision are relatively slow, so do them all in a
 # single batch to amortize python startup, etc.
 revisions = exec_script("//native_client/build/get_toolchain_revision.py",
                         [
                           "nacl_x86_glibc",
                           "nacl_arm_glibc",
                           "pnacl_newlib",
                         ],
                         "trim list lines")
 nacl_x86_glibc_rev = revisions[0]
 nacl_arm_glibc_rev = revisions[1]
 
-# TODO(mcgrathr): Uncomment this when
-# https://code.google.com/p/chromium/issues/detail?id=395883 is fixed.
-#pnacl_newlib_rev = revisions[2]
+pnacl_newlib_rev = revisions[2]
+
+if (host_os == "win") {
+  toolsuffix = ".exe"
+} else {
+  toolsuffix = ""
+}
+
+# The PNaCl toolchain tools are all wrapper scripts rather than binary
+# executables.  On POSIX systems, nobody cares what kind of executable
+# file you are.  But on Windows, scripts (.bat files) cannot be run
+# directly and need the Windows shell (cmd.exe) specified explicily.
+if (host_os == "win") {
+  # NOTE!  The //build/toolchain/gcc_*_wrapper.py scripts recognize
+  # this exact prefix string, so they must be updated if this string
+  # is changed in any way.
+  scriptprefix = "cmd /c call "
+  scriptsuffix = ".bat"
+} else {
+  scriptprefix = ""
+  scriptsuffix = ""
+}
+
+# When the compilers are run via goma or ccache rather than directly by
+# GN/Ninja, the goma/ccache wrapper handles .bat files but gets confused
+# by being given the scriptprefix.
+if (host_os == "win" && !use_goma && cc_wrapper == "") {
+  compiler_scriptprefix = scriptprefix
+} else {
+  compiler_scriptprefix = ""
+}
 
 template("pnacl_toolchain") {
   assert(defined(invoker.executable_extension),
          "Must define executable_extension")
 
-  # TODO(mcgrathr): See above.
-  pnacl_newlib_rev = revisions[2]
-
-  # The PNaCl toolchain tools are all wrapper scripts rather than binary
-  # executables.  On POSIX systems, nobody cares what kind of executable
-  # file you are.  But on Windows, scripts (.bat files) cannot be run
-  # directly and need the Windows shell (cmd.exe) specified explicily.
-  # TODO(mcgrathr): Hoist this to top level when
-  # https://code.google.com/p/chromium/issues/detail?id=395883 is fixed.
-  if (host_os == "win") {
-    # NOTE!  The //build/toolchain/gcc_*_wrapper.py scripts recognize
-    # this exact prefix string, so they must be updated if this string
-    # is changed in any way.
-    scriptprefix = "cmd /c call "
-    scriptsuffix = ".bat"
-  } else {
-    scriptprefix = ""
-    scriptsuffix = ""
-  }
-
-  # When the compilers are run via goma or ccache rather than directly by
-  # GN/Ninja, the goma/ccache wrapper handles .bat files but gets confused
-  # by being given the scriptprefix.
-  if (host_os == "win" && !use_goma && cc_wrapper == "") {
-    compiler_scriptprefix = scriptprefix
-  } else {
-    compiler_scriptprefix = ""
-  }
-
   nacl_toolchain(target_name) {
     toolchain_package = "pnacl_newlib"
     toolchain_revision = pnacl_newlib_rev
     toolprefix =
         rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/pnacl-",
                     root_build_dir)
 
     cc = compiler_scriptprefix + toolprefix + "clang" + scriptsuffix
     cxx = compiler_scriptprefix + toolprefix + "clang++" + scriptsuffix
     ar = scriptprefix + toolprefix + "ar" + scriptsuffix
@@ skipping 42 matching lines @@
   forward_variables_from(invoker,
                          [
                            "toolchain_package",
                            "toolchain_revision",
                          ])
 
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
                            root_build_dir)
 
-  # TODO(mcgrathr): Hoist this to top level when
-  # https://code.google.com/p/chromium/issues/detail?id=395883 is fixed.
-  if (host_os == "win") {
-    toolsuffix = ".exe"
-  } else {
-    toolsuffix = ""
-  }
-
   nacl_toolchain("glibc_" + toolchain_cpu) {
     cc = toolprefix + "gcc" + toolsuffix
     cxx = toolprefix + "g++" + toolsuffix
     ar = toolprefix + "ar" + toolsuffix
     ld = cxx
     readelf = toolprefix + "readelf" + toolsuffix
     nm = toolprefix + "nm" + toolsuffix
     strip = toolprefix + "strip" + toolsuffix
 
     toolchain_args = {
@@ skipping 25 matching lines @@
 nacl_glibc_toolchain("arm") {
   toolchain_package = "nacl_arm_glibc"
   toolchain_revision = nacl_arm_glibc_rev
   toolchain_tuple = "arm-nacl"
 }
 
 template("nacl_clang_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
-  # TODO(mcgrathr): See above.
-  pnacl_newlib_rev = revisions[2]
-
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
                            root_build_dir)
 
-  # TODO(mcgrathr): Hoist this to top level when
-  # https://code.google.com/p/chromium/issues/detail?id=395883 is fixed.
-  if (host_os == "win") {
-    toolsuffix = ".exe"
-  } else {
-    toolsuffix = ""
-  }
-
   nacl_toolchain("clang_newlib_" + toolchain_cpu) {
     cc = toolprefix + "clang" + toolsuffix
     cxx = toolprefix + "clang++" + toolsuffix
     ar = toolprefix + "ar" + toolsuffix
     ld = cxx
     readelf = toolprefix + "readelf" + toolsuffix
     nm = toolprefix + "nm" + toolsuffix
     strip = toolprefix + "strip" + toolsuffix
 
     toolchain_args = {
       current_cpu = toolchain_cpu
       is_clang = true
     }
   }
 }
 
 template("nacl_irt_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
-  # TODO(mcgrathr): See above.
-  pnacl_newlib_rev = revisions[2]
-
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
                            root_build_dir)
 
-  # TODO(mcgrathr): Hoist this to top level when
-  # https://code.google.com/p/chromium/issues/detail?id=395883 is fixed.
-  if (host_os == "win") {
-    toolsuffix = ".exe"
-  } else {
-    toolsuffix = ""
-  }
-
   link_irt = rebase_path("//native_client/build/link_irt.py", root_build_dir)
 
   tls_edit_label =
       "//native_client/src/tools/tls_edit:tls_edit($host_toolchain)"
   host_toolchain_out_dir =
       rebase_path(get_label_info(tls_edit_label, "root_out_dir"),
                   root_build_dir)
   tls_edit = "${host_toolchain_out_dir}/tls_edit"
 
   nacl_toolchain("irt_" + toolchain_cpu) {
@@ skipping 39 matching lines @@
   toolchain_tuple = "x86_64-nacl"
 }
 
 nacl_clang_toolchains("x64") {
   toolchain_tuple = "x86_64-nacl"
 }
 
 nacl_clang_toolchains("arm") {
   toolchain_tuple = "arm-nacl"
 }