Add an action to create a symbol file for the Blimp engine

blimp/engine/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/config/chrome_build.gni")
 import("//build/config/features.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/config/ui.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//tools/grit/repack.gni")
 import("//tools/grit/grit_rule.gni")
 
 repack("pak") {
   sources = [
     "$root_gen_dir/blink/public/resources/blink_image_resources_100_percent.pak",
@@ skipping 509 matching lines @@
       "--dockerfile",
       _rebased_dockerfile,
       "--startup-script",
       _rebased_startup_script,
       "--manifest",
       _rebased_manifest,
       "--output",
       rebase_path(_bundle),
     ]
   }
+
+  # Creates a breakpad symbol file for the engine. This takes a long time so
+  # it should only be done as part of the official build.
+  if (is_official_build) {
+    action("blimp_symbols") {
+      script = "//build/linux/dump_app_syms.py"
+
+      dump_syms_label = "//breakpad:dump_syms($host_toolchain)"

[Dirk Pranke, 2016/05/16 23:50:23]

($host_toolchain) is almost certainly unnecessary here, since the blimp_engine
will probably always be built w/ the host toolchain.

[marcinjb, 2016/05/17 17:49:31]

Ah, good to know.  Removed (this was basically a copy-paste from Chrome's where
$host_toolchain was probably necessary).

+      dump_syms_binary =
+          get_label_info(dump_syms_label, "root_out_dir") + "/" + "dump_syms"
+
+      engine_binary = "$root_out_dir/blimp_engine_app"
+      symbol_file = "$root_out_dir/blimp_engine_app.breakpad.x64"
+
+      inputs = [
+        engine_binary,
+        dump_syms_binary,
+      ]
+      outputs = [
+        symbol_file,
+      ]
+
+      args = [
+        "./" + rebase_path(dump_syms_binary, root_build_dir),
+        "0",  # strip_binary = false
+        rebase_path(engine_binary, root_build_dir),
+        rebase_path(symbol_file, root_build_dir),
+      ]
+
+      deps = [
+        ":blimp_engine_app",
+        dump_syms_label,
+      ]
+    }
+  }
 }