[iOS/GN] Add support for info_plist_target to ios_info_plist.

build/config/ios/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
 #     info_plist:
-#         string, the path to an plist file that will be included in the final
-#         Info.plist generated.
+#         (optional) string, path to the Info.plist file that will be used for
+#         the bundle.
+#
+#     info_plist_target:
+#         (optional) string, if the info_plist is generated from an action,
+#         rather than a regular source file, specify the target name in lieu
+#         of info_plist. The two arguments are mutually exclusive.
 #
 #     executable_name:
 #         string, name of the generated target used for the product
 #         and executable name as specified in the output Info.plist.
 #
 #     extra_substitutions:
 #         (optional) string array, 'key=value' pairs for extra fields which are
 #         specified in a source Info.plist template.
 template("ios_info_plist") {
+  assert(defined(invoker.info_plist) != defined(invoker.info_plist_target),
+         "Only one of info_plist or info_plist_target may be specified in " +
+             target_name)
+
+  if (defined(invoker.info_plist)) {
+    _info_plist = invoker.info_plist
+  } else {
+    _info_plist_target_output = get_target_outputs(invoker.info_plist_target)
+    _info_plist = _info_plist_target_output[0]
+  }
+
   info_plist(target_name) {
     format = "binary1"
     extra_substitutions = []
     if (defined(invoker.extra_substitutions)) {
       extra_substitutions = invoker.extra_substitutions
     }
     extra_substitutions += [
       "IOS_DEPLOYMENT_TARGET=$ios_deployment_target",
       "IOS_PLATFORM_BUILD=$ios_platform_build",
       "IOS_PLATFORM_NAME=$ios_sdk_name",
       "IOS_PLATFORM_VERSION=$ios_sdk_version",
       "IOS_SDK_BUILD=$ios_sdk_build",
       "IOS_SDK_NAME=$ios_sdk_name$ios_sdk_version",
       "IOS_SUPPORTED_PLATFORM=$ios_sdk_platform",
     ]
     plist_templates = [
       "//build/config/ios/BuildInfo.plist",
-      invoker.info_plist,
+      _info_plist,
     ]
+    if (defined(invoker.info_plist_target)) {
+      deps = [
+        invoker.info_plist_target,
+      ]
+    }
     forward_variables_from(invoker,
                            [
                              "executable_name",
                              "output_name",
                              "visibility",
                            ])
   }
 }
 
 # TODO(crbug.com/297668): refactor this template to extract common behaviour
@@ skipping 12 matching lines @@
 #   output_name:
 #       (optional) string, name of the generated application, if omitted,
 #       defaults to the target_name.
 #
 #   extra_substitutions:
 #       (optional) list of string in "key=value" format, each value will
 #       be used as an additional variable substitution rule when generating
 #       the application Info.plist
 #
 #   info_plist:
-#       path to the template to use to generate the application Info.plist
-#       by performing variable substitutions.
+#       (optional) string, path to the Info.plist file that will be used for
+#       the bundle.
+#
+#   info_plist_target:
+#       (optional) string, if the info_plist is generated from an action,
+#       rather than a regular source file, specify the target name in lieu
+#       of info_plist. The two arguments are mutually exclusive.
 #
 #   bundle_extension:
 #       (optional) bundle extension including the dot, default to ".app".
 #
 #   product_type
 #       (optional) string, product type for the generated Xcode project,
 #       default to "com.apple.product-type.application". Should generally
 #       not be overridden.
 #
 # For more information, see "gn help executable".
 template("ios_app_bundle") {
-  assert(defined(invoker.info_plist),
-         "info_plist must be specified for target $target_name")
-
   _output_name = target_name
   _target_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
   _generate_info_plist = target_name + "_generate_info_plist"
   _bundle_data_info_plist = target_name + "_bundle_data_info_plist"
 
   ios_info_plist(_generate_info_plist) {
     executable_name = _output_name
     forward_variables_from(invoker,
                            [
                              "extra_substitutions",
                              "info_plist",
+                             "info_plist_target",
                            ])
   }
 
   bundle_data(_bundle_data_info_plist) {
     forward_variables_from(invoker, [ "testonly" ])
     visibility = [ ":$_target_name" ]
     sources = get_target_outputs(":$_generate_info_plist")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
     public_deps = [
       ":$_generate_info_plist",
     ]
   }
 
   _generate_executable = target_name + "_generate_executable"
   _bundle_data_executable = target_name + "_bundle_data_executable"
 
   executable(_generate_executable) {
     visibility = [ ":$_bundle_data_executable" ]
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "bundle_extension",
                              "code_signing_identity",
                              "data_deps",
                              "entitlements_path",
                              "info_plist",
+                             "info_plist_target",
                              "output_name",
                              "product_type",
                              "visibility",
                            ])
 
     output_name = rebase_path("$target_gen_dir/$_output_name", root_out_dir)
     if (!defined(libs)) {
       libs = []
     }
     libs += [ "UIKit.framework" ]
@@ skipping 79 matching lines @@
 #   output_name:
 #       (optional) string, name of the generated application, if omitted,
 #       defaults to the target_name.
 #
 #   extra_substitutions:
 #       (optional) list of string in "key=value" format, each value will
 #       be used as an additional variable substitution rule when generating
 #       the application Info.plist
 #
 #   info_plist:
-#       path to the template to use to generate the application Info.plist
-#       by performing variable substitutions.
+#       (optional) string, path to the Info.plist file that will be used for
+#       the bundle.
+#
+#   info_plist_target:
+#       (optional) string, if the info_plist is generated from an action,
+#       rather than a regular source file, specify the target name in lieu
+#       of info_plist. The two arguments are mutually exclusive.
 #
 # For more information, see "gn help executable".
 template("ios_appex_bundle") {
   ios_app_bundle(target_name) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "bundle_extension",
                              "product_type",
                            ])
@@ skipping 252 matching lines @@
                              [
                                "testonly",
                                "visibility",
                              ])
       public_deps = [
         ":$_framework_target+link",
       ]
     }
   }
 }