Add InfoBarPickerController for displaying a picker view from an infobar

ios/chrome/browser/infobars/infobar_picker_controller.mm

Index: ios/chrome/browser/infobars/infobar_picker_controller.mm
diff --git a/ios/chrome/browser/infobars/infobar_picker_controller.mm b/ios/chrome/browser/infobars/infobar_picker_controller.mm
new file mode 100644
index 0000000000000000000000000000000000000000..c7b33374275e29bb6256f3b4b3bdbfbed6e5a76d
--- /dev/null
+++ b/ios/chrome/browser/infobars/infobar_picker_controller.mm
@@ -0,0 +1,133 @@
+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/infobars/infobar_picker_controller.h"
+
+#include "base/logging.h"
+#import "base/mac/objc_property_releaser.h"
+
+namespace {
+// Font size of text in the picker view.
+CGFloat kUIPickerFontSize = 26;
+}  // namespace
+
+@interface InfoBarPickerController ()<UIPickerViewDelegate,
+                                      UIPickerViewDataSource> {
+  base::mac::ObjCPropertyReleaser _propertyReleaser_InfoBarPickerController;
+  id<InfoBarPickerControllerDelegate> _delegate;  // weak
+}
+// "Done" button presented in the navigation bar.
+@property(nonatomic, retain) UIBarButtonItem* doneButton;
+// "Cancel" button presented in the navigation bar.
+@property(nonatomic, retain) UIBarButtonItem* cancelButton;
+@end
+
+@implementation InfoBarPickerController
+
+@synthesize pickerView = _pickerView;
+@synthesize navigationBar = _navigationBar;
+@synthesize doneButton = _doneButton;
+@synthesize cancelButton = _cancelButton;
+
+- (instancetype)initWithNibName:(NSString*)nibName bundle:(NSBundle*)nibBundle {
+  self = [super initWithNibName:nibName bundle:nil];
+  if (self) {
+    _propertyReleaser_InfoBarPickerController.Init(
+        self, [InfoBarPickerController class]);
+    _pickerView = [[UIPickerView alloc] initWithFrame:CGRectZero];

[marq (ping after 24h), 2016/06/30 16:10:11]

 View controllers usually create subviews in -viewDidLoad.

[Jackie Quinn, 2016/06/30 18:00:39]

I created them originally to make sure delegate/target/action setting would
happen properly. With what I suggested below, I'll move them to viewDidLoad. Or
maybe into loadView?

[marq (ping after 24h), 2016/07/01 11:48:44]

- loadView is called when a UIViewController's |view| property is accessed and
has a nil value. It should create the root view of the view controller's view
hierarchy and assign it to self.view. If this method isn't implemented and
there's a .xib file for the view controller, the view hierarchy is instantiated
from the .xib (we don't do this). If this method isn't implemented, a plain
UIView instance is created.

- viewDidLoad is called after the view hierarchy is loaded via -loadView, and
it's the expected place to perform "additional customization" of views. The
UIViewController docs recommend, if -loadView is being used to manually create a
root view (as it is here), that additional view initialization happens in
-viewDidLoad.

The additional view creation you're doing in loadView now is fine, since they
need to go inside the StackView, and it would be ugly to cast self.view into a
UIStackView later. But the view initialization in the -init can go into
viewDidLoad.

+    _doneButton = [[UIBarButtonItem alloc]
+        initWithBarButtonSystemItem:UIBarButtonSystemItemDone
+                             target:nil
+                             action:nil];
+    _cancelButton = [[UIBarButtonItem alloc]
+        initWithBarButtonSystemItem:UIBarButtonSystemItemCancel
+                             target:nil
+                             action:nil];
+  }
+  return self;
+}
+
+- (void)loadView {
+  self.pickerView.showsSelectionIndicator = YES;
+  self.pickerView.backgroundColor = [UIColor whiteColor];
+  self.pickerView.delegate = self;
+  self.pickerView.dataSource = self;
+  NSInteger initialRow = [self.delegate infoBarPickerControllerInitialRow:self];
+  [self.pickerView selectRow:initialRow inComponent:0 animated:NO];
+
+  self.navigationBar = [[UINavigationBar alloc] initWithFrame:CGRectZero];
+  UINavigationItem* navigationItem =
+      [[[UINavigationItem alloc] initWithTitle:@""] autorelease];
+  [navigationItem setRightBarButtonItem:self.doneButton];
+  [navigationItem setLeftBarButtonItem:self.cancelButton];
+  [navigationItem setHidesBackButton:YES];
+  [self.navigationBar pushNavigationItem:navigationItem animated:NO];
+
+  self.pickerView.translatesAutoresizingMaskIntoConstraints = NO;
+  self.navigationBar.translatesAutoresizingMaskIntoConstraints = NO;
+  UIStackView* stackView = [[[UIStackView alloc]
+      initWithArrangedSubviews:@[ self.navigationBar, self.pickerView ]]
+      autorelease];
+  stackView.backgroundColor = [UIColor whiteColor];
+  stackView.axis = UILayoutConstraintAxisVertical;
+  stackView.translatesAutoresizingMaskIntoConstraints = NO;
+  self.view = stackView;
+}
+
+- (void)setDoneTarget:(id)target action:(SEL)action {
+  self.doneButton.target = target;

[marq (ping after 24h), 2016/06/30 16:10:11]

This (and its companion method) should never be necessary. 

The view controller owns a view, and it should either handle the actions sent by
its views, or they should be forwarded up the responder chain.

The controls should set a target of nil and an action selector that's either
defined and implemented in this class, or is implemented in a view controller
further up in the responder chain. 

[Jackie Quinn, 2016/06/30 18:00:39]

I agree... these seemed a bit silly to me. I didn't really understand your
original comments. 

What happens when the ultimate responder isn't a view controller? In this case
it's the infobar controller, which, sadly, is not a view controller. I could
have this class respond and invoke delegate methods that looks more like
infoBarPickerViewController:dismissWithSelection: or something like that, would
that work?

[marq (ping after 24h), 2016/07/01 11:48:44]

This is one problem we have with having these not-really-a-view-controller
controllers around. The next item in the responder chain will actually be the
application's root view controller, since that's what's presenting this VC.

Instead of explaining what I had in mind here, I'll add this as a (very good)
example in the Coordinators document.

+  self.doneButton.action = action;
+}
+
+- (void)setCancelTarget:(id)target action:(SEL)action {
+  self.cancelButton.target = target;
+  self.cancelButton.action = action;
+}
+
+- (id<InfoBarPickerControllerDelegate>)delegate {
+  return _delegate;
+}
+
+- (void)setDelegate:(id<InfoBarPickerControllerDelegate>)delegate {
+  _delegate = delegate;
+}
+
+#pragma mark - UIPickerViewDataSource
+
+- (NSInteger)numberOfComponentsInPickerView:(UIPickerView*)pickerView {
+  return 1;
+}
+
+- (NSInteger)pickerView:(UIPickerView*)pickerView
+    numberOfRowsInComponent:(NSInteger)component {
+  return [self.delegate infoBarPickerControllerNumberOfRows:self];
+}
+
+#pragma mark - UIPickerViewDelegate
+
+- (UIView*)pickerView:(UIPickerView*)pickerView
+           viewForRow:(NSInteger)row
+         forComponent:(NSInteger)component
+          reusingView:(UIView*)view {
+  DCHECK_EQ(0, component);
+  UILabel* label = [view isKindOfClass:[UILabel class]]
+                       ? (UILabel*)view
+                       : [[[UILabel alloc] init] autorelease];
+  [label setText:[self.delegate infoBarPickerController:self textForRow:row]];
+  [label setTextAlignment:NSTextAlignmentCenter];
+  UIFont* font = [UIFont systemFontOfSize:kUIPickerFontSize];
+  if (row == [self.delegate infoBarPickerControllerInitialRow:self]) {
+    font = [UIFont boldSystemFontOfSize:kUIPickerFontSize];
+  }
+  if ([self.delegate
+          respondsToSelector:@selector(infoBarPickerControllerDisabledRow:)]) {
+    if (row == [self.delegate infoBarPickerControllerDisabledRow:self]) {
+      label.enabled = NO;
+    }
+  }
+  [label setFont:font];
+  return label;
+}
+
+@end