[GN] Configure a pool for copy_bundle_data and compile_xcassets tools.

build/toolchain/mac/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
 # some enhancements since the commands on Mac are slightly different than on
 # Linux.
 
 import("../goma.gni")
 import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/mac_sdk.gni")
 import("//build/config/mac/symbols.gni")
 
 assert(host_os == "mac")
 
 import("//build/toolchain/goma.gni")
 import("//build/toolchain/toolchain.gni")
 import("//build/toolchain/concurrent_links.gni")
 
 if (use_goma) {
   goma_prefix = "$goma_dir/gomacc "
 } else {
   goma_prefix = ""
 }
 
+declare_args() {
+  # Control the number of copy_bundle_data and compile_xcassets tasks to run
+  # simultaneously. As the tasks are doing lots of I/O, some limit is required
+  # to prevent I/O starvation when ninja is run with a large number of parallel
+  # jobs (e.g. when using distributed build like goma).
+  bundle_pool_depth = -1
+}
+
+if (current_toolchain == default_toolchain) {
+  # Reduce the number of tasks using the copy_bundle_data and compile_xcassets
+  # tools as they can cause lots of I/O contention when invoking ninja with a
+  # large number of parallel jobs (e.g. when using distributed build like goma).
+  pool("bundle_pool") {
+    if (bundle_pool_depth == -1) {

[Dirk Pranke, 2016/06/07 22:17:46]

Can we just use the value of concurrent_links here? It seems like adding another
build arg for this is overkill. 

It also seems like we can just re-use the existing (concurrent_links) value
rather than not having to call out to the script again. I suppose it's
theoretically possible that someone might set concurrent_links=X explicitly and
we want bundle_pool_depth=Y, but that seems like excessive optimization.

[sdefresne, 2016/06/08 08:04:27]

Done.

+      depth =
+          exec_script("//build/toolchain/get_concurrent_links.py", [], "value")
+    } else {
+      depth = bundle_pool_depth
+    }
+  }
+}
+
 # This will copy the gyp-mac-tool to the build directory. We pass in the source
 # file of the mac tool.
 gyp_mac_tool_source =
     rebase_path("//tools/gyp/pylib/gyp/mac_tool.py", root_build_dir)
 exec_script("setup_toolchain.py", [ gyp_mac_tool_source ])
 
 # Shared toolchain definition. Invocations should set toolchain_os to set the
 # build args in this definition.
 template("mac_toolchain") {
   toolchain(target_name) {
@@ skipping 228 matching lines @@
     tool("copy") {
       command = copy_command
       description = copy_description
     }
 
     tool("copy_bundle_data") {
       _tool = rebase_path("//build/toolchain/mac/copy_bundle_data.py",
                           root_build_dir)
       command = "python $_tool {{source}} {{output}}"
       description = "COPY_BUNDLE_DATA {{source}} {{output}}"
+      pool = ":bundle_pool($default_toolchain)"
     }
     tool("compile_xcassets") {
       _tool = rebase_path("//build/toolchain/mac/compile_xcassets.py",
                           root_build_dir)
       if (is_ios) {
         _sdk_name = ios_sdk_name
         _min_deployment_target = ios_deployment_target
       } else {
         _sdk_name = mac_sdk_name
         _min_deployment_target = mac_deployment_target
       }
       command = "rm -f {{output}} && " +
                 "python $_tool -p $_sdk_name -t $_min_deployment_target " +
                 "-o {{output}} {{inputs}}"
 
       description = "COMPILE_XCASSETS {{output}}"
+      pool = ":bundle_pool($default_toolchain)"
     }
 
     toolchain_args() {
       current_cpu = invoker.toolchain_cpu
       current_os = invoker.toolchain_os
 
       # These values need to be passed through unchanged.
       host_toolchain = host_toolchain
       target_os = target_os
       target_cpu = target_cpu
@@ skipping 79 matching lines @@
 }
 
 mac_toolchain("x64") {
   toolchain_cpu = "x64"
   toolchain_os = "mac"
   cc = "${goma_prefix}/gcc"
   cxx = "${goma_prefix}/g++"
   ld = cxx
   is_clang = false
 }