move //media/capture to //device/capture

device/capture/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//media/media_options.gni")
 import("//testing/test.gni")
+if (is_android) {
+  import("//build/config/android/rules.gni")  # For generate_jni().
+}
 
 component("capture") {
   defines = [ "CAPTURE_IMPLEMENTATION" ]
+
   sources = [
     "capture_export.h",
+    "content/android/screen_capture_jni_registrar.cc",
+    "content/android/screen_capture_jni_registrar.h",
+    "content/android/screen_capture_machine_android.cc",
+    "content/android/screen_capture_machine_android.h",
     "content/animated_content_sampler.cc",
     "content/animated_content_sampler.h",
     "content/capture_resolution_chooser.cc",
     "content/capture_resolution_chooser.h",
     "content/screen_capture_device_core.cc",
     "content/screen_capture_device_core.h",
     "content/smooth_event_sampler.cc",
     "content/smooth_event_sampler.h",
     "content/thread_safe_capture_oracle.cc",
     "content/thread_safe_capture_oracle.h",
     "content/video_capture_oracle.cc",
     "content/video_capture_oracle.h",
     "device_monitor_mac.h",
     "device_monitor_mac.mm",
     "system_message_window_win.cc",
     "system_message_window_win.h",
+    "video/android/capture_jni_registrar.cc",
+    "video/android/capture_jni_registrar.h",
+    "video/android/photo_capabilities.cc",
+    "video/android/photo_capabilities.h",
+    "video/android/video_capture_device_android.cc",
+    "video/android/video_capture_device_android.h",
+    "video/android/video_capture_device_factory_android.cc",
+    "video/android/video_capture_device_factory_android.h",
     "video/fake_video_capture_device.cc",
     "video/fake_video_capture_device.h",
     "video/fake_video_capture_device_factory.cc",
     "video/fake_video_capture_device_factory.h",
     "video/file_video_capture_device.cc",
     "video/file_video_capture_device.h",
     "video/file_video_capture_device_factory.cc",
     "video/file_video_capture_device_factory.h",
     "video/linux/v4l2_capture_delegate.cc",
     "video/linux/video_capture_device_chromeos.cc",
@@ skipping 36 matching lines @@
     "video/win/video_capture_device_win.h",
   ]
 
   public_deps = []
   deps = [
     "//base",
     "//base:i18n",
     "//media",
     "//media/mojo/interfaces:image_capture",
     "//skia",
+    "//third_party/libyuv",
     "//ui/display",
     "//ui/gfx",
   ]
 
-  configs += [
-    # TODO(mcasas): media/base should be a component and not a source_set, but
-    # it depends on parts of media/filters, media/ffmpeg etc. Until then, we
-    # pretend to be inside media.dll and duplicate the few symbols needed, see
-    # https://crbug.com/590017.
-    "//media:media_implementation",
-  ]
-
   if (is_android) {
-    public_deps += [
-      "content/android",
-      "video/android",
-    ]
-    deps += [
-      "content/android:screen_capture_jni_headers",
-      "video/android:capture_jni_headers",
-    ]
+    deps += [ ":capture_jni_headers" ]
   }
 
   if (is_mac) {
     deps += [ "//third_party/decklink" ]
     libs = [
       "CoreFoundation.framework",
       "CoreGraphics.framework",
       "CoreVideo.framework",
       "Foundation.framework",
     ]
   }
 
   if (use_udev) {
     deps += [ "//device/udev_linux" ]
     sources += [
       "device_monitor_udev.cc",
       "device_monitor_udev.h",
     ]
   }
 
   if (is_win) {
-    deps += [
-      "//media/base",  # For media_switches.
-      "//media/base/win",
-    ]
+    deps += [ "//media/base/win" ]
     libs = [
       "mf.lib",
       "mfplat.lib",
       "mfreadwrite.lib",
       "mfuuid.lib",
+      "strmiids.lib",
     ]
     ldflags = [
       "/DELAYLOAD:mf.dll",
       "/DELAYLOAD:mfplat.dll",
       "/DELAYLOAD:mfreadwrite.dll",
     ]
 
     # TODO(jschuh): https://crbug.com/167187 fix size_t to int truncations.
     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
   }
 }
 
+if (is_android) {
+  generate_jni("capture_jni_headers") {
+    sources = [
+      "content/android/java/src/org/chromium/device/ScreenCapture.java",
+      "video/android/java/src/org/chromium/device/PhotoCapabilities.java",
+      "video/android/java/src/org/chromium/device/VideoCapture.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureFactory.java",
+    ]
+    jni_package = "device"
+  }
+
+  java_cpp_enum("capture_java_enums_srcjar") {
+    sources = [
+      "video/android/video_capture_device_android.h",
+      "video/video_capture_device_descriptor.h",
+    ]
+  }
+
+  android_library("capture_java") {
+    deps = [
+      ":capture",
+      ":capture_jni_headers",
+      "//base:base_java",
+      "//third_party/android_tools:android_support_annotations_java",
+    ]
+
+    srcjar_deps = [ ":capture_java_enums_srcjar" ]
+
+    java_files = [
+      "content/android/java/src/org/chromium/device/ScreenCapture.java",
+      "video/android/java/src/org/chromium/device/PhotoCapabilities.java",
+      "video/android/java/src/org/chromium/device/VideoCapture.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureAndroid.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureCamera.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureCamera2.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureFactory.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureFormat.java",
+      "video/android/java/src/org/chromium/device/VideoCaptureTango.java",
+    ]
+  }
+}
+
 test("capture_unittests") {
   sources = [
     "content/animated_content_sampler_unittest.cc",
     "content/capture_resolution_chooser_unittest.cc",
     "content/smooth_event_sampler_unittest.cc",
     "content/video_capture_oracle_unittest.cc",
     "system_message_window_win_unittest.cc",
     "video/fake_video_capture_device_unittest.cc",
     "video/mac/video_capture_device_factory_mac_unittest.mm",
     "video/video_capture_device_unittest.cc",
   ]
 
   deps = [
     ":capture",
     "//base/test:run_all_unittests",
     "//base/test:test_support",
+    "//media:test_support",
     "//media/base:test_support",
     "//media/mojo/interfaces:image_capture",
     "//testing/gmock",
     "//testing/gtest",
     "//ui/gfx:test_support",
   ]
 
   if (is_android) {
     deps += [
-      "//media/capture/video/android",
-      "//media/capture/video/android:capture_java",
+      ":capture_java",
+      ":capture_jni_headers",
     ]
   }
 
   if (is_win) {
     # TODO(jschuh): https://crbug.com/167187 fix size_t to int truncations.
     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
   }
 }