[Mac/GN] Implement dSYM generation and stripping.

build/toolchain/mac/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
 # some enhancements since the commands on Mac are slightly different than on
 # Linux.
 
 import("../goma.gni")
 import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/mac_sdk.gni")
+import("//build/config/mac/symbols.gni")
 
 assert(host_os == "mac")
 
 import("//build/toolchain/goma.gni")
 import("//build/toolchain/toolchain.gni")
 
 if (use_goma) {
   goma_prefix = "$goma_dir/gomacc "
 } else {
   goma_prefix = ""
@@ skipping 17 matching lines @@
     assert(defined(invoker.toolchain_os),
            "mac_toolchain() must specify a \"toolchain_os\"")
 
     # We can't do string interpolation ($ in strings) on things with dots in
     # them. To allow us to use $cc below, for example, we create copies of
     # these values in our scope.
     cc = invoker.cc
     cxx = invoker.cxx
     ld = invoker.ld
 
+    linker_driver =
+        rebase_path("//build/toolchain/mac/linker_driver.py", root_build_dir)
+
     # Make these apply to all tools below.
     lib_switch = "-l"
     lib_dir_switch = "-L"
 
     # Object files go in this directory. Use label_name instead of
     # target_output_name since labels will generally have no spaces and will be
     # unique in the directory.
     object_subdir = "{{target_out_dir}}/{{label_name}}"
 
+    # If dSYMs are enabled, this flag will be added to the link tools.
+    if (enable_dsyms) {
+      dsym_switch = " -Wcrl,dsym," + rebase_path(root_out_dir) + " "
+    } else {
+      dsym_switch = ""
+    }
+
     tool("cc") {
       depfile = "{{output}}.d"
       precompiled_header_type = "gcc"
       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "CC {{output}}"
       outputs = [
         "$object_subdir/{{source_name_part}}.o",
       ]
     }
@@ skipping 63 matching lines @@
       # the existing .TOC file, overwrite it, otherwise, don't change it.
       #
       # As a special case, if the library reexports symbols from other dynamic
       # libraries, we always update the .TOC and skip the temporary file and
       # diffing steps, since that library always needs to be re-linked.
       tocname = dylib + ".TOC"
       temporary_tocname = dylib + ".tmp"
 
       does_reexport_command = "[ ! -e \"$dylib\" -o ! -e \"$tocname\" ] || otool -l \"$dylib\" | grep -q LC_REEXPORT_DYLIB"
 
-      link_command = "$ld -shared "
+      link_command = "$linker_driver $ld -shared "
       if (is_component_build) {
         link_command += " -Wl,-install_name,@rpath/\"{{target_output_name}}{{output_extension}}\" "
       }
+      link_command += dsym_switch
       link_command += "{{ldflags}} -o \"$dylib\" -Wl,-filelist,\"$rspfile\" {{libs}} {{solibs}}"
 
       replace_command = "if ! cmp -s \"$temporary_tocname\" \"$tocname\"; then mv \"$temporary_tocname\" \"$tocname\""
       extract_toc_command = "{ otool -l \"$dylib\" | grep LC_ID_DYLIB -A 5; nm -gP \"$dylib\" | cut -f1-2 -d' ' | grep -v U\$\$; true; }"
 
       command = "if $does_reexport_command ; then $link_command && $extract_toc_command > \"$tocname\"; else $link_command && $extract_toc_command > \"$temporary_tocname\" && $replace_command ; fi; fi"
 
       rspfile_content = "{{inputs_newline}}"
 
       description = "SOLINK {{output}}"
@@ skipping 12 matching lines @@
       restat = true
 
       # Tell GN about the output files. It will link to the dylib but use the
       # tocname for dependency management.
       outputs = [
         dylib,
         tocname,
       ]
       link_output = dylib
       depend_output = tocname
+
+      if (enable_dsyms) {
+        outputs += [ dylib + ".dSYM/" ]
+      }
     }
 
     tool("solink_module") {
       sofile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"  # eg "./libfoo.so"
       rspfile = sofile + ".rsp"
 
-      link_command =
-          "$ld -bundle {{ldflags}} -o \"$sofile\" -Wl,-filelist,\"$rspfile\""
+      link_command = "$linker_driver $ld -bundle {{ldflags}} -o \"$sofile\" -Wl,-filelist,\"$rspfile\""
       if (is_component_build) {
         link_command += " -Wl,-install_name,@rpath/{{target_output_name}}{{output_extension}}"
       }
+      link_command += dsym_switch
       link_command += " {{solibs}} {{libs}}"
       command = link_command
 
       rspfile_content = "{{inputs_newline}}"
 
       description = "SOLINK_MODULE {{output}}"
 
       # Use this for {{output_extension}} expansions unless a target manually
       # overrides it (in which case {{output_extension}} will be what the target
       # specifies).
       default_output_dir = "{{root_out_dir}}"
       default_output_extension = ".so"
 
       outputs = [
         sofile,
       ]
+
+      if (enable_dsyms) {
+        outputs += [ sofile + ".dSYM/" ]
+      }
     }
 
     tool("link") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       rspfile = "$outfile.rsp"
 
       # Note about --filelist: Apple's linker reads the file list file and
       # interprets each newline-separated chunk of text as a file name. It
       # doesn't do the things one would expect from the shell like unescaping
       # or handling quotes. In contrast, when Ninja finds a file name with
       # spaces, it single-quotes them in $inputs_newline as it would normally
       # do for command-line arguments. Thus any source names with spaces, or
       # label names with spaces (which GN bases the output paths on) will be
       # corrupted by this process. Don't use spaces for source files or labels.
-      command = "$ld {{ldflags}} -o \"$outfile\" -Wl,-filelist,\"$rspfile\" {{solibs}} {{libs}}"
+      command = "$linker_driver $ld $dsym_switch {{ldflags}} -o \"$outfile\" -Wl,-filelist,\"$rspfile\" {{solibs}} {{libs}}"
       description = "LINK $outfile"
       rspfile_content = "{{inputs_newline}}"
       outputs = [
         outfile,
       ]
 
+      if (enable_dsyms) {
+        outputs += [ outfile + ".dSYM/" ]
+      }
+
       default_output_dir = "{{root_out_dir}}"
     }
 
     # These two are really entirely generic, but have to be repeated in
     # each toolchain because GN doesn't allow a template to be used here.
     # See //build/toolchain/toolchain.gni for details.
     tool("stamp") {
       command = stamp_command
       description = stamp_description
     }
@@ skipping 121 matching lines @@
 }
 
 mac_toolchain("x64") {
   toolchain_cpu = "x64"
   toolchain_os = "mac"
   cc = "${goma_prefix}/gcc"
   cxx = "${goma_prefix}/g++"
   ld = cxx
   is_clang = false
 }