a11y/Mac: Add screenreader support for SubtleNotificationView announcements.

ui/accessibility/platform/ax_platform_node_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/accessibility/platform/ax_platform_node_mac.h"
 
 #import <Cocoa/Cocoa.h>
 #include <stddef.h>
 
 #include "base/macros.h"
@@ skipping 289 matching lines @@
 
 - (id)accessibilityAttributeValue:(NSString*)attribute {
   SEL selector = NSSelectorFromString(attribute);
   if ([self respondsToSelector:selector])
     return [self performSelector:selector];
   return nil;
 }
 
 @end
 
+// TODO(patricialor): Remove this when the deployment target is 10.9 or later.

[dmazzoni, 2016/06/21 20:09:36]

Just an idea: rather than a TODO, how about just making the
compile fail, like:

#if (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_9)
#error Delete the following line once the deployment target is >= 10.9
#endif

[tapted, 2016/06/22 00:23:38]

This is a good suggestion! But I have an alternative which is a bit more
idiomatic, and that's just to add this declaration to
base/mac/sdk_forward_declarations.h around line 66. When we get around to
bumping the deployment target, that file will be properly swept for anything
stale

[Patti Lor, 2016/06/23 01:00:39]

Done, thanks for the suggestions. I stole that bit of code from ellyjones's CL
(https://crrev.com/1999823002/), so I have also done the same thing there - not
sure if it is worth doing that in a separate commit?

dmazzoni, I think you missed my message about testing this on other platforms
(see https://codereview.chromium.org/2010493005/#msg2), please advise? Thanks!

+extern NSString* const NSAccessibilityPriorityKey;
+
 namespace ui {
 
 // static
 AXPlatformNode* AXPlatformNode::Create(AXPlatformNodeDelegate* delegate) {
   AXPlatformNodeBase* node = new AXPlatformNodeMac();
   node->Init(delegate);
   return node;
 }
 
 AXPlatformNodeMac::AXPlatformNodeMac() {
 }
 
 AXPlatformNodeMac::~AXPlatformNodeMac() {
 }
 
 void AXPlatformNodeMac::Destroy() {
   if (native_node_)
     [native_node_ detach];
   AXPlatformNodeBase::Destroy();
 }
 
 gfx::NativeViewAccessible AXPlatformNodeMac::GetNativeViewAccessible() {
   if (!native_node_)
     native_node_.reset([[AXPlatformNodeCocoa alloc] initWithNode:this]);
   return native_node_.get();
 }
 
 void AXPlatformNodeMac::NotifyAccessibilityEvent(ui::AXEvent event_type) {
-  // TODO(dmazzoni): implement this.  http://crbug.com/396137
+  switch (event_type) {
+    case ui::AX_EVENT_ALERT: {
+      NSString* announcement = base::SysUTF8ToNSString(
+          GetData().GetStringAttribute(ui::AX_ATTR_NAME));
+      NSDictionary* notification_info = @{
+        NSAccessibilityAnnouncementKey : announcement,
+        NSAccessibilityPriorityKey : @(NSAccessibilityPriorityHigh)

[tapted, 2016/06/22 00:23:38]

does

NSAccessibilityPriorityKey : NSAccessibilityPriorityHigh

work?

[Patti Lor, 2016/06/23 01:00:39]

It complains "collection element of type 'NSAccessibilityPriorityLevel' is not
an Objective-C object", so I'm guessing it's a C primitive that needs to be
converted with the @(), have left as is.

[tapted, 2016/07/11 03:46:47]

Ah - right you are. [NSNumber numberWithInteger:NSAccessibilityPriorityHigh] is
the old-school way of doing this, but @(foo) is better.

+      };
+      NSAccessibilityPostNotificationWithUserInfo(
+          [NSApp mainWindow], NSAccessibilityAnnouncementRequestedNotification,
+          notification_info);
+    } break;
+    default:
+      // TODO(dmazzoni): implement this.  http://crbug.com/396137
+      break;
+  }
 }
 
 int AXPlatformNodeMac::GetIndexInParent() {
   // TODO(dmazzoni): implement this.  http://crbug.com/396137
   return -1;
 }
 
 }  // namespace ui