[GN] New template convert_plist to convert a plist file to another format.

build/config/mac/base_rules.gni

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # This file contains rules that are shared between Mac and iOS.
 
 import("//build/toolchain/toolchain.gni")
 
 if (is_mac) {
   import("//build/config/mac/mac_sdk.gni")
 } else if (is_ios) {
   import("//build/config/ios/ios_sdk.gni")
 }
 
+# Convert plist file to given format.
+#
+# Arguments
+#
+#   source:
+#     string, path to the plist file to convert
+#
+#   output:
+#     string, path to the converted plist, must be under $root_build_dir
+#
+#   format:
+#     string, the format to `plutil -convert` the plist to.
+template("convert_plist") {
+  assert(defined(invoker.source), "source must be defined for $target_name")
+  assert(defined(invoker.output), "output must be defined for $target_name")
+  assert(defined(invoker.format), "format must be defined for $target_name")
+
+  action(target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "visibility",
+                             "testonly",
+                             "deps",
+                           ])
+
+    script = "//build/config/mac/xcrun.py"
+    sources = [
+      invoker.source,
+    ]
+    outputs = [
+      invoker.output,
+    ]
+    args = [
+      "plutil",
+      "-convert",
+      invoker.format,
+      "-o",
+      rebase_path(invoker.output, root_out_dir),
+      rebase_path(invoker.source, root_out_dir),
+    ]
+  }
+}
+
 # The base template used to generate Info.plist files for iOS and Mac apps and
 # frameworks.
 #
 # Arguments
 #
 #     plist_templates:
 #         string array, paths to plist files which will be used for the bundle.
 #
 #     executable_name:
 #         string, name of the generated target used for the product
@@ skipping 34 matching lines @@
           "-s=GCC_VERSION=com.apple.compilers.llvm.clang.1_0",
           "-s=PRODUCT_NAME=$executable_name",
           "-s=XCODE_BUILD=$xcode_build",
           "-s=XCODE_VERSION=$xcode_version",
           "-o=" + rebase_path(outputs[0], root_build_dir),
           "-f=" + invoker.format,
         ] + rebase_path(sources, root_build_dir)
     args = [ "@{{response_file_name}}" ]
     forward_variables_from(invoker,
                            [
+                             "deps",
                              "testonly",
-                             "deps",
+                             "visibility",
                            ])
   }
 }
 
 # This is used as the base template for both iOS and Mac frameworks.
 #
 # By default, the bundle target this template generates does not link the
 # resulting framework into anything that depends on it. If a dependency wants
 # a link-time (as well as build-time) dependency on the framework bundle,
 # depend against "$target_name+link". If only the build-time dependency is
@@ skipping 236 matching lines @@
       "$target_gen_dir/{{source_name_part}}.nib",
     ]
     args = [
              "--input",
              "{{source}}",
              "--output",
              rebase_path("$target_gen_dir/{{source_name_part}}.nib"),
            ] + ibtool_flags
   }
 }