Read characteristic implementation on macOS

device/bluetooth/bluetooth_remote_gatt_characteristic_mac.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "device/bluetooth/bluetooth_remote_gatt_characteristic_mac.h"
 
 #import <CoreBluetooth/CoreBluetooth.h>
 
 #include "device/bluetooth/bluetooth_adapter_mac.h"
+#include "device/bluetooth/bluetooth_device_mac.h"
 #include "device/bluetooth/bluetooth_remote_gatt_service_mac.h"
 
 namespace device {
 
 namespace {
 
 static BluetoothGattCharacteristic::Properties ConvertProperties(
     CBCharacteristicProperties cb_property) {
   BluetoothGattCharacteristic::Properties result =
       BluetoothGattCharacteristic::PROPERTY_NONE;
@@ skipping 38 matching lines @@
     result |= BluetoothGattCharacteristic::PROPERTY_INDICATE;
   }
   return result;
 }
 }  // namespace
 
 BluetoothRemoteGattCharacteristicMac::BluetoothRemoteGattCharacteristicMac(
     BluetoothRemoteGattServiceMac* gatt_service,
     CBCharacteristic* cb_characteristic)
     : gatt_service_(gatt_service),
-      cb_characteristic_(cb_characteristic, base::scoped_policy::RETAIN) {
+      cb_characteristic_(cb_characteristic, base::scoped_policy::RETAIN),
+      characteristic_value_read_in_progress_(false) {
   uuid_ = BluetoothAdapterMac::BluetoothUUIDWithCBUUID(
       [cb_characteristic_.get() UUID]);
   identifier_ =
       [NSString stringWithFormat:@"%s-%p", uuid_.canonical_value().c_str(),
                                  (void*)cb_characteristic_]
           .UTF8String;
 }
 
 BluetoothRemoteGattCharacteristicMac::~BluetoothRemoteGattCharacteristicMac() {}
 
@@ skipping 47 matching lines @@
 
 void BluetoothRemoteGattCharacteristicMac::StartNotifySession(
     const NotifySessionCallback& callback,
     const ErrorCallback& error_callback) {
   NOTIMPLEMENTED();
 }
 
 void BluetoothRemoteGattCharacteristicMac::ReadRemoteCharacteristic(
     const ValueCallback& callback,
     const ErrorCallback& error_callback) {
-  NOTIMPLEMENTED();
+  if (!IsReadable()) {
+    error_callback.Run(BluetoothRemoteGattService::GATT_ERROR_NOT_PERMITTED);

[ortuno, 2016/06/16 18:22:18]

ReadRemoteCharacteristic should always be async. Post a task to call
error_callback.

[jlebel, 2016/06/22 18:03:58]

Can I denounce windows code?
https://cs.chromium.org/chromium/src/device/bluetooth/bluetooth_remote_gatt_c...

Should I create a bug for windows?

+    return;
+  }
+  if (characteristic_value_read_in_progress_) {
+    error_callback.Run(BluetoothRemoteGattService::GATT_ERROR_IN_PROGRESS);

[ortuno, 2016/06/16 18:22:18]

Same here, post a task.

[jlebel, 2016/06/22 18:03:58]

Done.

+    return;
+  }
+  characteristic_value_read_in_progress_ = true;
+  read_characteristic_value_callbacks_ =
+      std::make_pair(callback, error_callback);
+  [gatt_service_->GetCBPeripheral()
+      readValueForCharacteristic:cb_characteristic_];
 }
 
 void BluetoothRemoteGattCharacteristicMac::WriteRemoteCharacteristic(
     const std::vector<uint8_t>& new_value,
     const base::Closure& callback,
     const ErrorCallback& error_callback) {
   NOTIMPLEMENTED();
 }
 
+void BluetoothRemoteGattCharacteristicMac::DidReadValue(NSError* error) {
+  if (!characteristic_value_read_in_progress_) {
+    return;
+  }
+  characteristic_value_read_in_progress_ = false;
+  if (error) {
+    VLOG(1) << "Bluetooth error while reading for characteristic, domain: "
+            << error.domain.UTF8String << ", error code: " << error.code;
+    BluetoothGattService::GattErrorCode error_code =
+        BluetoothDeviceMac::GetGattErrorCodeFromNSError(error);
+    read_characteristic_value_callbacks_.second.Run(error_code);
+    return;
+  }
+  NSData* nsdata_value = cb_characteristic_.get().value;
+  const uint8_t* buffer = static_cast<const uint8_t*>(nsdata_value.bytes);

[ortuno, 2016/06/16 18:22:18]

nit: Shouldn't you use [nsdata_value bytes] since NSData is an objective-c
class?

[jlebel, 2016/06/22 18:03:58]

Calling [nsdata_value bytes] or doing |nsdata_value.bytes|, it is exactly the
same for Objective-C. Both call the method -[NSData bytes].

Since -[NSData bytes] is declared as a property, .bytes is more appropriate. The
syntaxe . has been created for the @property.  

+  value_.assign(buffer, buffer + nsdata_value.length);
+  read_characteristic_value_callbacks_.first.Run(value_);
+}
+
+bool BluetoothRemoteGattCharacteristicMac::IsReadable() const {
+  return GetProperties() & BluetoothGattCharacteristic::PROPERTY_READ;
+}
+
 CBCharacteristic* BluetoothRemoteGattCharacteristicMac::GetCBCharacteristic()
     const {
   return cb_characteristic_.get();
 }
 
 }  // namespace device.