Enable precompiled headers for Blink on Windows

third_party/WebKit/Source/core/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/ui.gni")
 import("//third_party/WebKit/Source/bindings/bindings.gni")
 import("//third_party/WebKit/Source/bindings/core/v8/generated.gni")
 import("//third_party/WebKit/Source/bindings/modules/modules.gni")
 import("//third_party/WebKit/Source/bindings/modules/v8/generated.gni")
@@ skipping 46 matching lines @@
 config("core_include_dirs") {
   include_dirs = [
     "..",
     "$root_gen_dir/blink",
   ]
   if (is_android && use_openmax_dl_fft) {
     include_dirs += [ "//third_party/openmax_dl" ]
   }
 }
 
+import("//build/config/pch.gni")
+import("//build/toolchain/goma.gni")
+
+config("blink_core_pch") {
+  if (!is_official_build && !use_goma && !disable_precompiled_headers) {
+    if (is_win) {
+      # This is a string rather than a file GN knows about. It has to match
+      # exactly what's in the /FI flag below, and what might appear in the
+      # source code in quotes for an #include directive.
+      precompiled_header = rebase_path("win/Precompile-core.h", root_build_dir)
+
+      # This is a file that GN will compile with the above header. It will be
+      # implicitly added to the sources (potentially multiple times, with one
+      # variant for each language used in the target).
+      precompiled_source =
+          "//third_party/WebKit/Source/core/win/Precompile-core.cpp"
+
+      # Force include the header.
+      cflags = [ "/FI$precompiled_header" ]
+
+      # Disable warning for "this file was empty after preprocessing". This
+      # error is generated only in C mode for ANSI compatibility. It conflicts
+      # with precompiled headers since the source file that's "compiled" for
+      # making the precompiled header is empty.
+      #
+      # This error doesn't happen every time. In VS2013, it seems if the .pch
+      # file doesn't exist, no error will be generated (probably MS tested this
+      # case but forgot the other one?). To reproduce this error, do a build,
+      # then delete the precompile.c.obj file, then build again.
+      cflags_c = [ "/wd4206" ]
+    }
+  }
+}
+
+core_config_add += [ ":blink_core_pch" ]
+
 # GYP version: WebKit/Source/core/core.gyp:webcore_generated
 source_set("generated") {
   deps = [
     ":make_core_generated",
     ":prerequisites",
     "inspector:instrumentation_sources",
     "inspector:protocol_sources",
     "//gin",
     "//skia",
     "//third_party/WebKit/Source/bindings/core/v8:bindings_core_v8_generated",
@@ skipping 204 matching lines @@
 # GYP version: //third_party/WebKit/Source/core/core.gyp:webcore_rendering
 source_set("rendering") {
   # The files that go here are currently in "remaining".
 }
 
 # GYP version: WebKit/Source/core/core.gyp:webcore_testing
 source_set("testing") {
   configs += [
     "//third_party/WebKit/Source:inside_blink",
     "//third_party/WebKit/Source:config",
+    ":blink_core_pch",
   ]
 
   deps = [
     ":core",
     ":generated_testing_idls",
   ]
 
   sources = generated_core_testing_dictionary_files + webcore_testing_files
   sources += [
     "$bindings_core_v8_output_dir/V8DictionaryTest.cpp",
@@ skipping 777 matching lines @@
     "$blink_core_output_dir/{{source_name_part}}.h",
   ]
   args = [
     "{{source}}",
     rel_blink_core_gen_dir,
     bison_exe,
   ]
 
   deps = make_core_generated_deps
 }