Use runtime_deps to tell create_installer_archive what dlls to copy.

chrome/installer/mini_installer/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build_overrides/v8.gni")
 import("//chrome/version.gni")
 import("//third_party/icu/config.gni")
 import("//ui/base/ui_features.gni")
@@ skipping 50 matching lines @@
     ":lib",
   ]
   deps = [
     "//base",
     "//testing/gtest",
   ]
 }
 
 packed_files_rc_file = "$target_gen_dir/packed_files.rc"
 
+# The runtime deps are used to tell create_installer_archive what component
+# build DLLs need to be packaged.

[gab, 2016/06/20 15:15:26]

s/component build DLLs need to be packaged/component DLLs need to be packaged in
a component build/

+setup_runtime_deps = "$root_gen_dir/setup.runtime_deps"
+installer_runtime_deps = "$root_gen_dir/mini_installer.runtime_deps"

[gab, 2016/06/20 15:15:26]

s/installer_runtime_deps/component_runtime_deps/

or chrome_runtime_deps (see below)

+
+group("setup_runtime_deps") {
+  write_runtime_deps = setup_runtime_deps
+  data_deps = [
+    "//chrome/installer/setup",
+  ]
+}
+
 action("archive") {
   script = "//chrome/tools/build/win/create_installer_archive.py"
 
   release_file = "chrome.release"
 
   inputs = [
     "$root_out_dir/chrome.exe",
     "$root_out_dir/chrome.dll",
     "$root_out_dir/locales/en-US.pak",
     "$root_out_dir/setup.exe",
@@ skipping 10 matching lines @@
     "--build_dir",
     rebase_path(root_out_dir, root_build_dir),
     "--staging_dir",
     rebase_path(root_gen_dir, root_build_dir),
     "--input_file",
     rebase_path(release_file, root_build_dir),
     "--resource_file_path",
     rebase_path(packed_files_rc_file, root_build_dir),
     "--target_arch=$current_cpu",
     "--distribution=_google_chrome",
+    "--runtime_deps",
+    rebase_path(installer_runtime_deps, root_build_dir),
+    "--setup_runtime_deps",
+    rebase_path(setup_runtime_deps, root_build_dir),
 
     # Optional arguments to generate diff installer.
     #'--last_chrome_installer=C:/Temp/base',
     #'--setup_exe_format=DIFF',
     #'--diff_algorithm=COURGETTE',
 
     # Optional argument for verbose archiving output.
     #'--verbose',
   ]
 
   deps = [
+    ":setup_runtime_deps",
     "//chrome",
     "//chrome:main_dll",
     "//chrome/browser/extensions/default_extensions",
     "//chrome/installer/setup",
     "//third_party/icu:icudata",
   ]
 
   if (enable_hidpi) {
     args += [ "--enable_hidpi=1" ]
   }
@@ skipping 22 matching lines @@
   }
 
   if (v8_use_external_startup_data) {
     inputs += [
       "$root_out_dir/natives_blob.bin",
       "$root_out_dir/snapshot_blob.bin",
     ]
     deps += [ "//v8" ]
   }
 
+  write_runtime_deps = installer_runtime_deps

[gab, 2016/06/20 15:15:26]

These actually only need to be the deps for chrome's target, not mini_installer.

+
   depfile = "$target_gen_dir/archive.d"
   args += [
     "--depfile",
     rebase_path(depfile, root_build_dir),
   ]
 }
 
 executable("mini_installer") {
   sources = [
     "mini_installer.cc",
@@ skipping 49 matching lines @@
     args = [
       "--out",
       "$target_name.exe",
     ]
     deps = [
       ":mini_installer",
       "//chrome/installer/test:alternate_version_generator",
     ]
   }
 }