[Cronet] Enforce ARMv7 Cronet doesn't inadvertently use ARM Neon instructions

components/cronet/android/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/rules.gni")
 import("//build/util/version.gni")
 import("//chrome/version.gni")
 import("//testing/test.gni")
@@ skipping 916 matching lines @@
     "$root_out_dir/lib.unstripped/libcronet.so",
   ]
   outputs = [
     "$_package_dir/symbols/${android_app_abi}/libcronet.so",
   ]
   deps = [
     ":cronet",
   ]
 }
 
+# Enforce that ARM Neon is not used when building for ARMv7
+if (target_cpu == "arm" && arm_version == 7 && !arm_use_neon) {
+  action("enforce_no_neon") {
+    script = "//components/cronet/tools/check_no_neon.py"
+    args = [
+      rebase_path("${android_tool_prefix}objdump", root_build_dir),
+
+      # libcronet.so may contain ARM Neon instructions from BoringSSL, but these
+      # are only used after checking whether the CPU supports NEON at runtime,
+      # so instead check base/ as it represents a large swath of code that only
+      # contains Neon instructions when Neon is enabled by default.
+      rebase_path("$root_out_dir/obj/base/base/*.o", root_build_dir),
+    ]
+    outputs = [
+      "$root_out_dir/cronet_$target_name.d",
+    ]
+    deps = [
+      "//base:base",
+    ]
+  }
+}
+
 group("cronet_package") {
-  deps = [
-    ":cronet_package_copy",
-    ":cronet_package_copy_native_lib",
-    ":cronet_package_copy_native_lib_unstripped",
-    ":generate_javadoc",
-    ":generate_licenses",
-    ":jar_cronet_api_source",
-    ":jar_cronet_other_source",
-    ":jar_cronet_sample_source",
-    ":repackage_extracted_jars",
-  ]
+  # Enforce that arm_use_neon==false when building for ARMv7 by
+  # not including any deps in cronet_package target otherwise.
+  if (!(target_cpu == "arm" && arm_version == 7) || !arm_use_neon) {
+    deps = [
+      ":cronet_package_copy",
+      ":cronet_package_copy_native_lib",
+      ":cronet_package_copy_native_lib_unstripped",
+      ":generate_javadoc",
+      ":generate_licenses",
+      ":jar_cronet_api_source",
+      ":jar_cronet_other_source",
+      ":jar_cronet_sample_source",
+      ":repackage_extracted_jars",
+    ]
+    if (current_cpu == "arm" && arm_version == 7) {
+      deps += [ ":enforce_no_neon" ]
+    }
+  }
 }