[iOS/GN] Add code signing rules to ios_app_bundle target.

build/config/ios/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
 #     info_plist:
 #         (optional) string, path to the Info.plist file that will be used for
 #         the bundle.
 #
@@ skipping 78 matching lines @@
 #
 #   info_plist:
 #       (optional) string, path to the Info.plist file that will be used for
 #       the bundle.
 #
 #   info_plist_target:
 #       (optional) string, if the info_plist is generated from an action,
 #       rather than a regular source file, specify the target name in lieu
 #       of info_plist. The two arguments are mutually exclusive.
 #
+#   entitlements_path:
+#       (optional) path to the template to use to generate the application
+#       entitlements by performing variable substitutions, defaults to
+#       $ios_sdk_path/Entitlements.plist.
+#
 #   bundle_extension:
 #       (optional) bundle extension including the dot, default to ".app".
 #
 #   product_type
 #       (optional) string, product type for the generated Xcode project,
 #       default to "com.apple.product-type.application". Should generally
 #       not be overridden.
 #
 # For more information, see "gn help executable".
 template("ios_app_bundle") {
@@ skipping 22 matching lines @@
     sources = get_target_outputs(":$_generate_info_plist")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
     public_deps = [
       ":$_generate_info_plist",
     ]
   }
 
   _generate_executable = target_name + "_generate_executable"
-  _bundle_data_executable = target_name + "_bundle_data_executable"
+  if (!ios_enable_code_signing) {
+    _bundle_data_executable = target_name + "_bundle_data_executable"
+  }
 
   executable(_generate_executable) {
-    visibility = [ ":$_bundle_data_executable" ]
+    if (ios_enable_code_signing) {
+      visibility = [ ":$_target_name" ]
+    } else {
+      visibility = [ ":$_bundle_data_executable" ]
+    }
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "bundle_extension",
-                             "code_signing_identity",
                              "data_deps",
                              "entitlements_path",
                              "info_plist",
                              "info_plist_target",
                              "output_name",
                              "product_type",
                              "visibility",
                            ])
 
     output_name = rebase_path("$target_gen_dir/$_output_name", root_out_dir)
     if (!defined(libs)) {
       libs = []
     }
     libs += [ "UIKit.framework" ]
     if (!defined(ldflags)) {
       ldflags = []
     }
     ldflags += [ "-ObjC" ]
   }
 
-  bundle_data(_bundle_data_executable) {
-    forward_variables_from(invoker, [ "testonly" ])
-    visibility = [ ":$_target_name" ]
-    sources = [
-      "$target_gen_dir/$_output_name",
-    ]
-    outputs = [
-      "{{bundle_executable_dir}}/$_output_name",
-    ]
-    public_deps = [
-      ":$_generate_executable",
-    ]
+  if (!ios_enable_code_signing) {
+    bundle_data(_bundle_data_executable) {
+      forward_variables_from(invoker, [ "testonly" ])
+      visibility = [ ":$_target_name" ]
+      sources = [
+        "$target_gen_dir/$_output_name",
+      ]
+      outputs = [
+        "{{bundle_executable_dir}}/$_output_name",
+      ]
+      public_deps = [
+        ":$_generate_executable",
+      ]
+    }
   }
 
   create_bundle(target_name) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                              "visibility",
                            ])
 
     if (!defined(deps)) {
       deps = []
     }
-    deps += [
-      ":$_bundle_data_executable",
-      ":$_bundle_data_info_plist",
-    ]
+    deps += [ ":$_bundle_data_info_plist" ]
+    if (ios_enable_code_signing) {
+      deps += [ ":$_generate_executable" ]
+    } else {
+      deps += [ ":$_bundle_data_executable" ]
+    }
 
     if (use_ios_simulator) {
       if (!defined(data_deps)) {
         data_deps = []
       }
       data_deps += [ "//testing/iossim" ]
     }
 
     if (defined(invoker.product_type)) {
       product_type = invoker.product_type
     } else {
       product_type = "com.apple.product-type.application"
     }
 
     if (defined(invoker.bundle_extension)) {
       _bundle_extension = invoker.bundle_extension
     } else {
       _bundle_extension = ".app"
     }
 
     bundle_root_dir = "$root_out_dir/$_output_name$_bundle_extension"
     bundle_resources_dir = bundle_root_dir
     bundle_executable_dir = bundle_root_dir
     bundle_plugins_dir = "$bundle_root_dir/PlugIns"
+
+    if (defined(invoker.entitlements_path)) {
+      _entitlements_path = invoker.entitlements_path
+    } else {
+      _entitlements_path = "$ios_sdk_path/Entitlements.plist"
+    }
+
+    if (ios_enable_code_signing) {
+      code_signing_script = "//build/config/ios/codesign.py"
+      code_signing_sources = [
+        _entitlements_path,
+        "$target_gen_dir/$_output_name",
+      ]
+      code_signing_outputs = [
+        "$bundle_root_dir/$_output_name",
+        "$bundle_root_dir/_CodeSignature/CodeResources",
+        "$bundle_root_dir/embedded.mobileprovision",
+      ]
+      code_signing_args = [
+        "-i=" + ios_code_signing_identity,
+        "-b=" + rebase_path("$target_gen_dir/$_output_name", root_build_dir),
+        "-e=" + rebase_path(_entitlements_path, root_build_dir),
+        rebase_path(bundle_root_dir, root_build_dir),
+      ]
+    } else {
+      assert(_entitlements_path != "",
+             "force usage of _entitlements_path to avoid unused variable error")
+    }
   }
-
-  # TODO(crbug.com/297668):
-  # - add support for codesigning,
-  # - find a way to make "ninja -C out/Default base_unittests.app" work as
-  #   an alias to "ninja -C out/Default base_unittests" (for convenience
-  #   and compatibility with gyp),
 }
 
 # Template to build an application extension bundle for iOS.
 #
 # This should be used instead of "executable" built-in target type on iOS.
 # As the template forward the generation of the application executable to
 # an "executable" target, all arguments supported by "executable" targets
 # are also supported by this template.
 #
 # Arguments
@@ skipping 280 matching lines @@
                              [
                                "testonly",
                                "visibility",
                              ])
       public_deps = [
         ":$_framework_target+link",
       ]
     }
   }
 }