[Mac] Enable "Edit Search Engines" in Omnibox context menu.

chrome/browser/cocoa/keyword_editor_cocoa_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <Cocoa/Cocoa.h>
 
 #import "base/mac_util.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/browser_process.h"
 #import "chrome/browser/cocoa/edit_search_engine_cocoa_controller.h"
@@ skipping 33 matching lines @@
   KeywordEditorController* controller = [controller_ controller];
   if (template_url) {
     controller->ModifyTemplateURL(template_url, title, keyword, url);
   } else {
     controller->AddTemplateURL(title, keyword, url);
   }
 }
 
 // KeywordEditorCocoaController -----------------------------------------------
 
+namespace {
+
+typedef std::map<Profile*,KeywordEditorCocoaController*> ProfileControllerMap;
+
+}  // namespace
+
 @implementation KeywordEditorCocoaController
 
++ (KeywordEditorCocoaController*)sharedInstanceForProfile:(Profile*)profile {
+  ProfileControllerMap* map = Singleton<ProfileControllerMap>::get();
+  DCHECK(map != NULL);
+  ProfileControllerMap::iterator it = map->find(profile);
+  if (it != map->end()) {
+    return it->second;
+  }
+  return nil;
+}
+
+// TODO(shess): The Windows code watches a single global window which
+// is not distinguished by profile.  This code could distinguish by
+// profile by checking the controller's class and profile.
++ (void)showKeywordEditor:(Profile*)profile {
+  // http://crbug.com/23359 describes a case where this panel is
+  // opened from an incognito window, which can leave the panel
+  // holding onto a stale profile.  Since the same panel is used
+  // either way, arrange to use the original profile instead.
+  if (profile->IsOffTheRecord()) {
+    profile = profile->GetOriginalProfile();
+  }
+
+  ProfileControllerMap* map = Singleton<ProfileControllerMap>::get();
+  DCHECK(map != NULL);
+  ProfileControllerMap::iterator it = map->find(profile);
+  if (it == map->end()) {
+    // Since we don't currently support multiple profiles, this class
+    // has not been tested against them, so document that assumption.
+    DCHECK_EQ(map->size(), 0U);
+
+    KeywordEditorCocoaController* controller =
+        [[self alloc] initWithProfile:profile];
+    it = map->insert(std::make_pair(profile, controller)).first;
+  }
+
+  [it->second showWindow:nil];
+}
+
 - (id)initWithProfile:(Profile*)profile {
   DCHECK(profile);
   NSString* nibpath = [mac_util::MainAppBundle()
                         pathForResource:@"KeywordEditor"
                                  ofType:@"nib"];
   if ((self = [super initWithWindowNibPath:nibpath owner:self])) {
     profile_ = profile;
     controller_.reset(new KeywordEditorController(profile_));
     observer_.reset(new KeywordEditorModelObserver(self));
     controller_->url_model()->AddObserver(observer_.get());
@@ skipping 23 matching lines @@
   }
 
   [self adjustEditingButtons];
   [tableView_ setDoubleAction:@selector(editKeyword:)];
   [tableView_ setTarget:self];
 }
 
 // When the window closes, clean ourselves up.
 - (void)windowWillClose:(NSNotification*)notif {
   [self autorelease];
+
+  ProfileControllerMap* map = Singleton<ProfileControllerMap>::get();
+  ProfileControllerMap::iterator it = map->find(profile_);
+  // It should not be possible for this to be missing.
+  // TODO(shess): Except that the unit test reaches in directly.
+  // Consider circling around and refactoring that.
+  //DCHECK(it != map->end());
+  if (it != map->end()) {
+    map->erase(it);
+  }
 }
 
 // The last page info window that was moved will determine the location of the
 // next new one.
 - (void)windowDidMove:(NSNotification*)notif {
   if (g_browser_process && g_browser_process->local_state()) {
     NSWindow* window = [self window];
     [window saveWindowPositionToPrefs:g_browser_process->local_state()
                              withPath:prefs::kKeywordEditorWindowPlacement];
   }
@@ skipping 124 matching lines @@
   if ([selection count] != 1) {
     [makeDefaultButton_ setEnabled:NO];
   } else {
     const TemplateURL& url =
         controller_->table_model()->GetTemplateURL([selection firstIndex]);
     [makeDefaultButton_ setEnabled:controller_->CanMakeDefault(&url)];
   }
 }
 
 @end