Enable precompiled headers for Blink on Windows

third_party/WebKit/Source/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("config.gni")
 if (is_clang) {
   import("//build/config/clang/clang.gni")
 }
 
 visibility = [ "//third_party/WebKit/*" ]
@@ skipping 23 matching lines @@
 
 # inside_blink -----------------------------------------------------------------
 
 config("inside_blink") {
   defines = [
     "BLINK_IMPLEMENTATION=1",
     "INSIDE_BLINK",
   ]
 }
 
+# blink_pch --------------------------------------------------------------------
+
+# Precompiled headers can save a lot of time compiling since Blink has
+# a lot of source in header files.
+
+import("//build/config/pch.gni")
+import("//build/toolchain/goma.gni")
+
+config("blink_pch") {
+  if (!is_official_build && !use_goma && !disable_precompiled_headers) {

[Nico, 2016/07/14 19:58:52]

Rather than repeat all these here, maybe they should influence the default for
disable_precompiled_headers?

[Daniel Bratell, 2016/07/15 06:43:55]

I've done that change in the next version but there are pros and cons of both
approaches. For instance, moving it to declare_args makes it possible to
override the value also when it should be true. But then again, if someone wants
to combine pch and official builds, let them.

+    if (is_win) {
+      # This is a string rather than a file GN knows about. It has to match
+      # exactly what's in the /FI flag below, and what might appear in the
+      # source code in quotes for an #include directive.
+      precompiled_header = rebase_path("build/win/Precompile.h", root_build_dir)
+
+      # This is a file that GN will compile with the above header. It will be
+      # implicitly added to the sources (potentially multiple times, with one
+      # variant for each language used in the target).
+      precompiled_source =
+          "//third_party/WebKit/Source/build/win/Precompile.cpp"
+
+      # Force include the header.
+      cflags = [ "/FI$precompiled_header" ]
+
+      # Disable warning for "this file was empty after preprocessing". This
+      # error is generated only in C mode for ANSI compatibility. It conflicts
+      # with precompiled headers since the source file that's "compiled" for
+      # making the precompiled header is empty.
+      #
+      # This error doesn't happen every time. In VS2013, it seems if the .pch
+      # file doesn't exist, no error will be generated (probably MS tested this
+      # case but forgot the other one?). To reproduce this error, do a build,
+      # then delete the precompile.c.obj file, then build again.
+      cflags_c = [ "/wd4206" ]
+    }
+  }
+}
+
 # config -----------------------------------------------------------------------
 
 config("config") {
   include_dirs = [
     ".",
     "..",
     "$root_gen_dir/blink",
     "$root_gen_dir/third_party/WebKit",
   ]
 
@@ skipping 70 matching lines @@
   }
 }
 
 if (is_mac) {
   # This sets up precompiled headers for Mac.
   config("mac_precompiled_headers") {
     precompiled_header = rebase_path("build/mac/Prefix.h", root_build_dir)
     precompiled_source = "//third_party/WebKit/Source/build/mac/Prefix.h"
   }
 }