Strip comments and whitespace from Javascript resources

tools/grit/grit_rule.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # Instantiate grit. This will produce a script target to run grit, and a
 # static library that compiles the .cc files.
 #
 # Parameters
 #
 #   source (required)
@@ skipping 64 matching lines @@
 #     ]
 #
 #     grit_flags = [ "-E", "foo=bar" ]  # Optional extra flags.
 #     # You can also put deps here if the grit source depends on generated
 #     # files.
 #   }
 import("//build/config/chrome_build.gni")
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
+import("//build/util/java_action.gni")
+import("//third_party/closure_compiler/compile_js2.gni")
 
 declare_args() {
   # Enables used resource whitelist generation.
   enable_resource_whitelist_generation = false
 }
 
 grit_defines = []
+grit_environment = []
 
 # Mac and iOS want Title Case strings.
 use_titlecase_in_grd_files = is_mac || is_ios
 if (use_titlecase_in_grd_files) {
   grit_defines += [
     "-D",
     "use_titlecase",
   ]
 }
 
 if (is_chrome_branded) {
   grit_defines += [
     "-D",
     "_google_chrome",
+  ]
+  grit_environment += [
     "-E",
     "CHROMIUM_BUILD=google_chrome",
   ]
 } else {
   grit_defines += [
     "-D",
     "_chromium",
+  ]
+  grit_environment += [
     "-E",
     "CHROMIUM_BUILD=chromium",
   ]
 }
 
 if (is_chromeos) {
   grit_defines += [
     "-D",
     "chromeos",
     "-D",
@@ skipping 44 matching lines @@
 }
 
 if (enable_image_loader_extension) {
   grit_defines += [
     "-D",
     "image_loader_extension",
   ]
 }
 
 if (is_android) {
-  grit_defines += [
+  grit_environment += [
     "-E",
     "ANDROID_JAVA_TAGGED_ONLY=true",
   ]
 }
 
 if (is_mac || is_ios) {
   grit_defines += [
     "-D",
     "scale_factors=2x",
   ]
@@ skipping 232 matching lines @@
     }
     args += [
               "-o",
               rebased_output_dir,
               "--depdir",
               ".",
               "--depfile",
               rebase_path(depfile, root_build_dir),
               "--write-only-new=1",
               "--depend-on-stamp",
-            ] + grit_defines
+            ] + grit_defines + grit_environment
 
     # Add extra defines with -D flags.
     if (defined(invoker.defines)) {
       foreach(i, invoker.defines) {
         args += [
           "-D",
           i,
         ]
       }
     }
 
+    if (defined(invoker.moved_file_list)) {
+      response_file_contents = invoker.moved_file_list
+      args += [ "--moved-input-file-list={{response_file_name}}" ]
+    }
+
     args += grit_flags + assert_files_flags
 
     if (defined(invoker.visibility)) {
       # This needs to include both what the invoker specified (since they
       # probably include generated headers from this target), as well as the
       # generated source set (since there's no guarantee that the visibility
       # specified by the invoker includes our target).
       #
       # Only define visibility at all if the invoker specified it. Otherwise,
       # we want to keep the public "no visibility specified" default.
@@ skipping 34 matching lines @@
     if (defined(invoker.configs)) {
       configs += invoker.configs
     }
 
     if (defined(invoker.visibility)) {
       visibility = invoker.visibility
     }
     output_name = grit_output_name
   }
 }
+
+flatten_resource_path = "//tools/grit/flatten_resource.py"
+closure_compiler_path = "//third_party/closure_compiler/compiler/compiler.jar"
+
+template("strip_js") {
+  assert(defined(invoker.sources),
+         "Need sources in $target_name listing the js files.")
+
+  _target_name = target_name
+
+  action_foreach("${_target_name}_flatten") {
+    script = flatten_resource_path
+    sources = invoker.sources
+    output = "{{source_gen_dir}}/flattened_${target_name}/{{source_file_part}}"
+    outputs = [
+      output,
+    ]
+    args = grit_defines
+    args += [
+      rebase_path("{{source}}"),
+      rebase_path("$root_out_dir/$output"),
+    ]
+  }
+
+  compile_js2_foreach(_target_name) {
+    sources = get_target_outputs(":${_target_name}_flatten")
+    deps = [
+      ":${_target_name}_flatten",
+    ]
+    strip_whitespace = true
+  }
+}
+
+template("strip_and_grit") {
+  _target_name = target_name
+
+  if (strip_resource_files) {
+    strip_js("${_target_name}_stripped") {
+      sources = invoker.js_resource_files
+    }
+    grit(_target_name) {
+      forward_variables_from(invoker,
+                             [
+                               "source",
+                               "outputs",
+                               "outputs_dir",
+                               "defines",
+                               "grit_flags",
+                               "output_dir",
+                             ])
+      moved_file_list = []
+
+      foreach(js_resource_file, invoker.js_resource_files) {
+        name = get_path_info(js_resource_file, "file")
+
+        # Generating the actual paths is messy, because, to avoid name clashes both the

[Dan Beam, 2016/07/14 17:47:59]

80 col wrap

+        # actions in strip_js use {{source_gen_dir}}, hence adding $root_gen_dir to
+        # the front of the path twice.
+        gen_dir = get_path_info(js_resource_file, "gen_dir")
+        gen_dir_rebased = rebase_path(gen_dir, "//")
+        stripped_target_name = "${_target_name}_stripped"
+        actual = "${root_gen_dir}/${gen_dir_rebased}/flattened_${stripped_target_name}_flatten/closure_${stripped_target_name}/${name}"
+        abs_orig = rebase_path(js_resource_file)
+        abs_actual = rebase_path(actual)
+        moved_file_list += [ "$abs_orig:$abs_actual" ]
+      }
+
+      deps = invoker.deps
+      deps += [ ":${_target_name}_stripped" ]
+    }
+  } else {
+    # If we can't run the closure compiler simply run grit.
+    grit(_target_name) {
+      forward_variables_from(invoker,
+                             [
+                               "source",
+                               "outputs",
+                               "outputs_dir",
+                               "defines",
+                               "grit_flags",
+                               "output_dir",
+                             ])
+
+      inputs = invoker.js_resource_files
+
+      deps = invoker.deps
+    }
+  }
+}