[headless] Embed pak file into binary.

headless/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
+import("//headless/headless.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//testing/test.gni")
 import("//tools/grit/grit_rule.gni")
 import("//tools/grit/repack.gni")
 
 config("headless_implementation") {
   defines = [ "HEADLESS_IMPLEMENTATION" ]
+
+  if (headless_use_embedded_resources) {
+    defines += [ "HEADLESS_USE_EMBEDDED_RESOURCES" ]
+  }
 }
 
 group("headless") {
   deps = [
     "//headless:headless_lib",
   ]
 }
 
 repack("pak") {
   sources = [
@@ skipping 30 matching lines @@
     "//net:net_resources",
     "//third_party/WebKit/public:image_resources",
     "//third_party/WebKit/public:resources",
     "//ui/resources",
     "//ui/strings",
   ]
 
   output = "$root_out_dir/headless_lib.pak"
 }
 
+action("embed_resources") {
+  # TODO(altimin): Consider zipping file here, it can reduce size up to 80%.
+  script = "//headless/lib/embed_data.py"
+
+  inputs = [
+    "$root_out_dir/headless_lib.pak",
+  ]
+
+  outputs = [
+    "$root_gen_dir/headless/embedded_resource_pak.cc",
+    "$root_gen_dir/headless/embedded_resource_pak.h",
+  ]
+
+  args = [
+    "--data_file",
+    rebase_path("$root_out_dir/headless_lib.pak"),
+    "--gendir",
+    rebase_path("$root_gen_dir"),
+    "--header_file",
+    "headless/embedded_resource_pak.h",
+    "--source_file",
+    "headless/embedded_resource_pak.cc",
+    "--namespace",
+    "headless",
+    "--variable_name",
+    "kHeadlessResourcePak",
+  ]
+
+  deps = [
+    ":pak",
+  ]
+}
+
 grit("resources") {
   source = "lib/resources/headless_lib_resources.grd"
   outputs = [
     "grit/headless_lib_resources.h",
     "$root_gen_dir/headless/headless_lib_resources.pak",
   ]
 }
 
 devtools_domains = [
   "accessibility",
@@ skipping 148 matching lines @@
               "public/util/testing/generic_url_request_mocks.h",
               "public/util/url_fetcher.cc",
               "public/util/url_fetcher.h",
               "public/util/url_request_dispatcher.h",
               "public/util/user_agent.cc",
               "public/util/user_agent.h",
             ]
 
   deps = [
     ":gen_devtools_client_api",
-    ":pak",
     "//base",
     "//components/security_state/content",
     "//components/security_state/core",
     "//content/public/app:both",
     "//content/public/browser",
     "//content/public/common",
     "//content/public/common:service_names",
     "//net",
     "//services/service_manager/public/cpp",
     "//third_party/mesa:osmesa",
     "//ui/aura",
     "//ui/base",
     "//ui/compositor",
     "//ui/display",
     "//ui/events/devices",
     "//url",
   ]
 
+  if (headless_use_embedded_resources) {
+    deps += [ ":embed_resources" ]
+    sources += [
+      "$root_gen_dir/headless/embedded_resource_pak.cc",
+      "$root_gen_dir/headless/embedded_resource_pak.h",
+    ]
+  } else {
+    deps += [ ":pak" ]
+  }
+
   if (use_ozone) {
     deps += [ "//ui/ozone" ]
   }
 
   configs += [ ":headless_implementation" ]
 }
 
 group("headless_tests") {
   testonly = true
 
@@ skipping 112 matching lines @@
 
 executable("headless_shell") {
   sources = [
     "app/headless_shell_main.cc",
   ]
 
   deps = [
     "//headless:headless_shell_lib",
   ]
 }