[iOS] Fix build always considered dirty.

build/config/ios/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/base_rules.gni")
 import("//build/config/mac/symbols.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
@@ skipping 192 matching lines @@
       sources = get_target_outputs(":$_generate_info_plist")
       outputs = [
         "{{bundle_root_dir}}/Info.plist",
       ]
       public_deps = [
         ":$_generate_info_plist",
       ]
     }
 
     _link_executable = _target_name + "_executable"
-    _executable_path = "$target_out_dir/$_output_name"
 
     if (ios_enable_code_signing) {
       _link_executable_visibility = [ ":$_target_name" ]
     } else {
       _bundle_data_executable = target_name + "_bundle_data_executable"
       _link_executable_visibility = [ ":$_bundle_data_executable" ]
     }
 
     # For a fat-build, the different "executable" outputs will be used to
     # create the final binary using "lipo". As the corresponding target has
     # the same role as the "executable" target in a thin build, copy the
     # visibility and redefine some variables.
     if (_is_fat_build) {
       _lipo_executable = _link_executable
       _lipo_executable_visibility = _link_executable_visibility
 
       _link_executable_visibility = []
       _link_executable_visibility = [ ":$_lipo_executable" ]
       _link_executable = _target_name + "_arch_executable"
-
-      _arch_executable_path = "$target_out_dir/$current_cpu/$_output_name"
     }
 
     executable(_link_executable) {
       forward_variables_from(invoker,
                              "*",
                              [
                                "bundle_deps",
                                "bundle_extension",
                                "extra_system_frameworks",
                                "data_deps",
                                "entitlements_path",
                                "extra_substitutions",
                                "info_plist",
                                "info_plist_target",
                                "output_name",
                                "product_type",
                                "visibility",
                              ])
 
       visibility = _link_executable_visibility
 
+      output_name = _output_name
       output_prefix_override = true
       if (_is_fat_build) {
-        output_name = rebase_path(_arch_executable_path, root_build_dir)
+        output_dir = "$target_out_dir/$current_cpu"
       } else {
-        output_name = rebase_path(_executable_path, root_build_dir)
+        output_dir = target_out_dir
       }
 
       if (!defined(libs)) {
         libs = []
       }
       libs += [ "UIKit.framework" ]
     }
 
     if (_is_fat_build) {
       # Create the multi-architecture binary from all the single architecture
       # binaries using "lipo". This target exists for the default toolchain
       # of a fat-build only and depends on the expansion of "ios_app_bundle"
       # for the other toolchains (i.e. a single "executable" target).
       #
       # This action only happens once per "ios_app_bundle" template (for the
       # main toolchain).
       action(_lipo_executable) {
         forward_variables_from(invoker, [ "testonly" ])
         visibility = _lipo_executable_visibility
         script = "//build/toolchain/mac/linker_driver.py"
         outputs = [
-          _executable_path,
+          "$target_out_dir/$_output_name",
         ]
         inputs = [
-          _arch_executable_path,
+          "$target_out_dir/$current_cpu/$_output_name",
         ]
         deps = [
           ":$_link_executable",
         ]
         foreach(_additional_toolchain, additional_toolchains) {
           _additional_toolchain_target = "$_target_name($_additional_toolchain)"
           deps += [ ":$_additional_toolchain_target" ]
           inputs += [ get_label_info(_additional_toolchain_target,
                                      "root_out_dir") + "/$_output_name" ]
         }
@@ skipping 690 matching lines @@
       public_deps = [
         ":$_xctest_info_plist_target",
       ]
       sources = get_target_outputs(":$_xctest_info_plist_target")
       outputs = [
         "{{bundle_root_dir}}/Info.plist",
       ]
     }
 
     _xctest_loadable_module_target = _xctest_target + "_loadable_module"
-    _xctest_loadable_module_path = "$target_out_dir/$_xctest_output"
 
     if (!ios_enable_code_signing) {
       _xctest_loadable_module_bundle =
           _xctest_target + "_loadable_module_bundle"
       _xctest_loadable_module_visibility =
           [ ":$_xctest_loadable_module_bundle" ]
     } else {
       _xctest_loadable_module_visibility = [ ":$_xctest_target" ]
     }
 
     if (_is_fat_build) {
       _xctest_lipo_loadable_module_target = _xctest_loadable_module_target
       _xctest_lipo_loadable_module_visibility =
           _xctest_loadable_module_visibility
-      _arch_xctest_loadable_module_path =
-          "$target_out_dir/$current_cpu/$_xctest_output"
 
       _xctest_loadable_module_visibility = []
       _xctest_loadable_module_visibility =
           [ ":$_xctest_lipo_loadable_module_target" ]
       _xctest_loadable_module_target = _xctest_target + "_arch_loadable_module"
     }
 
     loadable_module(_xctest_loadable_module_target) {
       visibility = _xctest_loadable_module_visibility
       sources = [
         "//build/config/ios/xctest_shell.mm",
       ]
       configs += [ "//build/config/ios:xctest_config" ]
 
       if (_is_fat_build) {
-        output_name =
-            rebase_path(_arch_xctest_loadable_module_path, root_out_dir)
+        output_dir = "$target_out_dir/$current_cpu"
       } else {
-        output_name = rebase_path(_xctest_loadable_module_path, root_out_dir)
+        output_dir = target_out_dir
       }
 
+      output_name = _xctest_output
       output_prefix_override = true
       output_extension = ""
     }
 
     if (_is_fat_build) {
       action(_xctest_lipo_loadable_module_target) {
         visibility = _xctest_lipo_loadable_module_visibility
         script = "//build/toolchain/mac/linker_driver.py"
         outputs = [
-          _xctest_loadable_module_path,
+          "$target_out_dir/$_xctest_output",
         ]
         inputs = [
-          _arch_xctest_loadable_module_path,
+          "$target_out_dir/$current_cpu/$_xctest_output",
         ]
         deps = [
           ":$_xctest_loadable_module_target",
         ]
         foreach(_additional_toolchain, additional_toolchains) {
           _additional_toolchain_target = "$_target_name($_additional_toolchain)"
           deps += [ ":$_additional_toolchain_target" ]
           inputs += [ get_label_info(_additional_toolchain_target,
                                      "root_out_dir") + "/$_xctest_output" ]
         }
@@ skipping 152 matching lines @@
       "-rpath",
       "-Xlinker",
       "@loader_path/Frameworks",
     ]
   }
 }
 
 set_defaults("ios_xctest_test") {
   configs = default_executable_configs
 }