Adding localization files to the mac bundles for CRD.

remoting/host/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build/config/win/manifest.gni")
 import("//build/util/version.gni")
 import("//chrome/version.gni")
 import("//remoting/remoting_enable.gni")
@@ skipping 664 matching lines @@
     configs += [ "//build/config/compiler:wexit_time_destructors" ]
 
     defines = host_predefines + [ "BINARY=BINARY_NATIVE_MESSAGING_HOST" ]
 
     deps = [
       ":remoting_core",
       ":remoting_windows_resources",
       "//build/win:default_exe_manifest",
     ]
 
+    if (is_mac) {
+      foreach(locale, remoting_locales_with_underscores) {
+        deps += [
+          ":native_messaging_host_strings_${locale}_bundle_data",
+          ":remoting_host_locale_${locale}_bundle_data",
+        ]
+      }
+      deps += [
+        ":remoting_infoplist_strings",
+        "//remoting/resources:copy_locales",
+      ]
+    }
+
     sources = [
       "$root_gen_dir/remoting/version.rc",
       "setup/me2me_native_messaging_host_entry_point.cc",
     ]
   }
 
   # GYP version: //remoting/remoting_host_win.gypi:remoting_windows_resources
   remoting_localize("remoting_windows_resources") {
     deps = [
       "//remoting/resources",
@@ skipping 97 matching lines @@
       "--variables",
       rebase_path(branding_path),
       "--template",
       "{{source}}",
       "--output",
       "remoting/{{source_name_part}}",
       "en",
     ]
   }
 
+  if (is_mac) {
+    foreach(locale, remoting_locales_with_underscores) {
+      bundle_data("remoting_host_locale_${locale}_bundle_data") {
+        sources = [
+          "$root_build_dir/remoting/resources/$locale.lproj/locale.pak",
+        ]
+        outputs = [
+          "{{bundle_resources_dir}}/$locale.lproj/{{source_file_part}}",
+        ]
+        deps = [
+          "//remoting/resources:copy_locales",
+        ]
+      }
+    }
+  }
+
   action_foreach("remoting_infoplist_strings") {
     sources = [
       "installer/mac/uninstaller/remoting_uninstaller-InfoPlist.strings.jinja2",
       "it2me/remote_assistance_host-InfoPlist.strings.jinja2",
       "mac/me2me_preference_pane-InfoPlist.strings.jinja2",
       "remoting_me2me_host-InfoPlist.strings.jinja2",
       "setup/native_messaging_host-InfoPlist.strings.jinja2",
     ]
 
     script = "//remoting/tools/build/remoting_localize.py"
@@ skipping 101 matching lines @@
         # "/NODEFAULTLIB",
       ]
     }
   } else {
     if (is_mac) {
       app_target_type = "mac_app_bundle"
     } else {
       app_target_type = "executable"
     }
 
+    if (is_mac) {
+      # remoting_me2me_host-InfoPlist.strings
+      foreach(locale, remoting_locales_with_underscores) {
+        bundle_data("remoting_me2me_host_strings_${locale}_bundle_data") {
+          sources = [
+            "$root_gen_dir/remoting/host/remoting_me2me_host-InfoPlist.strings/$locale.lproj/InfoPlist.strings",
+          ]
+          outputs = [
+            "{{bundle_resources_dir}}/$locale.lproj/{{source_file_part}}",
+          ]
+          deps = [
+            ":remoting_infoplist_strings",
+          ]
+        }
+      }
+    }
+
     target(app_target_type, "remoting_me2me_host") {
       if (is_mac) {
         extra_configs = [ "//remoting:version" ]
         info_plist = "remoting_me2me_host-Info.plist"
       } else {
         configs += [ "//remoting:version" ]
       }
 
       sources = [
         "host_main.cc",
         "host_main.h",
       ]
 
       if (is_mac && is_chrome_branded && is_official_build) {
         defines = [ "REMOTING_ENABLE_BREAKPAD" ]
       }
 
       deps = [
         ":credits",
         ":remoting_me2me_host_static",
         "//build/config/sanitizers:deps",
         "//remoting/resources",
       ]
+      if (is_mac) {
+        foreach(locale, remoting_locales_with_underscores) {
+          deps += [
+            ":remoting_host_locale_${locale}_bundle_data",
+            ":remoting_me2me_host_strings_${locale}_bundle_data",
+          ]
+        }
+        deps += [
+          ":remoting_infoplist_strings",
+          "//remoting/resources:copy_locales",
+        ]
+      }
     }
 
     if (is_linux) {
       copy("remoting_me2me_host_copy_script") {
         sources = [
           "linux/linux_me2me_host.py",
         ]
         outputs = [
           "$root_build_dir/remoting/chrome-remote-desktop",
         ]
@@ skipping 11 matching lines @@
       }
       group("remoting_dev_me2me_host") {
         deps = [
           ":remoting_me2me_host",
           ":remoting_me2me_host_copy_host",
           ":remoting_me2me_host_copy_script",
         ]
       }
     }
 
+    if (is_mac) {
+      # native_messaging_host-InfoPlist.strings
+      foreach(locale, remoting_locales_with_underscores) {
+        bundle_data("native_messaging_host_strings_${locale}_bundle_data") {
+          sources = [
+            "$root_gen_dir/remoting/host/native_messaging_host-InfoPlist.strings/$locale.lproj/InfoPlist.strings",
+          ]
+          outputs = [
+            "{{bundle_resources_dir}}/$locale.lproj/{{source_file_part}}",
+          ]
+          deps = [
+            ":remoting_infoplist_strings",
+          ]
+        }
+      }
+    }
+
     target(app_target_type, "native_messaging_host") {
       if (is_mac) {
         info_plist = "setup/native_messaging_host-Info.plist"
         extra_configs = [ "//build/config/compiler:wexit_time_destructors" ]
       } else {
         configs += [ "//build/config/compiler:wexit_time_destructors" ]
       }
 
       sources = [
         "setup/me2me_native_messaging_host_entry_point.cc",
         "setup/me2me_native_messaging_host_main.cc",
         "setup/me2me_native_messaging_host_main.h",
       ]
 
       deps = [
         ":remoting_infoplist_strings",
         "//base",
         "//remoting/base:breakpad",
         "//remoting/host",
         "//remoting/host/native_messaging",
         "//remoting/host/setup",
       ]
 
+      if (is_mac) {
+        foreach(locale, remoting_locales_with_underscores) {
+          deps += [
+            ":native_messaging_host_strings_${locale}_bundle_data",
+            ":remoting_host_locale_${locale}_bundle_data",
+          ]
+        }
+        deps += [ "//remoting/resources:copy_locales" ]
+      }
+
       # The |major|, |build| and |patch| versions are inherited from Chrome.
       # Since Chrome's |minor| version is always '0', we replace it with a
       # Chromoting-specific patch version.
       defines = [ "VERSION=" + "$chrome_version_major" + "." +
                   "$remoting_version_patch" + "." + "$chrome_version_build" +
                   "." + "$chrome_version_patch" ]
     }
   }
 
   if (is_chrome_branded && enable_me2me_host && is_linux && !is_chromeos) {
@@ skipping 267 matching lines @@
         ":remoting_host_uninstaller",
         ":remoting_me2me_host",
         ":remoting_native_messaging_manifests",
         "//remoting/host/it2me:remote_assistance_host",
       ]
     }
 
     _uninstaller_plist =
         "installer/mac/uninstaller/remoting_uninstaller-Info.plist"
 
+    # remoting_uninstaller-InfoPlist.strings
+    foreach(locale, remoting_locales_with_underscores) {
+      bundle_data("remoting_uninstaller_strings_${locale}_bundle_data") {
+        sources = [
+          "$root_gen_dir/remoting/host/remoting_uninstaller-InfoPlist.strings/$locale.lproj/InfoPlist.strings",
+        ]
+        outputs = [
+          "{{bundle_resources_dir}}/$locale.lproj/{{source_file_part}}",
+        ]
+        deps = [
+          ":remoting_infoplist_strings",
+        ]
+      }
+    }
+
     mac_app_bundle("remoting_host_uninstaller") {
       info_plist = _uninstaller_plist
 
       defines = [
         "HOST_BUNDLE_NAME=\"" + host_bundle_name + "\"",
         "PREFPANE_BUNDLE_NAME=\"" + prefpane_bundle_name + "\"",
       ]
 
       sources = [
         "constants_mac.cc",
         "constants_mac.h",
         "installer/mac/uninstaller/remoting_uninstaller.h",
         "installer/mac/uninstaller/remoting_uninstaller.mm",
         "installer/mac/uninstaller/remoting_uninstaller_app.h",
         "installer/mac/uninstaller/remoting_uninstaller_app.mm",
       ]
 
       libs = [
         "Cocoa.framework",
         "CoreFoundation.framework",
         "Security.framework",
       ]
 
       deps = [
         ":remoting_host_uninstaller_xibs",
         ":remoting_infoplist_strings",
         "//base",
       ]
+      foreach(locale, remoting_locales_with_underscores) {
+        deps += [ ":remoting_uninstaller_strings_${locale}_bundle_data" ]
+      }
     }
 
     mac_xib_bundle_data("remoting_host_uninstaller_xibs") {
       sources = [
         #"installer/mac/uninstaller/remoting_uninstaller.icns",
         "installer/mac/uninstaller/remoting_uninstaller.xib",
         #_uninstaller_plist
       ]
     }
 
@@ skipping 45 matching lines @@
         "CoreFoundation.framework",
         "PreferencePanes.framework",
         "Security.framework",
       ]
 
       deps = [
         ":host",
         ":remoting_host_prefpane_xibs",
         ":remoting_infoplist_strings",
         "//remoting/base",
+        "//remoting/resources:copy_locales",
         "//third_party/jsoncpp",
       ]
+      foreach(locale, remoting_locales_with_underscores) {
+        deps += [ ":remoting_host_prefpane_strings_${locale}_bundle_data" ]
+      }
     }
 
     bundle_data("remoting_host_prefpane_plist") {
       sources = [
         "mac/me2me_preference_pane-Info.plist",
       ]
       outputs = [
         "{{bundle_root_dir}}/Info.plist",
       ]
     }
@@ skipping 53 matching lines @@
                       root_build_dir),
           rebase_path(outputs[0], root_build_dir),
         ]
       }
     } else {
       group("remoting_host_installation") {
       }
     }
   }
 }