[Mac/GN] Write PkgInfo files for .app bundles.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
@@ skipping 225 matching lines @@
     executable_name = _output_name
     forward_variables_from(invoker,
                            [
                              "extra_substitutions",
                              "info_plist",
                              "info_plist_target",
                              "testonly",
                            ])
   }
 
+  _pkg_info_target = target_name + "_pkg_info"
+
+  action(_pkg_info_target) {
+    forward_variables_from(invoker, [ "testonly" ])
+    script = "//build/config/mac/write_pkg_info.py"
+    sources = get_target_outputs(":$_info_plist_target")
+    outputs = [
+      "$target_gen_dir/$_pkg_info_target",
+    ]
+    args = [ "--plist" ] + rebase_path(sources, root_build_dir) +
+           [ "--output" ] + rebase_path(outputs, root_build_dir)
+    deps = [
+      ":$_info_plist_target",
+    ]
+  }
+
   executable(_executable_target) {
     visibility = [ ":$_executable_bundle_data" ]
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "data_deps",
                              "info_plist",
                              "output_name",
                              "visibility",
@@ skipping 29 matching lines @@
     visibility = [ ":$_target_name" ]
     sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
     public_deps = [
       ":$_info_plist_target",
     ]
   }
 
+  _pkg_info_bundle_data = _pkg_info_target + "_bundle_data"
+
+  bundle_data(_pkg_info_bundle_data) {
+    forward_variables_from(invoker, [ "testonly" ])
+    visibility = [ ":$_target_name" ]
+    sources = get_target_outputs(":$_pkg_info_target")
+    outputs = [
+      "{{bundle_root_dir}}/PkgInfo",
+    ]
+    public_deps = [
+      ":$_pkg_info_target",
+    ]
+  }
+
   create_bundle(_target_name) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [
       ":$_executable_bundle_data",
       ":$_info_plist_bundle_data",
+      ":$_pkg_info_bundle_data",
     ]
 
     bundle_root_dir = "$root_out_dir/${_output_name}.app/Contents"
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }
 
 # Template to package a loadable_module into a .plugin bundle.
 #
@@ skipping 50 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_output_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }