[Mac/GN] Load Content Shell Framework using rpath rather than executable_path.

content/shell/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/config/ui.gni")
 import("//build/config/win/console_app.gni")
 import("//build/config/win/manifest.gni")
 import("//media/media_options.gni")
@@ skipping 437 matching lines @@
     ]
     deps = [
       ":content_shell_framework_bundle_data",
       ":content_shell_resources_bundle_data",
 
       # TODO(rsesek): Remove this after GYP is gone, since it only needs to
       # be here per the comment in blink_test_platform_support_mac.mm about
       # the bundle structure.
       "//components/test_runner:resources",
     ]
+    ldflags = [
+      # The main app is at Content Shell.app/Contents/MacOS/Content Shell
+      # so set the rpath up to Contents/ so that the loader can find
+      # Framworks/.
+      "-rpath",
+      "@executable_path/../",
+    ]
     info_plist_target = ":content_shell_plist"
   }
 } else {
   # TODO(brettw) when GYP is no longer necessary, delete
   # content/shell/app/shell.exe.manifest. This file is not used in GN.
   executable("content_shell") {
     testonly = true
 
     # TODO(GYP) mac resource bundle stuff for this target.
     sources = [
@@ skipping 146 matching lines @@
       ":content_shell_framework_resources",
       ":content_shell_framework_xibs",
       ":content_shell_lib",
       "//third_party/icu:icudata",
     ]
 
     if (enable_plugins) {
       deps += [ ":content_shell_framework_plugins" ]
     }
 
-    ldflags = [ "-Wl,-install_name,@executable_path/../Frameworks/$output_name.framework/$output_name" ]
+    # Both the main :content_shell and :content_shell_helper_app executables
+    # need to link the framework. Because they are at different directory
+    # depths, using @executable_path as the install_name would require using
+    # install_name_tool on one of the executables. However install_name_tool
+    # only operates in-place, which is problematic to express in GN. Instead,
+    # use rpath-based loading.
+    # TODO(rsesek): After GYP is gone, re-write content_shell_main to be like
+    # chrome_main and use dlopen() instead of a linked framework.
+    ldflags = [ "-Wl,-install_name,@rpath/Frameworks/$output_name.framework/$output_name" ]
+
+    if (is_component_build) {
+      # Set up the rpath for the framework so that it can find dylibs in the
+      # root output directory. The framework is at
+      # Content Shell.app/Contents/Frameworks/Content Shell Framework.framework/Content Shell Framework
+      # so use loader_path to go back to the root output directory.
+      ldflags += [
+        "-rpath",
+        "@loader_path/../../../..",
+      ]
+    }
 
     info_plist_target = ":content_shell_framework_plist"
   }
 
   tweak_info_plist("content_shell_helper_plist") {
     testonly = true
     info_plist = "app/helper-Info.plist"
     args = [
       "--breakpad=0",
       "--keystone=0",
       "--scm=0",
       "--version",
       content_shell_version,
     ]
   }
 
   mac_app_bundle("content_shell_helper_app") {
     testonly = true
     output_name = content_shell_helper_name
     sources = [
       "app/shell_main.cc",
     ]
     deps = [
       ":content_shell_framework+link",
     ]
     ldflags = [
       # The helper is in Content Shell.app/Contents/Frameworks/Content Shell Helper.app/Contents/MacOS/
-      # so set rpath up to the base.
+      # so set rpath up to Contents/ so that the loader can find Frameworks/.
       "-rpath",
-      "@loader_path/../../../../../..",
+      "@executable_path/../../../..",
     ]
     info_plist_target = ":content_shell_helper_plist"
   }
 
-  # The install_name_tool can only operate in-place, rather than producing a
-  # unique output. Use the xcrun wrapper script to write a fake stamp output
-  # file. After :content_shell_helper_app has been built and bundled, this
-  # will run, modifying the executable in the bundle and writing out the
-  # --stamp specified. This will change the mtime on the executable, but
-  # because the stamp will also be updated, the
-  # :content_shell_framework_bundle_data will re-copy the output. This only
-  # works because nothing else depends on the output of
-  # :content_shell_helper_app.
-  # TODO(rsesek): After GYP is gone, re-write content_shell_main to be like
-  # chrome_main and use dlopen() instead of a linked framework.
-  action("fix_helper_link_framework") {
-    testonly = true
-    script = "//build/config/mac/xcrun.py"
-    inputs = [
-      "$root_out_dir/$content_shell_helper_name.app/Contents/MacOS/$content_shell_helper_name",
-    ]
-
-    stamp_file = "$target_out_dir/xcrun_$target_name.stamp"
-    outputs = [
-      stamp_file,
-    ]
-
-    # TODO(rsesek): Figure out something like GYP's postbuilds to allow
-    # install_name_tool to operate in-place <https://crbug.com/607292>.
-    args = [
-             "--stamp",
-             rebase_path(stamp_file, root_build_dir),
-
-             # xcrun arguments:
-             "install_name_tool",
-             "-change",
-             "@executable_path/../Frameworks/$content_shell_framework_name.framework/$content_shell_framework_name",
-             "@executable_path/../../../$content_shell_framework_name.framework/$content_shell_framework_name",
-           ] + rebase_path(inputs, root_build_dir)
-    public_deps = [
-      ":content_shell_helper_app",
-    ]
-  }
-
   bundle_data("content_shell_framework_bundle_data") {
     testonly = true
     sources = [
       "$root_out_dir/$content_shell_framework_name.framework",
       "$root_out_dir/$content_shell_helper_name.app",
     ]
     outputs = [
       "{{bundle_root_dir}}/Frameworks/{{source_file_part}}",
     ]
     public_deps = [
       ":content_shell_framework+link",
-      ":fix_helper_link_framework",
+      ":content_shell_helper_app",
     ]
   }
 
   bundle_data("content_shell_resources_bundle_data") {
     testonly = true
     sources = [
       "app/app.icns",
     ]
     outputs = [
       "{{bundle_resources_dir}}/{{source_file_part}}",
     ]
   }
 }
 
 mojom("mojo_bindings") {
   sources = [
     "common/layout_test/layout_test_bluetooth_fake_adapter_setter.mojom",
   ]
 }