Add support for multi-architecture application bundle on iOS.

build/config/BUILDCONFIG.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+if (target_os == "ios") {
+  declare_args() {
+    # If defined, then the build is a multi-architecture build (aka fat build)
+    # and target_cpu must not be defined. Any value supported by target_cpu can
+    # be used in this list.
+    multi_arch_target_cpus = []
+  }
+}
+
 # =============================================================================
 # PLATFORM SELECTION
 # =============================================================================
 #
 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
 # of the GN thing that encodes combinations of these things.
 #
 # Users typically only set the variables "target_os" and "target_cpu" in "gn
 # args", the rest are set up by our build and internal to GN.
 #
@@ skipping 23 matching lines @@
   target_os = host_os
 }
 
 if (target_cpu == "") {
   if (target_os == "android") {
     # If we're building for Android, we should assume that we want to
     # build for ARM by default, not the host_cpu (which is likely x64).
     # This allows us to not have to specify both target_os and target_cpu
     # on the command line.
     target_cpu = "arm"
+  } else if (target_os == "ios") {
+    # If we're building for iOS, we respect the multi_arch_target_cpus if
+    # it is defined. In that case, we pick the first architecture listed in
+    # multi_arch_target_cpus and use it as target_cpu, the others will be
+    # build as secondary toolchain by the ios_app_bundle target.
+    if (multi_arch_target_cpus != []) {
+      assert(target_cpu == "",
+             "cannot define both multi_arch_target_cpus and target_cpu")
+      target_cpu = multi_arch_target_cpus[0]
+    } else {
+      target_cpu = host_cpu
+    }
   } else {
     target_cpu = host_cpu
   }
 }
 
 if (current_cpu == "") {
   current_cpu = target_cpu
 }
 if (current_os == "") {
   current_os = target_os
@@ skipping 149 matching lines @@
   # See comments in build/toolchain/cros/BUILD.gn about board compiles.
   assert(host_os == "linux",
          "ChromeOS builds are only supported on Linux hosts.")
   if (is_clang) {
     _default_toolchain = "//build/toolchain/cros:clang_target"
   } else {
     _default_toolchain = "//build/toolchain/cros:target"
   }
 } else if (target_os == "ios") {
   _default_toolchain = "//build/toolchain/mac:ios_clang_$target_cpu"
+  assert(custom_toolchain == "" || multi_arch_target_cpus == [],
+         "cannot define both multi_arch_target_cpus and custom_toolchain")
+
+  # Initialize multi_arch_toolchains from multi_arch_target_cpus. The
+  # list will not contain the default_toolchain and may be empty while
+  # multi_arch_target_cpus is not. This allows the build to default to
+  # regular build if multi_arch_target_cpus contains a single cpu.
+  multi_arch_toolchains = []
+  foreach(_multi_arch_target_cpu, multi_arch_target_cpus) {
+    if (_multi_arch_target_cpu != target_cpu) {
+      multi_arch_toolchains +=
+          [ "//build/toolchain/mac:ios_clang_$_multi_arch_target_cpu" ]
+    }
+  }
 } else if (target_os == "linux") {
   if (is_clang) {
     _default_toolchain = "//build/toolchain/linux:clang_$target_cpu"
   } else {
     _default_toolchain = "//build/toolchain/linux:$target_cpu"
   }
 } else if (target_os == "mac") {
   assert(host_os == "mac", "Mac cross-compiles are unsupported.")
   _default_toolchain = host_toolchain
 } else if (target_os == "win") {
@@ skipping 431 matching lines @@
     forward_variables_from(invoker, "*", [ "visibility" ])
 
     # All shared libraries must have the sanitizer deps to properly link in
     # asan mode (this target will be empty in other cases).
     if (!defined(deps)) {
       deps = []
     }
     deps += [ "//build/config/sanitizers:deps" ]
   }
 }