Add an XPC service to handle alert notifications on mac

chrome/browser/ui/cocoa/notifications/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/util/branding.gni")
+import("//build/config/mac/rules.gni")
+
+mac_app_bundle("alert_notification_xpc_service") {
+  output_name = "AlertNotificationService"
+  package_type = "xpc"
+
+  info_plist = "xpc-Info.plist"
+  extra_substitutions =
+      [ "PRODUCT_BUNDLE_IDENTIFIER=$chrome_mac_bundle_id.$output_name" ]

[Robert Sesek, 2016/09/29 14:23:04]

The convention for setting the bundle ID is to declare
CHROME_BUNDLE_ID=$chrome_mac_bundle_id as the extra_substitutions and then in
the .plist file either append a literal or ${EXECUTABLE_NAME}.

[Miguel Garcia, 2016/10/03 16:07:50]

Ok, let's see if I got this right, in the .plist I went with

        <key>CFBundleIdentifier</key>
        <string>${CHROME_BUNDLE_ID}.AlertNotificationService</string>

Since  <string>${CHROME_BUNDLE_ID}.${output_name}</string> didn't seem to work

[Robert Sesek, 2016/10/04 16:04:25]

Yes, that works. ${output_name} won't work but ${EXECUTABLE_NAME} will.

+
+  sources = [
+    "alert_notification_service.h",
+    "alert_notification_service.mm",
+    "notification_service_delegate.h",
+    "notification_service_delegate.mm",
+    "xpc_service_main.mm",
+  ]
+
+  deps = [
+    ":common",
+  ]
+
+  libs = [
+    "AppKit.framework",

[Robert Sesek, 2016/09/29 14:23:04]

Do you need AppKit?

[Miguel Garcia, 2016/10/03 16:07:50]

Yes (for NSImage).

+    "Foundation.framework",
+  ]
+
+  ldflags = []
+  if (is_component_build) {
+    ldflags += [
+      # The XPC service is in Chromium.app/Contents/Versions/X/Chromium \
+      # Framework.framework/XPCServices/AlertNotificationService.xpc/\
+      # Contents/MacOS/ so set rpath up to the base.
+      "-rpath",
+      "@loader_path/../../../../../../../../../",
+    ]
+  }
+}
+
 static_library("common") {
   sources = [
     "notification_builder_mac.h",
     "notification_builder_mac.mm",
     "notification_constants_mac.h",
     "notification_constants_mac.mm",
     "notification_delivery.h",
     "notification_response_builder_mac.h",
     "notification_response_builder_mac.mm",
   ]
 
-  deps = [
-    "//base",
+  public_deps = [

[Robert Sesek, 2016/09/29 14:23:04]

Leave this as deps and add an explicit deps on base where you need it
(presumably in alert_notification_xpc_service).

[Miguel Garcia, 2016/10/03 16:07:50]

Done.

+    "//base:base",
   ]
 }