| OLD | NEW |
|---|
| (Empty) | |
| 1 # Copyright 2016 the V8 project authors. All rights reserved. |
| 2 # Use of this source code is governed by a BSD-style license that can be |
| 3 # found in the LICENSE file. |
| 4 |
| 5 protocol_path = "//third_party/WebKit/Source/platform/inspector_protocol" |
| 6 protocol_sources = [ |
| 7 "$target_gen_dir/Console.cpp", |
| 8 "$target_gen_dir/Console.h", |
| 9 "$target_gen_dir/Debugger.cpp", |
| 10 "$target_gen_dir/Debugger.h", |
| 11 "$target_gen_dir/HeapProfiler.cpp", |
| 12 "$target_gen_dir/HeapProfiler.h", |
| 13 "$target_gen_dir/Profiler.cpp", |
| 14 "$target_gen_dir/Profiler.h", |
| 15 "$target_gen_dir/Runtime.cpp", |
| 16 "$target_gen_dir/Runtime.h", |
| 17 ] |
| 18 |
| 19 action("inspector_protocol_sources") { |
| 20 visibility = [ ":*" ] # Only targets in this file can depend on this. |
| 21 script = "$protocol_path/CodeGenerator.py" |
| 22 sources = [ |
| 23 "$protocol_path/CodeGenerator.py", |
| 24 "$protocol_path/Exported_h.template", |
| 25 "$protocol_path/Imported_h.template", |
| 26 "$protocol_path/TypeBuilder_cpp.template", |
| 27 "$protocol_path/TypeBuilder_h.template", |
| 28 ] |
| 29 inputs = [ |
| 30 "js_protocol.json", |
| 31 ] |
| 32 outputs = protocol_sources |
| 33 args = [ |
| 34 "--protocol", |
| 35 rebase_path("js_protocol.json", root_build_dir), |
| 36 "--string_type", |
| 37 "String", |
| 38 "--export_macro", |
| 39 "PLATFORM_EXPORT", |
| 40 "--output_dir", |
| 41 rebase_path(target_gen_dir, root_build_dir), |
| 42 "--output_package", |
| 43 "inspector", |
| 44 ] |
| 45 } |
| 46 |
| 47 config("inspector_protocol_config") { |
| 48 include_dirs = [ |
| 49 "$protocol_path/../..", |
| 50 ] |
| 51 defines = [ |
| 52 "V8_INSPECTOR_USE_STL" |
| 53 ] |
| 54 cflags = [] |
| 55 if (is_win) { |
| 56 cflags += [ |
| 57 "/wd4267", # Truncation from size_t to int. |
| 58 "/wd4305", # Truncation from 'type1' to 'type2'. |
| 59 "/wd4324", # Struct padded due to declspec(align). |
| 60 "/wd4714", # Function marked forceinline not inlined. |
| 61 "/wd4800", # Value forced to bool. |
| 62 "/wd4996", # Deprecated function call. |
| 63 ] |
| 64 } |
| 65 } |
| 66 |
| 67 source_set("inspector_protocol") { |
| 68 deps = [ |
| 69 ":inspector_protocol_sources", |
| 70 ] |
| 71 configs += [ |
| 72 ":inspector_protocol_config" |
| 73 ] |
| 74 include_dirs = [ |
| 75 "$target_gen_dir/..", |
| 76 ] |
| 77 sources = protocol_sources + [ |
| 78 "$protocol_path/Allocator.h", |
| 79 "$protocol_path/Array.h", |
| 80 "$protocol_path/BackendCallback.h", |
| 81 "$protocol_path/CodeGenerator.py", |
| 82 "$protocol_path/Collections.h", |
| 83 "$protocol_path/DispatcherBase.cpp", |
| 84 "$protocol_path/DispatcherBase.h", |
| 85 "$protocol_path/ErrorSupport.cpp", |
| 86 "$protocol_path/ErrorSupport.h", |
| 87 "$protocol_path/FrontendChannel.h", |
| 88 "$protocol_path/Maybe.h", |
| 89 "$protocol_path/Object.cpp", |
| 90 "$protocol_path/Object.h", |
| 91 "$protocol_path/Parser.cpp", |
| 92 "$protocol_path/Parser.h", |
| 93 "$protocol_path/Platform.h", |
| 94 "$protocol_path/PlatformSTL.h", |
| 95 "$protocol_path/String16.h", |
| 96 "$protocol_path/String16STL.cpp", |
| 97 "$protocol_path/String16STL.h", |
| 98 "$protocol_path/ValueConversions.h", |
| 99 "$protocol_path/Values.cpp", |
| 100 "$protocol_path/Values.h", |
| 101 ] |
| 102 } |
| OLD | NEW |
|---|
Chromium Code Reviews
Issue 2190833004:
Reland [inspector] add inspector protocol parser test build target. (Closed)
Base URL: https://chromium.googlesource.com/v8/v8.git@master