Fuchsia: Builds run_vm_tests and a wrapper program for running it.

runtime/bin/BUILD.gn

Index: runtime/bin/BUILD.gn
diff --git a/runtime/bin/BUILD.gn b/runtime/bin/BUILD.gn
index 610115ac7ecde55f86ddfac61094be1a07861c23..fb91ab73728b08d938478c36629ed0a7aa157b9e 100644
--- a/runtime/bin/BUILD.gn
+++ b/runtime/bin/BUILD.gn
@@ -504,4 +504,88 @@ if (defined(is_fuchsia) && is_fuchsia) {
       "//third_party",
     ]
   }
+
+  action("generate_snapshot_test_dat_file") {
+    snapshot_test_dat_file = "$root_gen_dir/snapshot_test.dat"
+    snapshot_test_in_dat_file = "../vm/snapshot_test_in.dat"
+    snapshot_test_dart_file = "../vm/snapshot_test.dart"
+    inputs = [
+      "../tools/create_string_literal.py",
+      snapshot_test_in_dat_file,
+      snapshot_test_dart_file,
+    ]
+
+    outputs = [
+      snapshot_test_dat_file,
+    ]
+
+    script = "../tools/create_string_literal.py"
+    args = [
+      "--output",
+      rebase_path(snapshot_test_dat_file),
+      "--input_cc",
+      rebase_path(snapshot_test_in_dat_file),
+      "--include",
+      "INTENTIONALLY_LEFT_BLANK",
+      "--var_name",
+      "INTENTIONALLY_LEFT_BLANK_TOO",
+      rebase_path(snapshot_test_dart_file),
+    ]
+  }
+
+  executable("run_vm_tests") {
+    testonly = true
+    configs += ["..:dart_config",
+                "..:dart_product_config",
+                "..:dart_precompiled_runtime_config",]
+    deps = [
+      "..:libdart",
+      ":libdart_builtin",
+      ":embedded_dart_io",
+      ":dart_snapshot_cc",
+      ":generate_snapshot_test_dat_file",
+      "../vm:libdart_platform",
+      "//third_party/zlib",
+    ]
+    include_dirs = [
+      "..",
+      "$target_gen_dir",
+    ]
+    defines = [
+      "TESTING",
+    ]
+
+    vm_tests_list = exec_script("../../tools/gypi_to_gn.py",
+                                  [rebase_path("../vm/vm_sources.gypi"),
+                                   "--keep_only=_test.cc",
+                                   "--keep_only=_test.h",],
+                                  "scope",
+                                  ["../vm/vm_sources.gypi"])
+    vm_tests = rebase_path(vm_tests_list.sources, ".", "../vm")
+
+    builtin_impl_tests_list =
+        exec_script("../../tools/gypi_to_gn.py",
+                    [rebase_path("builtin_impl_sources.gypi"),
+                     "--keep_only=_test.cc",
+                     "--keep_only=_test.h",],
+                    "scope",
+                    ["builtin_impl_sources.gypi"])
+
+    sources = [
+      "run_vm_tests.cc",
+    ] + builtin_impl_tests_list.sources + vm_tests
+  }
+
+  copy("fuchsia_vm_tests") {
+    sources = [ "fuchsia_vm_tests.txt" ]
+    outputs = [ "$root_out_dir/fuchsia_vm_tests.txt" ]
+  }
+
+  executable("run_vm_tests_fuchsia") {
+    testonly = true
+    configs += ["..:dart_config"]
+    sources = [
+      "run_vm_tests_fuchsia.cc"
+    ]
+  }
 }  # defined(is_fuchsia) && is_fuchsia