MacViews: Implemented Drag & Drop

ui/views/cocoa/cocoa_drag_drop_manager.mm

+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ui/views/cocoa/cocoa_drag_drop_manager.h"
+
+#include "base/mac/mac_util.h"
+#include "base/strings/sys_string_conversions.h"
+#include "ui/base/dragdrop/os_exchange_data.h"
+#include "ui/base/dragdrop/os_exchange_data_provider_mac.h"
+#include "ui/gfx/image/image_skia_util_mac.h"
+#include "ui/views/drag_utils.h"
+#import "ui/views/cocoa/bridged_content_view.h"
+#import "ui/views/cocoa/bridged_native_widget.h"
+#include "ui/views/widget/drop_helper.h"
+
+namespace {}  // namespace
+
+@interface CocoaDragSourceProvider : NSObject<NSPasteboardItemDataProvider> {
+  std::unique_ptr<ui::OSExchangeData> data_;
+}
+
+@end
+
+@implementation CocoaDragSourceProvider
+
+- (id)initWithData:(const ui::OSExchangeData&)data {
+  if ((self = [super init])) {
+    data_.reset(new OSExchangeData(data.provider().Clone()));
+  }
+  return self;
+}
+
+- (id)initWithPasteboard:(NSPasteboard*)pasteboard {
+  if ((self = [super init])) {
+    data_.reset(new OSExchangeData(
+        ui::OSExchangeDataProviderMac::CreateProviderFromPasteboard(
+            pasteboard)));
+  }
+  return self;
+}
+
+- (ui::OSExchangeData*)data {
+  return data_.get();
+}
+
+- (void)pasteboard:(NSPasteboard*)sender
+                  item:(NSPasteboardItem*)item
+    provideDataForType:(NSString*)type {
+  const ui::OSExchangeDataProviderMac* provider =
+      static_cast<const ui::OSExchangeDataProviderMac*>(&data_->provider());
+  NSData* ns_data = provider->GetNSDataForType(type);
+  [sender setData:ns_data forType:type];
+}
+
+@end
+
+namespace views {
+
+CocoaDragDropManager::CocoaDragDropManager(BridgedNativeWidget* bridge)
+    : bridge_(bridge) {
+  DCHECK(bridge);
+  drop_helper_.reset(new DropHelper([bridge->ns_view() hostedView]));
+}
+
+CocoaDragDropManager::~CocoaDragDropManager() {}
+
+void CocoaDragDropManager::BeginDrag(
+    const ui::OSExchangeData& data,
+    const gfx::Point& location,
+    int operation,
+    ui::DragDropTypes::DragEventSource source) {
+  drag_source_.reset([[CocoaDragSourceProvider alloc] initWithData:data]);
+  operation_ = operation;
+
+  const ui::OSExchangeDataProviderMac* provider =
+      static_cast<const ui::OSExchangeDataProviderMac*>(&data.provider());
+  const base::NativeEvent event = provider->GetNativeEvent();
+
+  NSImage* image = gfx::NSImageFromImageSkiaWithColorSpace(
+      provider->GetDragImage(), base::mac::GetSRGBColorSpace());
+
+  base::scoped_nsobject<NSPasteboardItem> item([[NSPasteboardItem alloc] init]);
+  [item setDataProvider:drag_source_.get()
+               forTypes:provider->GetPasteboardTypes()];
+
+  base::scoped_nsobject<NSDraggingItem> dragItem(
+      [[NSDraggingItem alloc] initWithPasteboardWriter:item.get()]);
+
+  [dragItem setDraggingFrame:NSMakeRect([event locationInWindow].x,
+                                        [event locationInWindow].y -
+                                            [image size].height,
+                                        [image size].width, [image size].height)
+                    contents:image];
+
+  [bridge_->ns_view() beginDraggingSessionWithItems:@[ dragItem.get() ]
+                                              event:event
+                                             source:nil];
+}
+
+NSDragOperation CocoaDragDropManager::DraggingOver(id<NSDraggingInfo> sender) {
+  int drag_operation = ui::DragDropTypes::DRAG_NONE;
+
+  // Since dragging from web contents does not generate OSExchangeData, we
+  // need to create one based on the pasteboard provided.
+  if (!drag_source_.get()) {
+    drag_source_.reset([[CocoaDragSourceProvider alloc]
+        initWithPasteboard:[sender draggingPasteboard]]);
+  }
+
+  drag_operation = drop_helper_->OnDragOver(
+      *[drag_source_ data], LocationInView([sender draggingLocation]),
+      operation_);
+
+  return ui::DragDropTypes::DragOperationToNSDragOperation(drag_operation);
+}
+
+NSDragOperation CocoaDragDropManager::OnDrop(id<NSDraggingInfo> sender) {
+  int drag_operation = drop_helper_->OnDrop(
+      *[drag_source_ data], LocationInView([sender draggingLocation]),
+      operation_);
+  return ui::DragDropTypes::DragOperationToNSDragOperation(drag_operation);
+}
+
+void CocoaDragDropManager::EndDrag() {
+  drag_source_.reset();
+}
+
+void CocoaDragDropManager::SetRootView(View* view) {
+  drop_helper_.reset(new DropHelper(view));
+}
+
+gfx::Point CocoaDragDropManager::LocationInView(NSPoint point) const {
+  return gfx::Point(point.x, NSHeight([bridge_->ns_window() frame]) - point.y);
+}
+
+}  // namespace views