Adds gn config for policy_templates.zip

components/policy/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/features.gni")
 import("//components/policy/resources/policy_templates.gni")
 import("//third_party/protobuf/proto_library.gni")
 import("//tools/grit/grit_rule.gni")
 
@@ skipping 115 matching lines @@
       "--app-restrictions-definition=" +
           rebase_path(app_restrictions_path, root_build_dir),
       "--risk-tag-header=" + rebase_path(risk_tag_header_path, root_build_dir),
       chrome_version_path,
       target_os,
       chromeos_flag,
       rebase_path("resources/policy_templates.json", root_build_dir),
     ]
   }
 
+  grit_grd_file = "resources/policy_templates.grd"

[brettw, 2016/06/21 22:50:42]

This variable name seems too generic, maybe something like
  policy_templates_grd_file

[zmin, 2016/06/22 00:02:23]

Done.

   grit("policy_templates") {
-    source = "resources/policy_templates.grd"
+    source = grit_grd_file
     use_qualified_include = true
     output_dir = "$root_gen_dir/chrome"
     outputs = policy_templates_doc_outputs
     if (is_android) {
       outputs += policy_templates_android_outputs
     }
     if (is_linux) {
       outputs += policy_templates_linux_outputs
     }
     if (is_mac) {
@@ skipping 239 matching lines @@
     create_bundle("chrome_manifest_bundle") {
       bundle_root_dir = "$root_out_dir/$chrome_mac_bundle_id.manifest/Contents"
       bundle_resources_dir = "$bundle_root_dir/Resources"
 
       deps = [
         ":manifest_bundle_data",
         ":manifest_strings_bundle_data",
       ]
     }
   }
+
+  version_file = "VERSION"

[brettw, 2016/06/21 22:50:42]

You should put these add_version and pack_templates targets in an is_win block
since you only reference them on Windows. Otherwise they'll still show up in
"all" on other platforms.

[zmin, 2016/06/22 00:02:23]

Done.

+  version_path = "$policy_templates_base_dir/" + version_file

[brettw, 2016/06/21 22:50:42]

This can be written:
  version_path = "$policy_templates_base_dir/$version_file"

[zmin, 2016/06/22 00:02:23]

Done.

+
+  copy("add_version") {
+    sources = [
+      "../../chrome/VERSION",

[brettw, 2016/06/21 22:50:42]

This would be clearer as "//chrome/VERSION"

[zmin, 2016/06/22 00:02:23]

Done.

+    ]
+    outputs = [
+      version_path,
+    ]
+  }
+
+  action("pack_templates") {
+    output_zip_file = "$root_out_dir/policy_templates.zip"

[brettw, 2016/06/21 22:50:42]

_Don't_ change this line when doing the below root_out_dir change. This line is
correct.

+    script = "tools/make_policy_zip.py"
+    inputs = [
+               version_path,
+               grit_grd_file,
+               grit_info_script,
+             ] + policy_templates_windows_outputs + policy_templates_doc_outputs
+    outputs = [
+      output_zip_file,
+    ]
+    args = [
+             "--output",
+             rebase_path(output_zip_file, root_out_dir),

[brettw, 2016/06/21 22:50:42]

All of these root_out_dir calls in args should be root_build_dir instead (they
will be the same for the main toolchain but not for cross-compiles).

[zmin, 2016/06/22 00:02:23]

Done.

+             "--basedir",
+             rebase_path(policy_templates_base_dir, root_out_dir),
+             "--grd_input",
+             rebase_path(grit_grd_file, root_out_dir),
+             "--grd_strip_path_prefix",
+             "app/policy",
+             "--extra_input",
+             version_file,
+             "--grit_info",
+             rebase_path(grit_info_script, root_out_dir),
+           ] + grit_defines
+    deps = [
+      ":add_version",
+      ":policy_templates",
+    ]
+  }
+
+  group("pack_policy_templates") {
+    if (is_win) {
+      deps = [
+        ":pack_templates",
+      ]
+    }
+  }
 }