GN Rule to build Cronet Dynamic Framework for iOS.

components/cronet/ios/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/ios/rules.gni")
+import("//build/mac/tweak_info_plist.gni")
 import("//build/util/version.gni")
 import("//chrome/version.gni")
 import("//testing/test.gni")
 import("//url/features.gni")
 
 assert(!is_component_build, "Cronet requires static library build.")
 
 declare_args() {
   cronet_enable_data_reduction_proxy_support = false
 }
@@ skipping 29 matching lines @@
     "cronet_c_for_grpc.h",
     "cronet_environment.cc",
     "cronet_environment.h",
   ]
 
   if (!use_platform_icu_alternatives) {
     deps += [ "//base:i18n" ]
   }
 }
 
+# Tweak |info_plist| with current version and revision.
+tweak_info_plist("cronet_framework_plist") {
+  info_plist = "Info.plist"
+  args = [ "--bundle_id=CRNT" ]

[sdefresne, 2016/07/01 12:50:11]

The "Info.plist" file already contains the following, do you really need to
change it:

  <key>CFBundleIdentifier</key>
  <string>org.chromium.net.Cronet</string>

[mef, 2016/07/01 14:10:08]

Done. I've kept it because omitting args triggers an error, but it seems that
empty args work fine.

+}
+
+# Compile plist into |output_name|.
+ios_info_plist("cronet_info_plist") {
+  executable_name = "Cronet"
+
+  output_name = "$root_out_dir/Cronet.framework/Info.plist"

[sdefresne, 2016/07/01 12:50:11]

I think this goes against how create_bundle/bundle_data have been designed.
Moreover, I'm not sure you need to use this template as it looks like none of
the substitutions performed by this template are needed.

But if you do, I would instead use the following:

tweak_info_plist("cronet_framework_plist") {
  info_plist = "Info.plist"
}

ios_info_plist("compile_info_plist") {
  executable_name = "Cronet"
  output_name = "$target_gen_dir/Info.plist"
}

bundle_data("cronet_info_plist") {
  sources = [ "$target_gen_dir/Info.plist" ]
  outputs = [ "{{bundle_root_dir}}/Info.plist" ]
}

[mef, 2016/07/01 14:10:08]

tweak_info_plist also puts correct version and revision into tweaked plist,
which is nice.
Thanks, that worked!

+  info_plist_target = ":cronet_framework_plist"
+}
+
 ios_framework_bundle("cronet_framework") {
   output_name = "Cronet"
 
   deps = [
+    ":cronet_info_plist",
     ":cronet_sources",
     "//base",
     "//net:net",
   ]
 
-  info_plist = "Info.plist"
-
   libs = [ "UIKit.Framework" ]
 
   public_headers = [
     "Cronet.h",
     "cronet_c_for_grpc.h",
   ]
 
   sources = [
     "Cronet.h",
     "Cronet.mm",
   ]
+
+  configs -= [ "//build/config/compiler:default_symbols" ]
+  configs += [ "//build/config/compiler:symbols" ]
+
+  ldflags = []
+
+  # For release version generate a separate dSYM.
+  if (!is_debug) {
+    ldflags += [ "-Wcrl,strip,-x" ]
+    ldflags += [ "-Wcrl,dsym," + rebase_path(root_out_dir) ]
+  }
 }
 
 bundle_data("cronet_test_bundle_data") {
   testonly = true
   sources = [
     "//net/data/ssl/certificates/quic_test.example.com.crt",
     "//net/data/ssl/certificates/quic_test.example.com.key",
     "//net/data/ssl/certificates/quic_test.example.com.key.pkcs8",
     "//net/data/ssl/certificates/quic_test.example.com.key.sct",
   ]
@@ skipping 58 matching lines @@
 }
 
 copy("cronet_package_copy") {
   sources = [
     "$root_out_dir/Cronet.framework",
     "//AUTHORS",
     "//chrome/VERSION",
     "//components/cronet/ios/Cronet.h",
     "//components/cronet/ios/cronet_c_for_grpc.h",
   ]
+  if (!is_debug) {
+    # sources += [ "$root_out_dir/Cronet.dSYM" ]
+  }
   outputs = [
     "$_package_dir/{{source_file_part}}",
   ]
 
   deps = [
     ":cronet_framework",
   ]
 }
 
 group("cronet_package") {
   deps = [
     ":cronet_package_copy",
     ":generate_license",
   ]
 }