Mac: Share kScrollbarPixelsPerCocoaTick between ui:: and blink:: events

ui/events/test/cocoa_test_event_utils.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/events/test/cocoa_test_event_utils.h"
 
 #include <stdint.h>
 
+#include "base/mac/scoped_cftyperef.h"
 #include "base/time/time.h"
 #include "ui/events/base_event_utils.h"
 #import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 
 namespace cocoa_test_event_utils {
 
+CGPoint ScreenPointFromWindow(NSPoint window_point, NSWindow* window) {
+  NSRect window_rect = NSMakeRect(window_point.x, window_point.y, 0, 0);
+  NSPoint screen_point = window
+                             ? [window convertRectToScreen:window_rect].origin
+                             : window_rect.origin;
+  CGFloat primary_screen_height =
+      NSHeight([[[NSScreen screens] firstObject] frame]);
+  screen_point.y = primary_screen_height - screen_point.y;
+  return NSPointToCGPoint(screen_point);
+}
+
+NSEvent* AttachWindowToCGEvent(CGEventRef event, NSWindow* window) {
+  // These CGEventFields were made public in the 10.7 SDK, but don't help to
+  // populate the -[NSEvent window] pointer when creating an event with
+  // +[NSEvent eventWithCGEvent:]. Set that separately, using reflection.
+  CGEventSetIntegerValueField(event, kCGMouseEventWindowUnderMousePointer,
+                              [window windowNumber]);
+  CGEventSetIntegerValueField(
+      event, kCGMouseEventWindowUnderMousePointerThatCanHandleThisEvent,
+      [window windowNumber]);
+
+  // CGEventTimestamp is nanoseconds since system startup as a 64-bit integer.
+  // Use EventTimeForNow() so that it can be mocked for tests.
+  CGEventTimestamp timestamp =
+      (ui::EventTimeForNow() - base::TimeTicks()).InMicroseconds() *
+      base::Time::kNanosecondsPerMicrosecond;
+  CGEventSetTimestamp(event, timestamp);
+
+  NSEvent* ns_event = [NSEvent eventWithCGEvent:event];
+  DCHECK_EQ(nil, [ns_event window]);  // Verify assumptions.
+  [ns_event setValue:window forKey:@"_window"];
+  DCHECK_EQ(window, [ns_event window]);
+
+  return ns_event;
+}
+
 NSEvent* MouseEventAtPoint(NSPoint point, NSEventType type,
                            NSUInteger modifiers) {
   if (type == NSOtherMouseUp) {
     // To synthesize middle clicks we need to create a CGEvent with the
     // "center" button flags so that our resulting NSEvent will have the
     // appropriate buttonNumber field. NSEvent provides no way to create a
     // mouse event with a buttonNumber directly.
     CGPoint location = { point.x, point.y };
     CGEventRef cg_event = CGEventCreateMouseEvent(NULL, kCGEventOtherMouseUp,
                                                   location,
@@ skipping 66 matching lines @@
                                                     NSUInteger clickCount) {
   const NSRect bounds = [view convertRect:[view bounds] toView:nil];
   const NSPoint mid_point = NSMakePoint(NSMidX(bounds), NSMidY(bounds));
   NSEvent* down = MouseEventAtPointInWindow(mid_point, NSRightMouseDown,
                                             [view window], clickCount);
   NSEvent* up = MouseEventAtPointInWindow(mid_point, NSRightMouseUp,
                                           [view window], clickCount);
   return std::make_pair(down, up);
 }
 
+NSEvent* TestScrollEvent(NSPoint location,
+                         NSWindow* window,
+                         CGFloat delta_x,
+                         CGFloat delta_y) {
+  const uint32_t wheel_count = 2;
+  int32_t wheel1 = static_cast<int>(delta_y);
+  int32_t wheel2 = static_cast<int>(delta_x);
+  CGScrollEventUnit units = kCGScrollEventUnitLine;
+  base::ScopedCFTypeRef<CGEventRef> scroll(CGEventCreateScrollWheelEvent(
+      nullptr, units, wheel_count, wheel1, wheel2));
+  CGEventSetLocation(scroll, ScreenPointFromWindow(location, window));
+  return AttachWindowToCGEvent(scroll, window);
+}
+
 NSEvent* KeyEventWithCharacter(unichar c) {
   return KeyEventWithKeyCode(0, c, NSKeyDown, 0);
 }
 
 NSEvent* KeyEventWithType(NSEventType event_type, NSUInteger modifiers) {
   return KeyEventWithKeyCode(0x78, 'x', event_type, modifiers);
 }
 
 NSEvent* KeyEventWithKeyCode(unsigned short key_code,
                              unichar c,
@@ skipping 130 matching lines @@
                                      context:nil
                                   characters:characters
                  charactersIgnoringModifiers:charactersIgnoringModifiers
                                    isARepeat:NO
                                      keyCode:(unsigned short)macKeycode];
 
   return event;
 }
 
 }  // namespace cocoa_test_event_utils