[Mac/GN] Add targets to run dump_syms and create the dSYM archive.

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
 import("//build/config/sanitizers/sanitizers.gni")
@@ skipping 417 matching lines @@
       ":chrome_app",
     ]
 
     data_deps = [
       ":chrome_app",
     ]
 
     if (debug_devtools) {
       deps += [ ":devtools_debug_resources" ]
     }
+
+    if (is_chrome_branded && is_official_build) {

[Mark Mentovai, 2016/06/09 18:48:04]

We don’t have a better variable for “want dumped symbols” than this as we do for
“want dSYMs”?

[Robert Sesek, 2016/06/09 20:53:46]

This is making the top-level "chrome" target depend on the dSYM archive and
dump_syms targets if you're building an official, branded build. But these
targets only do something if enable_dsyms=true.

+      deps += [
+        ":chrome_dsym_archive",
+        ":chrome_dump_syms",
+      ]
+    }
   }
 
   tweak_info_plist("chrome_app_plist") {
     info_plist = "app/app-Info.plist"
     _keystone_arg = "0"
     if (enable_mac_keystone) {
       _keystone_arg = "1"
     }
     args = [
       "--breakpad=0",
@@ skipping 549 matching lines @@
         ":chrome_framework",
       ]
     }
   } else {
     group("verify_chrome_framework_order") {
       public_deps = [
         ":chrome_framework",
       ]
     }
   }
+
+  if (enable_dsyms) {
+    # This list must be updated with the two targets' deps list below, and
+    # the list of _dsyms in :chrome_dsym_archive.
+    _chrome_symbols_sources = [
+      "$root_out_dir/$chrome_framework_name.framework/$chrome_framework_name",
+      "$root_out_dir/$chrome_helper_name.app/Contents/MacOS/$chrome_helper_name",
+      "$root_out_dir/$chrome_product_full_name.app/Contents/MacOS/$chrome_product_full_name",
+      "$root_out_dir/crashpad_handler",
+    ]
+
+    # It is possible to run dump_syms on unstripped products without dSYMs,
+    # but doing so isn't logical and won't happen in practice.
+    action_foreach("chrome_dump_syms") {
+      script = "//build/redirect_stdout.py"
+
+      sources = _chrome_symbols_sources
+
+      outputs = [
+        "$root_out_dir/{{source_file_part}}-$chrome_version_full.breakpad",
+      ]
+
+      # Prefix dump_syms with a ./ in case a user has it in their path.

[Mark Mentovai, 2016/06/09 18:48:04]

Does this mean that gn or something puts an implicit dot in its path? Hmm…

Do this or use an absolute path, good call. Absolute paths are nice when you
want to copy and paste commands from verbose output and not have to worry about
your working directory.

[Robert Sesek, 2016/06/09 20:53:46]

No, the way I had rebase_path'd it, there was no path prefix at all. Switched to
an absolute path.

+      args = rebase_path(outputs, root_out_dir) + [
+               "./" + rebase_path("$root_out_dir/dump_syms", root_build_dir),
+               "-g",
+               rebase_path(
+                   "$root_out_dir/{{source_name_part}}.dSYM/Contents/Resources/DWARF/{{source_name_part}}",
+                   root_out_dir),
+               "{{source}}",
+             ]
+
+      deps = [
+        ":chrome_app",
+        ":chrome_framework",
+        ":chrome_helper_app",
+        "//breakpad:dump_syms",
+        "//third_party/crashpad/crashpad/handler:crashpad_handler",
+      ]
+    }
+
+    action("chrome_dsym_archive") {
+      script = "//chrome/tools/build/mac/archive_symbols.py"
+
+      # These are the dSYMs that will be archived. The sources list must be
+      # are the target outputs that correspond to the dSYMs (since a dSYM is
+      # a directory it cannot be listed as a source file). The targets that
+      # generate both the dSYM and binary image are listed in deps.
+      _dsyms = [
+        "$root_out_dir/$chrome_framework_name.dSYM",
+        "$root_out_dir/$chrome_helper_name.dSYM",
+        "$root_out_dir/$chrome_product_full_name.dSYM",
+        "$root_out_dir/crashpad_handler.dSYM",
+      ]
+
+      sources = _chrome_symbols_sources
+
+      _output = "$root_out_dir/$chrome_product_full_name.dSYM.tar.bz2"
+
+      outputs = [
+        _output,
+      ]
+
+      args = [ rebase_path(_output, root_out_dir) ] +
+             rebase_path(_dsyms, root_out_dir)
+
+      deps = [
+        ":chrome_app",
+        ":chrome_framework",
+        ":chrome_helper_app",
+        "//third_party/crashpad/crashpad/handler:crashpad_handler",
+      ]
+    }
+  } else {
+    group("chrome_dump_syms") {
+    }
+    group("chrome_symbol_archive") {
+    }
+  }
 }
 
 # GYP version: chromium_browser_dependencies variable in chrome.gyp
 group("browser_dependencies") {
   public_deps = [
     "//chrome/browser",
     "//chrome/common",
     "//sync",
   ]
   if (enable_plugins) {
@@ skipping 650 matching lines @@
       "//chrome/app/theme/$branding_path_component/product_logo_48.png",
       "//chrome/tools/build/linux/chrome-wrapper",
       "//third_party/xdg-utils/scripts/xdg-mime",
       "//third_party/xdg-utils/scripts/xdg-settings",
     ]
     outputs = [
       "$root_out_dir/{{source_file_part}}",
     ]
   }
 }