Fix the GN mini_installer_syzygy target.

chrome/installer/mini_installer/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/compiler/compiler.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build/config/win/visual_studio_version.gni")
 import("//build_overrides/v8.gni")
 import("//chrome/test/mini_installer/mini_installer_test.gni")
@@ skipping 81 matching lines @@
     "//chrome/installer/setup",
   ]
 }
 
 # Generates a mini installer.
 #
 #   out_dir (required)
 #     The output directory out_dir where the mini_installer image should be
 #     written.
 #
+#   chrome_dll_file (required)
+#     The path to the version of chrome.dll that should be included in the
+#     installer archive.
+#
+#   chrome_dll_target (required)
+#     The target that generated chrome_dll_file.
+#
 #   deps (required)
 #     Normal meaning.
 template("generate_mini_installer") {
-  custom_deps = invoker.deps
+  chrome_dll_file = invoker.chrome_dll_file
+  chrome_dll_target = invoker.chrome_dll_target
   output_dir = invoker.out_dir
 
   packed_files_rc_file = "$target_gen_dir/$target_name/packed_files.rc"
   archive_name = target_name + "_archive"
   staging_dir = "$target_gen_dir/$target_name"
 
   action(archive_name) {
     script = "//chrome/tools/build/win/create_installer_archive.py"
 
     release_file = "chrome.release"
 
     inputs = [
-      "$output_dir/chrome.dll",
+      "$chrome_dll_file",
       "$root_out_dir/chrome.exe",
       "$root_out_dir/locales/en-US.pak",
       "$root_out_dir/setup.exe",
       release_file,
     ]
 
     outputs = [
       # See also chrome.packed.7z conditionally added below.
       "$output_dir/chrome.7z",
       "$output_dir/setup.ex_",
@@ skipping 19 matching lines @@
 
       # Optional arguments to generate diff installer.
       #'--last_chrome_installer=C:/Temp/base',
       #'--setup_exe_format=DIFF',
       #'--diff_algorithm=COURGETTE',
 
       # Optional argument for verbose archiving output.
       #'--verbose',
     ]
 
-    deps = custom_deps + [
-             ":chrome_runtime_deps",
-             ":setup_runtime_deps",
-             "//chrome",
-             "//chrome/browser/extensions/default_extensions",
-             "//chrome/installer/setup",
-             "//third_party/icu:icudata",
-           ]
+    deps = [
+      ":chrome_runtime_deps",
+      ":setup_runtime_deps",
+      "//chrome",
+      "//chrome/browser/extensions/default_extensions",
+      "//chrome/installer/setup",
+      "//third_party/icu:icudata",
+      chrome_dll_target,
+    ]
 
     if (enable_hidpi) {
       args += [ "--enable_hidpi=1" ]
     }
     if (is_component_build) {
       args += [ "--component_build=1" ]
     } else {
       outputs += [ "$output_dir/chrome.packed.7z" ]
     }
 
@@ skipping 66 matching lines @@
       ":lib",
       ":version",
       "//build/config/sanitizers:deps",
       "//build/win:default_exe_manifest",
     ]
   }
 }
 
 generate_mini_installer("mini_installer") {
   out_dir = root_out_dir
-  deps = [
-    "//chrome:main_dll",
-  ]
+  chrome_dll_file = "$root_out_dir/chrome.dll"
+  chrome_dll_target = "//chrome:main_dll"
 }
 
 if (syzygy_optimize) {
   generate_mini_installer("mini_installer_syzygy") {
     out_dir = "$root_out_dir/syzygy/"
-    deps = [
-      "//chrome/tools/build/win/syzygy:chrome_dll_syzygy",
-    ]
+    chrome_dll_file = "$root_out_dir/syzygy/chrome.dll"
+    chrome_dll_target = "//chrome/tools/build/win/syzygy:chrome_dll_syzygy"
   }
 }
 
 # next_version_mini_installer.exe can't be generated in an x86 Debug component
 # build because it requires too much memory.
 if (!(is_component_build && is_debug && target_cpu == "x86")) {
   action("next_version_mini_installer") {
     script = "generate_next_version_mini_installer.py"
     testonly = true
     inputs = [
       "$root_out_dir/alternate_version_generator.exe",
       "$root_out_dir/mini_installer.exe",
     ]
     outputs = [
       "$root_out_dir/$target_name.exe",
     ]
     args = [
       "--out",
       "$target_name.exe",
     ]
     deps = [
       ":mini_installer",
       "//chrome/installer/test:alternate_version_generator",
     ]
   }
 }