Mac a11y: Add RoleDescription and Value attributes to accessibility information.

ui/accessibility/platform/ax_platform_node_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/accessibility/platform/ax_platform_node_mac.h"
 
 #import <Cocoa/Cocoa.h>
 #include <stddef.h>
 
 #include "base/macros.h"
@@ skipping 172 matching lines @@
   };
 
   RoleMap subrole_map;
   for (size_t i = 0; i < arraysize(subroles); ++i)
     subrole_map[subroles[i].value] = subroles[i].nativeValue;
   return subrole_map;
 }
 
 }  // namespace
 
+@interface AXPlatformNodeCocoa ()
+// Helper function for string attributes that don't require extra processing.
+- (NSString*)getStringAttribute:(ui::AXStringAttribute)attribute;
+@end
+
 @implementation AXPlatformNodeCocoa
 
 // A mapping of AX roles to native roles.
 + (NSString*)nativeRoleFromAXRole:(ui::AXRole)role {
   CR_DEFINE_STATIC_LOCAL(RoleMap, role_map, (BuildRoleMap()));
   RoleMap::iterator it = role_map.find(role);
   return it != role_map.end() ? it->second : NSAccessibilityUnknownRole;
 }
 
 // A mapping of AX roles to native subroles.
@@ skipping 13 matching lines @@
 - (void)detach {
   node_ = nil;
 }
 
 - (NSRect)boundsInScreen {
   if (!node_)
     return NSZeroRect;
   return gfx::ScreenRectToNSRect(node_->GetBoundsInScreen());
 }
 
-- (NSArray*)AXChildren {
-  if (!node_)
-    return nil;
-  int count = node_->GetChildCount();
-  NSMutableArray* children = [NSMutableArray arrayWithCapacity:count];
-  for (int i = 0; i < count; ++i)
-    [children addObject:node_->ChildAtIndex(i)];
-  return NSAccessibilityUnignoredChildren(children);
-}
-
-- (id)AXParent {
-  if (!node_)
-    return nil;
-  return NSAccessibilityUnignoredAncestor(node_->GetParent());
-}
-
-- (NSValue*)AXPosition {
-  return [NSValue valueWithPoint:self.boundsInScreen.origin];
-}
-
-- (NSString*)AXRole {
-  if (!node_)
-    return nil;
-  return [[self class] nativeRoleFromAXRole:node_->GetData().role];
-}
-
-- (NSValue*)AXSize {
-  return [NSValue valueWithSize:self.boundsInScreen.size];
-}
-
-- (NSString*)AXTitle {
-  std::string value;
-  if (node_->GetStringAttribute(ui::AX_ATTR_NAME, &value))
-    return base::SysUTF8ToNSString(value);
+- (NSString*)getStringAttribute:(ui::AXStringAttribute)attribute {
+  std::string attributeValue;
+  if (node_->GetStringAttribute(attribute, &attributeValue))
+    return base::SysUTF8ToNSString(attributeValue);
   return nil;
 }
 
 // NSAccessibility informal protocol implementation.
 
 - (BOOL)accessibilityIsIgnored {
   return [[self AXRole] isEqualToString:NSAccessibilityUnknownRole];
 }
 
 - (id)accessibilityHitTest:(NSPoint)point {
@@ skipping 13 matching lines @@
   return @[
     NSAccessibilityChildrenAttribute,
     NSAccessibilityParentAttribute,
     NSAccessibilityPositionAttribute,
     NSAccessibilityRoleAttribute,
     NSAccessibilitySizeAttribute,
 
     // Title is required for most elements. Cocoa asks for the value even if it
     // is omitted here, but won't present it to accessibility APIs without this.
     NSAccessibilityTitleAttribute,
+
+    // Attributes which are not required, but are general to all roles.
+    NSAccessibilityRoleDescriptionAttribute,
+    NSAccessibilityValueAttribute,

[tapted, 2016/06/06 04:09:51]

So I poked around a bit - I think doing this for RoleDescriptionAttribute is
fine, but not much provides valueAttribute. we should act on that TODO below --
switch on node_->GetData().role and append extra things to the array, based on
the role.

[Patti Lor, 2016/06/10 01:36:10]

Have added switch to add Value attributes on a bunch of user input fields for
now, or do you think I should just add it for TEXT_FIELDs only and leave it?

   ];
   // TODO(tapted): Add additional attributes based on role.
 }
 
 - (BOOL)accessibilityIsAttributeSettable:(NSString*)attribute {
   return NO;
 }
 
 - (id)accessibilityAttributeValue:(NSString*)attribute {
   SEL selector = NSSelectorFromString(attribute);
   if ([self respondsToSelector:selector])
     return [self performSelector:selector];
   return nil;
 }
 
+// NSAccessibility attributes.
+
+- (NSArray*)AXChildren {
+  if (!node_)
+    return nil;
+  int count = node_->GetChildCount();
+  NSMutableArray* children = [NSMutableArray arrayWithCapacity:count];
+  for (int i = 0; i < count; ++i)
+    [children addObject:node_->ChildAtIndex(i)];
+  return NSAccessibilityUnignoredChildren(children);
+}
+
+- (id)AXParent {
+  if (!node_)
+    return nil;
+  return NSAccessibilityUnignoredAncestor(node_->GetParent());
+}
+
+- (NSValue*)AXPosition {
+  return [NSValue valueWithPoint:self.boundsInScreen.origin];
+}
+
+- (NSString*)AXRole {
+  if (!node_)
+    return nil;
+  return [[self class] nativeRoleFromAXRole:node_->GetData().role];
+}
+
+- (NSValue*)AXSize {
+  return [NSValue valueWithSize:self.boundsInScreen.size];
+}
+
+- (NSString*)AXTitle {
+  return [self getStringAttribute:ui::AX_ATTR_NAME];
+}
+
+- (NSString*)AXRoleDescription {
+  return [self getStringAttribute:ui::AX_ATTR_DESCRIPTION];

[tapted, 2016/06/06 04:09:51]

So if this returns nil, I think we should then try doing

NSString* role = [self AXRole];
NSString* subrole = nil;  // TODO(..): Support subroles.
return role ? NSAccessibilityRoleDescription(role, subrole) : nil;

NSAccessibilityRoleDescription gets localized descriptions for the standard
roles from AppKit.

It might be worth simply trying to pass a nil |role| as well - -maybe AppKit
provides something better than merely `nil` (or maybe it crashes - we should
check)

[Patti Lor, 2016/06/10 01:36:09]

Works with nil values! Done. Have also added the subrole attribute to this CL,
but to do this I copied some logic from browser_accessibility_cocoa.mm's subrole
method which I am not sure about.

[tapted, 2016/06/10 03:17:17]

What string does it return for nil? The API is

NSAccessibilityRoleDescription(NSString *role, NSString * __nullable subrole)

So, passing nil to subrole is unambiguously OK.

but |role| is neither __nullable nor __nonnull (nor __null_unspecified). If an
actual string is returned, then that's good, but if it returns nil, then we
can't be sure we're using the api right (and should perhaps check for that)

[Patti Lor, 2016/06/16 07:05:21]

Having a nil role returns an empty NSString, so I've left it as is.

+}
+
+- (NSString*)AXValue {
+  return [self getStringAttribute:ui::AX_ATTR_VALUE];
+}
+
 @end
 
 namespace ui {
 
 // static
 AXPlatformNode* AXPlatformNode::Create(AXPlatformNodeDelegate* delegate) {
   AXPlatformNodeBase* node = new AXPlatformNodeMac();
   node->Init(delegate);
   return node;
 }
@@ skipping 19 matching lines @@
 void AXPlatformNodeMac::NotifyAccessibilityEvent(ui::AXEvent event_type) {
   // TODO(dmazzoni): implement this.  http://crbug.com/396137
 }
 
 int AXPlatformNodeMac::GetIndexInParent() {
   // TODO(dmazzoni): implement this.  http://crbug.com/396137
   return -1;
 }
 
 }  // namespace ui