[Mac/GN] When using debug_devtools=true, bundle the inspector resources using a symlink.

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
 import("//build/config/sanitizers/sanitizers.gni")
@@ skipping 400 matching lines @@
       }
     }
   }
 } else if (is_mac) {
   chrome_helper_name = chrome_product_full_name + " Helper"
   chrome_framework_name = chrome_product_full_name + " Framework"
 
   group("chrome") {
     deps = [
       ":chrome_app",
+      ":devtools_debug_resources",
     ]
   }
 
   tweak_info_plist("chrome_app_plist") {
     info_plist = "app/app-Info.plist"
     _keystone_arg = "0"
     if (enable_mac_keystone) {
       _keystone_arg = "1"
     }
     args = [
@@ skipping 248 matching lines @@
 
     if (v8_use_external_startup_data) {
       sources += [
         "$root_out_dir/natives_blob.bin",
         "$root_out_dir/snapshot_blob.bin",
       ]
       public_deps += [ "//v8" ]
     }
   }
 
+  # When debug_devtools is enabled, symlink the inspector resources into the
+  # framework bundle. The resources go into the final output directory for the
+  # framework in the app bundle, rather than the framework bundle in
+  # root_out_dir, since copy_bundle_data copies the contents of the link
+  # rather than the link itself.
+  action("devtools_debug_resources") {
+    _stamp = "$target_out_dir/run_${target_name}.stamp"
+
+    outputs = [
+      _stamp,
+    ]
+
+    # Convert the destination to an absolute path to make symlinking easier
+    # (no pwd manipulation).
+    _symlink_dest = rebase_path(
+            "$root_out_dir/$chrome_product_full_name.app/Contents/Versions/$chrome_version_full/$chrome_framework_name.framework/Resources/inspector")
+
+    _stamp_arg = rebase_path(_stamp, root_out_dir)
+
+    if (debug_devtools) {
+      script = "//build/symlink.py"
+      args = [
+        "-f",
+        "--touch",
+        _stamp_arg,
+
+        # Convert the symlink source to an absolute path, too.
+        rebase_path("$root_out_dir/resources/inspector"),
+        _symlink_dest,
+      ]
+    } else {
+      script = "//build/rmdir_and_stamp.py"

[Nico, 2016/06/02 18:03:46]

rmdir_and_stamp removes the symlink, not the contents of the directory the
symlink links to, yes?

[Robert Sesek, 2016/06/02 18:20:08]

Correct.

[Robert Sesek, 2016/06/02 18:41:56]

Actually, the rmdir is unnecessary because when copy_bundle_data copies the
framework, it will be deleted first if it exists. Simplified!

(I previously was putting it in .framework to get copied into .app, but
copy_bundle_data traverses symlinks rather than copying the link itself).

[Nico, 2016/06/02 18:44:34]

I figured the rmdir is here so that if you remove devtools_debug, the symlink
disappears on the next build

[Robert Sesek, 2016/06/02 18:47:11]

If you remove devtools_debug, it will create a new .pak, which causes a repak
action to run, which gets put in the .framework/Resources, which then gets
copied to .app. Copying .framework to .app will cause the old .framework to get
rmtree()'d itself, so the link gets removed.

+      args = [
+        _symlink_dest,
+        _stamp_arg,
+      ]
+    }
+
+    deps = [
+      # Depend on :chrome_app to ensure that the bundle is produced before
+      # creating or destroying the symlink.
+      ":chrome_app",
+      "//third_party/WebKit/public:blink_devtools_frontend_resources",
+    ]
+  }
+
   if (enable_nacl) {
     bundle_data("chrome_framework_plugins") {
       sources = []
       outputs = [
         "{{bundle_root_dir}}/Internet Plug-Ins/{{source_file_part}}",
       ]
       public_deps = []
 
       if (enable_nacl) {
         sources += [ "$root_out_dir/nacl_irt_x86_64.nexe" ]
@@ skipping 868 matching lines @@
       "//chrome/app/theme/$branding_path_component/product_logo_48.png",
       "//chrome/tools/build/linux/chrome-wrapper",
       "//third_party/xdg-utils/scripts/xdg-mime",
       "//third_party/xdg-utils/scripts/xdg-settings",
     ]
     outputs = [
       "$root_out_dir/{{source_file_part}}",
     ]
   }
 }