Build libmonochrome.so with secondary toolchain

build/config/android/config.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # This file contains common system config stuff for the Android build.
 
 if (is_android) {
   assert(rebase_path("//", root_build_dir) == "../../",
          "Android output directory must be nested 2 levels within src/ (" +
              "e.g.: out-gn/Debug). http://crbug.com/412935")
@@ skipping 248 matching lines @@
   android_objcopy = "${android_tool_prefix}objcopy"
   android_gdbserver =
       "$android_ndk_root/prebuilt/$android_prebuilt_arch/gdbserver/gdbserver"
 
   # Toolchain stuff ------------------------------------------------------------
 
   android_libcpp_root = "$android_ndk_root/sources/cxx-stl/llvm-libc++"
 
   # ABI ------------------------------------------------------------------------
 
-  # Intentionally do not define android_app_secondary_abi for 64-bit
-  # android_app_abi, since they are not used.
   if (current_cpu == "x86") {
     android_app_abi = "x86"
-    android_app_secondary_abi = "x86_64"
   } else if (current_cpu == "arm") {
     import("//build/config/arm.gni")
     if (arm_version < 7) {
       android_app_abi = "armeabi"
     } else {
       android_app_abi = "armeabi-v7a"
     }
-    android_app_secondary_abi = "arm64-v8a"
   } else if (current_cpu == "mipsel") {
     android_app_abi = "mips"
-    android_app_secondary_abi = "mips64"
   } else if (current_cpu == "x64") {
     android_app_abi = "x86_64"
   } else if (current_cpu == "arm64") {
     android_app_abi = "arm64-v8a"
   } else if (current_cpu == "mips64el") {
     android_app_abi = "mips64"
   } else {
     assert(false, "Unknown Android ABI: " + current_cpu)
   }
 
   if (android_libcpp_lib_dir == "") {
     android_libcpp_lib_dir = "${android_libcpp_root}/libs/${android_app_abi}"
   }
+
+  # Secondary ABI -------------------------------------------------------------
+  if (target_cpu == "arm64" || target_cpu == "x64" || target_cpu == "mips64el") {
+    android_64bit_target_cpu = true
+  } else if (target_cpu == "arm" || target_cpu == "x86" ||
+             target_cpu == "mipsel") {
+    android_64bit_target_cpu = false
+  } else {
+    assert(false, "Unknown target CPU: $target_cpu")
+  }
+
+  # Intentionally do not define android_app_secondary_abi_cpu and
+  # android_app_secondary_abi for 32-bit target_cpu, since they are not used.
+  if (target_cpu == "arm64") {
+    android_secondary_abi_cpu = "arm"
+    android_app_secondary_abi = "armeabi-v7a"
+  } else if (target_cpu == "x64") {
+    android_secondary_abi_cpu = "x86"
+    android_app_secondary_abi = "x86"
+  } else if (target_cpu == "mips64el") {
+    android_secondary_abi_cpu = "mipsel"
+    android_app_secondary_abi = "mips"
+  }
+
+  if (defined(android_secondary_abi_cpu)) {
+    if (is_clang) {
+      android_secondary_abi_toolchain =
+          "//build/toolchain/android:clang_${android_secondary_abi_cpu}"
+    } else {
+      android_secondary_abi_toolchain =
+          "//build/toolchain/android:${android_secondary_abi_cpu}"
+    }
+  }
 }