Update GN files w/ changes needed to make sanitizers work.

build/config/sanitizers/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/chromecast_build.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/toolchain/toolchain.gni")
 
 # Contains the dependencies needed for sanitizers to link into executables and
@@ skipping 20 matching lines @@
 
 group("deps_no_options") {
   if (using_sanitizer) {
     public_configs = [
       # Even when a target removes default_sanitizer_flags, it may be depending
       # on a library that did not remove default_sanitizer_flags. Thus, we need
       # to add the ldflags here as well as in default_sanitizer_flags.
       ":default_sanitizer_ldflags",
     ]
     deps = []
+
+    data = [
+      "//tools/valgrind/asan/",
+    ]
+    if (is_win) {
+      exe = ".exe"
+    } else {
+      exe = ""
+    }
+    data += [ "//third_party//llvm-build/Release+Asserts/bin/llvm-symbolizer${exe}" ]
+    if (is_linux) {
+      data += [ "//third_party/llvm-build/Release+Asserts/lib/libstdc++.so.6" ]

[Nico, 2016/06/02 18:16:41]

Can you add a comment here that says that this is needed by llvm-symbolizer?
(While libc++ is used for all of "our" binaries)

[Dirk Pranke, 2016/06/02 18:47:08]

Sure.

+    }
+
     if (use_prebuilt_instrumented_libraries) {
       deps += [ "//third_party/instrumented_libraries:deps" ]
     }
     if (use_custom_libcxx) {
       public_deps = [
         "//buildtools/third_party/libc++:libcxx_proxy",
       ]
+      data += [ "$root_out_dir/libc++.so" ]
     }
     if (is_mac) {
       data_deps = [
         ":copy_asan_runtime",
       ]
     }
   }
 }
 
 if (is_mac) {
@@ skipping 93 matching lines @@
   cflags = []
   cflags_cc = []
 
   # Sanitizers need line table info for stack traces. They don't need type info
   # or variable info, so we can leave that out to speed up the build.
   if (using_sanitizer) {
     assert(is_clang, "sanitizers only supported with clang")
     cflags += [ "-gline-tables-only" ]
   }
 
+  if (symbolized) {
+    cflags += [

[Nico, 2016/06/02 18:16:41]

What's the motivation for this block? I can't find the corresponding bit in gyp.

(I can find
https://code.google.com/p/chromium/codesearch#chromium/src/build/common.gypi&...
for tsan which is probably still missing here?)

[Dirk Pranke, 2016/06/02 18:47:08]

These flags get passed directly in the 'release_extra_cflags' value of
GYP_DEFINES on the "symbolized" bots on chromium.lkgr, e.g.:

https://build.chromium.org/p/chromium.lkgr/builders/ASAN%20Release%20%28symbo...

I think the release_extra_cflags escape valve is a misfeature, which is why I
added the 'symbolized' config to MB and the GN files.

I'll look at the gyp block and see what might need to be merged in.

+      "-O1",

[Nico, 2016/06/02 18:16:41]

Wouldn't the gn way for this be to pick a different default optimization level
in the compiler config if symbolized is set, instead of adding -O1 here?
Depending on config ordering, this -O1 might be before or after the -O flag from
the compiler config. Since the last flag wins, it's not clear if this will have
an effect.

[Dirk Pranke, 2016/06/02 18:47:08]

Hm, probably. Good catch. I'll look at reworking this.

+      "-fno-line-functions",

[Nico, 2016/06/02 18:16:41]

This is supposed to be -fno-inline-functions I assume

[Dirk Pranke, 2016/06/02 18:47:08]

Yup, that's a typo. Another good catch.

+      "-fno-inline",
+    ]
+  }
+
   # Common options for AddressSanitizer, LeakSanitizer, ThreadSanitizer,
   # MemorySanitizer and non-official CFI builds.
   if (using_sanitizer || (is_cfi && !is_official_build)) {
     if (is_posix) {
       cflags += [ "-fno-omit-frame-pointer" ]
     } else {
       cflags += [ "/Oy-" ]
     }
   }
 
@@ skipping 232 matching lines @@
 # This allows to selectively disable ubsan_vptr, when needed. In particular,
 # if some third_party code is required to be compiled without rtti, which
 # is a requirement for ubsan_vptr.
 config("default_sanitizer_flags_but_ubsan_vptr") {
   configs = all_sanitizer_configs - [ ":ubsan_vptr_flags" ]
 }
 
 config("default_sanitizer_flags_but_coverage") {
   configs = all_sanitizer_configs - [ ":coverage_flags" ]
 }